0 REM ************  The Horrible Rotten Dancing Dragon ... Strikes  ************
2 REM 1983       - Softline by Ken Rose 
3 REM 16/06/2025 - Bilingual version D.Rioual 
10 REM ANOTHER ADVENTURE FROM SOFTLINE
15 REM WRITTEN FOR THE ATARI BUT EASILY TRANSPORTABLE IF YOU READ THE ACCOMPANYING ARTICLE
20 FCOL = 2:COLOR FCOL,0
25 GOSUB 30000
30 DIM N(34),S(34),E(34),W(34),OB(7),RD(34)
40 OB(1)=5:OB(2)=22:OB(3)=25:OB(4)=31:OB(5)=27:OB(6)=33:OB(7)=32
45 CL=80:REM NUMBER OF COLUMN
46 NL=1:REM FLAG TO MOVE TO NEXT LINE AFTER PRINTING
50 REM ****************************  READING DATA  ****************************
60 FOR A=1 TO 33
70 READ X:N(A)=X:READ X:S(A)=X:READ X:E(A)=X:READ X:W(A)=X:X=0:RD(A)=0
80 NEXT A
90 R=1:GOSUB 1500:GOTO 620
100 REM ******************************  PARSER   ******************************
110 V1$="":N1$=""
120 PRINT :M1$="WHAT NOW ":M2$="Que faites-vous ":NL=0:GOSUB 10000:INPUT A$
130 A$=UCASE$(A$)
140 FOR A = 1 TO LEN (A$)
150 IF MID$ (A$,A,1) = " " THEN X = A - 1: A = 0: GOTO 180
160 NEXT A
170 V1$ = A$: GOTO 300
180 V1$=LEFT$ (A$,X)
190 IF RIGHT$ (A$, LEN(A$) - X) = " " THEN N1$ = "": GOTO 300:REM BE SURE THERE IS A SPACE BETWEEN THE FIRST PAIR OF QUOTES AND NO SPACE BETWEEN THE SECOND PAIR OF QUOTES
200 N1$ = RIGHT$ (A$, LEN (A$) - (X+1)): GOTO 300
300 REM ***********************  VERB-HANDLING ROUTINE  ***********************
310 IF V1$="GO" THEN V1$=N1$:GOTO 500
320 IF V1$="NORTH" OR V1$="N" OR V1$="SOUTH" OR V1$="S" OR V1$="EAST" OR V1$="E" OR V1$="WEST" OR V1$="W" OR V1$="NORD" OR V1$="SUD" OR V1$="EST" OR V1$="OUEST" OR V1$="O" THEN GOTO 500
330 IF V1$="INVENTORY" OR V1$="INVENTAIRE" OR V1$="INV" OR V1$="I" THEN GOTO 700
335 IF V1$="PREND" THEN V1$="PRENDRE"
340 IF V1$="GET" OR V1$="TAKE" OR V1$="PRENDRE" THEN GOTO 800
345 IF V1$="APPUIE" THEN V1$="APPUYER"
346 IF V1$="PRESSE" THEN V1$="PRESSER"
350 IF V1$="PUSH" OR V1$="PRESS" OR V1$="APPUYER" OR V1$="PRESSER" THEN GOTO 900
355 IF V1$="POSE" THEN V1$="POSER"
360 IF V1$="DROP" OR V1$="POSER" THEN GOTO 1000
365 IF V1$="QUITTE" THEN V1$="QUITTER"
370 IF V1$="QUIT" OR V1$="QUITTER" THEN GOTO 3700
375 IF V1$="FRAPPE" THEN V1$="FRAPPER"
376 IF V1$="ATTAQUE" THEN V1$="ATTAQUER"
377 IF V1$="TUE" THEN V1$="TUER"
380 IF V1$="HIT" OR V1$="STRIKE" OR V1$="BEAT" OR V1$="KILL" OR V1$="FRAPPER" OR V1$="ATTAQUER" OR V1$="TUER" THEN GOTO 1200
385 IF V1$="MANGE" THEN V1$="MANGER"
390 IF V1$="EAT" OR V1$="MANGER" THEN GOSUB 1300:GOTO 100
395 IF V1$="DONNE" THEN V1$="DONNER"
400 IF V1$="FEED" OR V1$="GIVE" OR V1$="DONNER" THEN GOTO 1400
405 IF V1$="DANSE" THEN V1$="DANSER"
410 IF V1$="DANCE" OR V1$="DANSER" THEN GOTO 1100
415 IF V1$="EXAMINE" THEN V1$="EXAMINER"
416 IF V1$="REGARDE" THEN V1$="REGARDER"
420 IF V1$="LOOK" OR V1$="REGARDER" OR V1$="EXAMINER" THEN CLS: RD(R)=0: GOTO 610
430 IF V1$="FR" OR V1$="FRANCAIS" THEN FR=1:PRINT "Passage en français.":GOTO 100
440 IF V1$="EN" OR V1$="ENGLISH" THEN FR=0:PRINT "Switch to English.":GOTO 100
490 PRINT :M1$="I DON'T KNOW HOW TO "+V1$+".":M2$="Je ne sais pas comment "+V1$+".":GOSUB 10000:GOTO 100
500 REM ************************ MOVING AROUND ROUTINE ************************
510 X=R:REM STORING CURRENT ROOM NUMBER
520 IF V1$="NORTH" OR V1$="N" OR V1$="NORD" THEN R = N(R)
530 IF V1$="SOUTH" OR V1$="S" OR V1$="SUD" THEN R = S(R)
540 IF V1$="EAST" OR V1$="E" OR V1$="EST" THEN R = E(R)
550 IF V1$="WEST" OR V1$="W" OR V1$="OUEST" OR V1$="O" THEN R = W(R)
560 IF X=28 AND R=32 THEN GOTO 590
570 IF R=28 AND S(28)=32 THEN GOTO 3570:REM RETURNING TO DRAGON'S CAVE
580 IF X=28 THEN GOTO 3590:REM TRAPPED IN DRAGON'S CAVE
590 IF R>0 THEN X=R:CLS:GOTO 610:REM YOU'VE MOVED AND X WILL BE USED IN SEARCHING FOR OBJECTS
600 IF R=0 THEN PRINT :M1$="YOU CAN'T MOVE THAT WAY (I THINK).":M2$="Impossible d'aller dans cette direction.":GOSUB 10000:R=X:X=0:GOTO 100:REM ORIGINAL ROOM VALUE SETUP
610 IF R>19 THEN GOTO 618
612 ON R GOSUB 1510,1530,1550,1570,1590,1610,1630,1650,1670,1690,1710,1730,1750,1770,1790,1810,1830,1850,1870
615 GOTO 620
618 ON (R-19) GOSUB 1890,1910,1930,1950,1970,1990,2010,2030,2050,2070,2090,2110,2130,2150
620 PRINT :M1$="OBJECTS HERE ARE:":M2$="Objets présents :":GOSUB 10000:PRINT
630 X=R:GOSUB 2300
640 X=0
650 M1$="EXITS: ":M2$="directions : ":NL=0:GOSUB 10000
651 IF N(R)>0 THEN M1$="NORTH ":M2$="Nord ":NL=0:GOSUB 10000
652 IF S(R)>0 THEN M1$="SOUTH ":M2$="Sud ":NL=0:GOSUB 10000
653 IF E(R)>0 THEN M1$="EAST ":M2$="Est ":NL=0:GOSUB 10000
654 IF W(R)>0 THEN M1$="WEST":M2$="Ouest ":NL=0:GOSUB 10000
655 PRINT
690 GOTO 100
700 REM *************************  INVENTORY ROUTINE  *************************
710 X=34
720 PRINT :M1$="YOU ARE CARRYING:":M2$="Vous transportez :":GOSUB 10000:PRINT
730 GOSUB 2300
740 GOTO 100
800 REM ****************************  GET ROUTINE  ****************************
810 IF N1$="" THEN PRINT :M1$="DON'T BE SILLY, I NEED A NOUN!":M2$="Soyez raisonable, il me faut un nom !":GOSUB 10000:GOTO 890
820 GOSUB 2200:IF X=0 THEN 100
830 IF OB(X)=R OR OB(X)=34 THEN GOTO 850
840 PRINT :M1$="YOU CAN'T, AT THE MOMENT.":M2$="Vous ne pouvez pas pour le moment.":GOSUB 10000:PRINT :GOTO 890
850 IF X=3 AND OB(7)<34 THEN GOTO 3410
860 OB(X)=34
870 IF OB(3)=34 THEN GOTO 3400
880 PRINT :M1$="YOU'VE GOT THE "+N1$+".":GOSUB 12000:M2$="Vous avez "+AD$+N1$+".":GOSUB 10000:PRINT
890 X=0:GOTO 100
900 REM ***************************  PRESS ROUTINE  ***************************
910 IF N1$="" THEN PRINT :M1$="DON'T BE SILLY, I NEED A NOUN!":M2$="Soyez raisonable, il me faut un nom !":GOSUB 10000:GOTO 890
920 IF R=11 OR R=18 THEN GOTO 940
930 GOTO 990
940 IF R=18 THEN GOTO 980
950 IF OB(1)=34 THEN GOTO 3060
960 IF N1$="BUTTON" OR N1$="BOUTON" THEN GOTO 3050
970 GOTO 3040
980 IF N1$="ROCK" OR N1$="STONE" OR N1$="PIERRE" OR N1$="ROCHER" THEN GOTO 3220
990 PRINT :M1$="I CAN'T "+V1$+" A "+N1$+".":GOSUB 12000:M2$="Je ne peux pas "+V1$+" "+AI$+N1$+".":GOSUB 10000:PRINT :GOTO 100
1000 REM **********************  ROUTINE TO DROP OBJECTS  *********************
1010 GOSUB 2200:IF X=0 THEN 100
1020 IF OB(X)=34 THEN GOTO 1040
1030 PRINT :M1$="I'M NOT CARRYING THE "+N1$+".":GOSUB 12000:M2$="Je ne porte pas "+AI$+N1$+".":GOSUB 10000:PRINT :GOTO 1080
1040 OB(X)=R
1050 IF N1$="WAGON" OR N1$="CHARIOT" AND OB(7)=R THEN GOTO 3420
1060 PRINT :M1$="I'VE DROPPED THE "+N1$+".":GOSUB 12000:M2$="J'ai posé "+AD$+N1$+".":GOSUB 10000:PRINT
1070 IF R=28 AND OB(X)=28 THEN OB(X)=0:GOTO 3580:REM THE DRAGON'S GONNA EAT IT
1080 X=0
1090 GOTO 100
1100 REM ***************************  DANCE ROUTINE  **************************
1110 PRINT: M1$="YOU START TO HUM A CATCHY LITTLE TUNE. YOU GRACEFULLY LEAP UP IN THE AIR, DO A PIROUETTE, LAND, DO A CARTWHEEL, AND TAKE A BOW."
1111 M2$="Vous vous mettez à fredonner un air entrainant. Vous sautez gracieusement en l'air, faites une pirouette, atterissez, faites une roue et saluez.":GOSUB 10000
1120 IF R=28 THEN GOTO 3530
1130 PRINT :M1$="FURRY LITTLE CREATURES APPEAR, APPLAUD FURRIOUSLY, AND LEAVE."
1131 M2$="De petites créatures à fourrure apparaissent, applaudissent furieusement et s'en vont.":GOSUB 10000
1140 GOTO 100
1200 REM *******************  BEATING AND HITTING ROUTINES  *******************
1210 IF N1$="" THEN PRINT :M1$="OKAY, BUT YOU HAVE TO TELL ME WHAT IT IS YOU WANT TO "+V1$+".":M2$="OK mais dites moi ce que vous voulez "+V1$+".":GOSUB 10000:PRINT :GOTO 100
1220 IF R=9 AND OB(7)<34 THEN GOTO 3310
1230 IF R=18 AND OB(2)=34 THEN GOTO 3230
1240 IF R=18 THEN GOTO 3250
1250 IF N1$="DRUM" OR N1$="DRUMSTICK" OR N1$="TAMBOUR" OR N1$="BAGUETTE" THEN GOTO 3320
1260 IF R=28 AND OB(2)=34 THEN GOTO 3550
1270 IF R=28 THEN GOTO 3560
1280 PRINT :M1$="YOU CAN'T "+V1$+" A "+N1$+" HERE.":GOSUB 12000:M2$="Vous ne pouvez pas "+V1$+" "+AI$+N1$+" ici.":GOSUB 10000:GOTO 100
1300 REM **************************  EATING ROUTINES  *************************
1310 IF N1$="" THEN PRINT :M1$="TSK, TSK, PLEASE SUPPLY A NOUN.":M2$="Hum, un nom s'il vous plait.":GOSUB 10000:PRINT :RETURN
1320 IF N1$="SANDWICH" AND OB(5)=34 THEN PRINT :M1$="YUM, YUM, THAT TASTED GOOD.":M2$="Miam miam, c'est bon.":GOSUB 10000:OB(5)=0:RETURN
1340 IF N1$="SANDWICH" THEN PRINT :M1$="YOU DON'T HAVE IT.":M2$="Vous ne l'avez pas.":GOSUB 10000:RETURN
1350 IF (N1$="DRUMSTICK" OR N1$="BAGUETTE") AND OB(4)=34 THEN PRINT :M1$="YUCK, THAT TASTED AWFUL.":M2$="Berk, c'est très mauvais.":GOSUB 10000:OB(4)=0:RETURN
1360 IF N1$="DRUMSTICK" OR N1$="BAGUETTE" THEN PRINT :M1$="HOW CAN YOU, YOU DON'T HAVE IT.":M2$="Vous ne l'avez pas.":GOSUB 10000:RETURN
1370 PRINT :M1$="DON'T BE SILLY. YOU CAN'T EAT THAT!":M2$="Soyez raisonable, vous ne pouvez pas manger cela!":GOSUB 10000:RETURN
1400 REM *********************  GIVING OR FEEDING ROUTINE  ********************
1410 GOSUB 2200:IF X=0 THEN 100
1420 IF OB(X)=34 THEN GOTO 1440
1430 PRINT :M1$="YOU CAN'T "+V1$+" SOMETHING YOU DON'T HAVE!":M2$="Vous ne pouvez pas "+V1$+" ce que vous n'avez pas !":GOSUB 10000:GOTO 100
1440 IF R=28 THEN OB(X)=0:GOTO 3580:REM THE DRAGON'S GONNA EAT IT
1450 PRINT :M1$="I DON'T KNOW HOW TO TELL YOU THIS, BUT NO ONE WANTS IT.":M2$="Comment vous le dire... personne ne veut ça.":GOSUB 10000:GOTO 100
1500 REM ********************  ROOM DESCRIPTION SUBROUTINE  *******************
1510 M1$="YOU ARE IN A FOREST":M2$="Vous êtes dans une forêt":GOSUB 11000:PRINT DES$:IF RD(R)=1 THEN RETURN
1520 PRINT :M1$="IT IS A WARM SPRING DAY IN THE FOREST PRIMEVAL. YOU ARE DRESSED IN A JERKIN.":M2$="C'est une chaude journée dans la forêt vierge. Vous portez un blouson.":GOSUB 10000
1522 M1$="CUTE LITTLE FURRY CREATURES BOUND THROUGH THE WOODS.":M2$="D'adorables petites créatures se promènent dans les bois.":GOSUB 10000:RD(R)=1:RETURN
1530 M1$="YOU ARE IN A LEAFY FOREST":M2$="Vous êtes dans une forêt feuillue":GOSUB 11000:PRINT DES$:IF RD(R)=1 THEN RETURN
1535 PRINT :M1$="THE LEAVES IN THE TREES ARE QUITE UNUSUAL SINCE THIS IS SPRING.":M2$="Les feuilles dans les arbres sont tout à fait inhabituelles.":GOSUB 10000:PRINT
1540 M1$="THESE ARE LEAF SPRINGS.":M2$="Ce sont des feuilles de printemps.":GOSUB 10000:RD(R)=1:RETURN
1550 M1$="YOU ARE IN A LEAFY GLADE":M2$="Vous êtes dans une clairière feuillue":GOSUB 11000:PRINT DES$:IF RD(R)=1 THEN RETURN
1560 PRINT :M1$="AREN'T YOU GLAD YOU'RE IN THE GLADE?":M2$="N'êtes-vous pas heureux d'être dans la clairière ?":GOSUB 10000:RD(R)=1:RETURN
1570 M1$="YOU ARE IN THE PINE FOREST":M2$="Vous êtes dans la forêt de pins":GOSUB 11000:PRINT DES$:IF RD(R)=1 THEN RETURN
1575 PRINT :M1$="THE WIND BLOWING THROUGH THE PINES IS SINGING A SONG. YOU LISTEN CLOSELY AND CAN MAKE OUT SOME OF THE WORDS."
1576 M2$="Le vent soufflant dans les pins chante une chanson. Vous écoutez avec attention et reconnaissez quelques mots.":GOSUB 10000
1577 PRINT :M1$="THEY ARE, 'I OPINE A DRAGON TO SWEETEN MAKE SURE THAT HE'S EATEN'.":M2$="Ils sont, 'Je souhaite un dragon pour adoucir et être sûr qu'il a mangé'.":GOSUB 10000
1580 RD(R)=1:RETURN
1590 M1$="ALL THE TREES ARE DEAD HERE":M2$="Ici tous les arbres sont morts":GOSUB 11000:PRINT DES$:IF RD(R)=1 THEN RETURN
1600 RD(R)=1:RETURN :REM PUT YOUR OWN CLEVER MESSAGE ON THIS LINE
1610 M1$="YOU ARE ON A PAVED ROAD":M2$="Vous êtes sur une route pavée":GOSUB 11000:PRINT DES$:IF RD(R)=1 THEN RETURN
1615 PRINT :M1$="TO THE SOUTH IS THE NORTH SIDE OF A DRAWBRIDGE. THE BRIDGE LOOKS PRETTY RICKETY.":M2$="Au sud se trouve le cote nord d'un pont mobile. Il a l'air plutôt branlant.":GOSUB 10000
1620 RD(R)=1:RETURN
1630 M1$="YOU ARE IN THE THRONE ROOM":M2$="Vous êtes dans la salle du trône":GOSUB 11000:PRINT DES$:GOSUB 3100
1640 RETURN
1650 M1$="YOU ARE IN THE ANTECHAMBER":M2$="Vous êtes dans l'antichambre":GOSUB 11000:PRINT DES$:IF RD(R)=1 THEN RETURN
1660 PRINT :M1$="THIS, AS YOU'LL FIND, IS NOT A VERY LARGE CASTLE. IN FACT IT HAS ONLY THREE (I THINK) ROOMS."
1661 M2$="Comme vous le verrez, ce château n'est pas très grand. Il n'a que trois salles (je crois).":GOSUB 10000
1665 RD(R)=1:RETURN
1670 M1$="THIS IS THE KING'S BEDROOM":M2$="La chambre à coucher du roi":GOSUB 11000:PRINT DES$:IF OB(3)=34 THEN PRINT :M1$="THE ROOM IS EMPTY.":M2$="La piece est vide.":GOSUB 10000:RETURN
1680 PRINT :M1$="THE POOR KING HAS BEEN EXPOSED TO WEREWOLF SIMPLEX II AND IS SLOWLY TURNING INTO A WOLF."
1681 M2$="Le pauvre roi a été exposé au Simplexe II du loup-garou et se tranforme lentement en loup.":GOSUB 10000
1685 PRINT:M1$="HE EXPLAINS THAT UNLESS CURED BY THE MAGIC SPRING HE IS DOOMED SINCE HE CAN'T LEAVE THE PALACE."
1686 M2$="Il explique qu'à moins d'être guéri par le ressort magique, il est condamné car il ne peut quitter le palais.":GOSUB 10000
1687 RD(R)=1:RETURN
1690 M1$="MORE FOREST":M2$="Plus de forêt":GOSUB 11000:PRINT DES$:IF RD(R)=1 THEN RETURN
1700 PRINT :M1$="JUST MORE AND MORE FOREST":M2$="Toujours plus de forêt":GOSUB 10000:RD(R)=1:RETURN
1710 M1$="NORTH END OF BRIDGE":M2$="Coté nord du pont mobile":GOSUB 11000:PRINT DES$:GOSUB 3000
1720 RETURN
1730 M1$="CAUSEWAY TO CASTLE":M2$="Passage menant au chateau":GOSUB 11000:PRINT DES$:IF RD(R)=1 THEN RETURN
1740 PRINT :M1$="TO THE NORTH YOU SEE A SMALL CASTLE. SMALL DOES NOT DO IT JUSTICE. IT IS REALLY SMALL. "
1741 M2$="Au nord vous voyez un petit château. Petit est un euphémisme. Il est minuscule.":GOSUB 10000
1745 M1$="IF YOU WANT TO SEE HOW SMALL, GO NORTH.":M2$="Si vous voulez voir à quel point, allez au nord.":GOSUB 10000:RD(R)=1:RETURN
1750 M1$="AND YET EVEN MORE FOREST":M2$="Et voilà encore plus de forêt":GOSUB 11000:PRINT DES$:IF RD(R)=1 THEN RETURN
1760 PRINT :M1$="IF YOU THINK IT'S DULL READING ABOUT THE FOREST, YOU SHOULD TRY YOUR HAND AT WRITING ABOUT IT."
1761 M2$="Si trouvez la lecture decrivant la forêt ennuyeuse, vous devriez essayer d'écrire à son propos.":GOSUB 10000
1765 RD(R)=1:RETURN
1770 M1$="DARK FOREST":M2$="Forêt sombre":GOSUB 11000:PRINT DES$:IF RD(R)=1 THEN RETURN
1780 PRINT :M1$="THERE IS SOMETHING VERY STRANGE HERE. THE GROUND SOUNDS HOLLOW!":M2$="Il y a quelquechose d'étrange ici. Le sol sonne creux !":GOSUB 10000:RD(R)=1:RETURN
1790 M1$="SOUTH SIDE OF DRAWBRIDGE.":M2$="Coté sud du pont mobile":GOSUB 11000:PRINT DES$:IF RD(R)=1 THEN RETURN
1800 GOSUB 3070:RETURN
1810 DES$="GENTLY ROLLING HILLS":M2$="Collines doucement vallonnées":GOSUB 11000:PRINT DES$:IF RD(R)=1 THEN RETURN
1820 PRINT :M1$="THE HILLS ARE ALIVE WITH THE SOUND OF MUSIC. THEY SING:":M2$="Les collines sont animées par la musique. Elles chantent :":GOSUB 10000
1825 PRINT :M1$="DON'T PUT YOUR SHOULDER TO THE BOULDER, BUT TEST YOUR METTLE, AGAINST THE KETTLE."
1826 M2$="Ne mettez pas votre épaule contre le rocher, mais testez votre courage face à la bouilloire.":GOSUB 10000:RD(R)=1:RETURN
1830 M1$="VOLCANIC HIGHLANDS":M2$="Hauts plateaux volcaniques":GOSUB 11000:PRINT DES$:IF RD(R)=1 THEN RETURN
1840 PRINT :M1$="ALL ADVENTURE GAMES HAVE TO HAVE AT LEAST ONE VOLCANO. THIS VOLCANO IS ALL POOPED OUT AND WILL NOT ERUPT DURING THIS GAME."
1841 M2$="Tous les jeux d'aventure doivent avoir un volcan. Ce dernier est complètement bouché et n'entrera pas en éruption durant ce jeu.":GOSUB 10000:RD(R)=1:RETURN
1850 M1$="VOLCANO VALLEY":M2$="Vallée des volcans":PRINT DES$:IF N(18)=14 THEN RETURN :REM IF N(19)=14 THE SECRET PASSAGE IS OPEN
1860 GOSUB 3210:RETURN
1870 M1$="MARSHY SWAMP":M2$="Marais détrempés":PRINT DES$:IF RD(R)=1 THEN RETURN
1880 PRINT :M1$="A SMALL DINOSAUR STICKS ITS TONGUE OUT AT YOU FROM BEHIND A FERN. IT THEN DARTS AWAY."
1881 M2$="Un petit dinosaure vous tire la langue de derrière une fougère. Puis il s'éloigne.":GOSUB 10000:RD(R)=1:RETURN
1890 M1$="MORE MARSHY SWAMP":M2$="Encore des marais détrempés":GOSUB 11000:PRINT DES$:IF RD(R)=1 THEN RETURN
1900 PRINT :M1$="THE SMALL DINOSAUR REAPPEARS AND HURLS A ROCK AT YOU. THE ROCK MISSES AND THE DINOSAUR DARTS AWAY."
1901 M2$="Le petit dinosaure réapparait et vous lance une pierre. Elle vous manque et le dinosaure s'éloigne.":GOSUB 10000
1905 RD(R)=1:RETURN
1910 M1$="MUSHY SWAMP":M2$="Marais ramollis":GOSUB 11000:PRINT DES$:IF RD(R)=1 THEN RETURN
1920 PRINT :M1$="THE SMALL DINOSAUR TAUNTS YOU BY SAYING (IN DINOSAUR LANGUAGE): 'NYAH, NYAH, THE DRAGON'S GONNA GET YOU!'"
1921 M2$="Le petit dinosaure vous narge en disant (en langue dinosaure) : 'gnarf, gnarf, le dragon va t'attraper !'":GOSUB 10000
1925 RD(R)=1:RETURN
1930 M1$="A PLAIN":M2$="Une plaine":GOSUB 11000:PRINT DES$:IF RD(R)=1 THEN RETURN
1940 PRINT :M1$="OUTSIDE OF A RUSTY SWORD, THERE IS NOTHING UNUSUAL HERE."
1941 M2$="A part une épée rouillée, il n'y a rien de spécial ici.":GOSUB 10000:RD(R)=1:RETURN
1950 M1$="PLAIN PLAIN":M2$="Plaine, morne plaine":GOSUB 11000:PRINT DES$:IF RD(R)=1 THEN RETURN
1960 PRINT :M1$="NOTHING UNUSUAL HERE.":M2$="Rien d'inhabituel ici.":GOSUB 10000:RD(R)=1:RETURN
1970 M1$="PLANE PLAIN PLAIN":M2$="Simple plaine plane":GOSUB 11000:PRINT DES$:IF RD(R)=1 THEN RETURN
1980 PRINT :M1$="NOT ONLY IS NOTHING UNUSUAL HERE, BUT IT'S VERY FLAT HERE.":M2$="Non seulement il n'y a rien de special, mais en plus ici c'est très plat.":GOSUB 10000:RD(R)=1:RETURN
1990 M1$="THE LAND OF THE MAGIC SPRING":M2$="La terre de la source magique":GOSUB 11000:PRINT DES$:IF RD(R)=1 THEN RETURN
2000 PRINT :M1$="A GORGEOUS RAINBOW ARCHES ACROSS THE SKY AND PINK EGRETS FLAP HAPPILY BY. A SIGN PAINTED ON THE WALL SAYS: 'SATISFACTION GUARANTEED OR YOUR MONEY BACK!'"
2001 M2$="Un magnifique arc-en-ciel se dessine dans le ciel et des aigrettes roses voltigent joyeusement. Un panneau peint sur le mur indique : 'Satisfait ou remboursé !'":GOSUB 10000:RD(R)=1:RETURN
2010 M1$="NONDESCRIPT LAND":M2$="Un terrain quelconque":GOSUB 11000:PRINT DES$:IF RD(R)=1 THEN RETURN
2020 PRINT :M1$="I SIMPLY CAN'T DESCRIBE A NONDESCRIPT LAND."
2021 M2$="Trop quelconque pour être décrit.":GOSUB 10000:RD(R)=1:RETURN
2030 M1$="BREAK LAND":M2$="Zone de repos":GOSUB 11000:PRINT DES$:IF RD(R)=1 THEN RETURN
2040 PRINT :M1$="LOOKING AROUND YOU SEE PICNIC TABLES AND GARBAGE CANS OVERFLOWING WITH LITTER. HOWEVER, IT APPEARS THAT YOU FRIGHTENED SOMEONE OR SOMETHING AWAY AS THEY LEFT THEIR LUNCH ON THE TABLE."
2041 M2$="En regardant autour de vous, vous voyez des tables de pique-nique et des poubelles débordantes de déchets. Il semble que vous ayez effrayé quelqu'un ou quelque chose qui a laissé son déjeuner sur la table."
2042 GOSUB 10000:RD(R)=1:RETURN
2050 M1$="LAIR OF THE DRAGON":M2$="L'antre du dragon":GOSUB 11000:PRINT DES$:GOTO 3500:REM OFF TO THE DRAGON ROUTINES
2060 REM DON'T NEED SECONDARY DESCRIPTIONS HERE
2070 M1$="TWISTY LITTLE MAZES":M2$="Petits labyrinthes tortueux":GOSUB 11000:PRINT DES$:IF RD(R)=1 THEN RETURN
2080 PRINT :M1$="JUST KIDDING. NO MAZES IN THIS GAME. IF YOU WANT TO SEE MY FEELING ON MAZES SEE THE LAST ISSUE OF 'SOFTLINE'."
2081 M2$="Je plaisante. Pas de labyrinthe dans ce jeu. Si vous voulez savoir ce que je pense des labyrinthes, lisez le dernier numéro de 'Softline'.":GOSUB 10000:RD(R)=1:RETURN
2090 M1$="ENTRANCE TO MAGIC LAND":M2$="Entrée de la terre magique":GOSUB 11000:PRINT DES$:IF RD(R)=1 THEN RETURN
2100 PRINT :M1$="MAGIC LAND IS TOO GORGEOUS FOR WORDS.":M2$="La terre magique est trop belle pour être décrite.":GOSUB 10000:RD(R)=1:RETURN
2110 M1$="COLONEL'S CAVERN":M2$="Caverne du colonel":GOSUB 11000:PRINT DES$:IF RD(R)=1 THEN RETURN
2120 PRINT :M1$="THIS APPEARS TO HAVE BEEN SOME SORT OF QUICK FOOD PLACE AT ONE TIME. THERE IS THE SMELL OF GREASE IN THE AIR."
2121 M2$="Cet endroit semble avoir été un lieu de restauration rapide. L'air sent la graisse.":GOSUB 10000:RD(R)=1:RETURN
2130 M1$="VERY SECRET CAVE":M2$="Une grotte très secrète":GOSUB 11000:PRINT DES$:IF RD(R)=1 THEN RETURN
2140 PRINT :M1$="SOMEONE HAS SPRAY PAINTED THIS CAVE AND SCRAWLED GRAFFITI ALL OVER THE WALL. I WON'T GIVE ANY MORE DETAILS AS I'M NOT THAT SORT OF COMPUTER."
2141 M2$="Quelqu'un a peint cette grotte à la bombe et gribouillé des graffitis sur le mur. Je ne donnerai pas plus de détail car je ne suis pas ce genre d'ordinateur.":GOSUB 10000:RD(R)=1:RETURN
2150 M1$="BOOM BOOM ROOM":M2$="Boum boum boum":GOSUB 11000:PRINT DES$:IF RD(R)=1 THEN RETURN
2160 PRINT :M1$="ISN'T THAT RICH?":M2$="N'est-ce pas riche ?":GOSUB 10000:RD(R)=1:RETURN
2200 REM *********************  SUBROUTINE TO CHECK NOUNS  ********************
2205 X=0
2210 IF N1$="STICK" OR N1$="BATON" THEN X=1
2220 IF N1$="SWORD" OR N1$="EPEE" THEN X=2
2230 IF N1$="SPRING" OR N1$="RESSORT" THEN X=3
2240 IF N1$="DRUMSTICK" OR N1$="BAGUETTE" THEN X=4
2250 IF N1$="MCRIB" OR N1$="SANDWICH" THEN X=5
2260 IF N1$="DRUM" OR N1$="TAMBOUR" THEN X=6
2270 IF N1$="WAGON" OR N1$="CHARIOT" THEN X=7
2275 IF X=0 THEN M1$="BE REALISTIC":M2$="Soyez réaliste":GOSUB 10000
2280 RETURN
2300 REM *********************  SUBROUTINE TO CHECK NOUNS  ********************
2310 IF X=OB(1) THEN M1$="A STICK":M2$="Un bâton":GOSUB 10000:Y=1
2320 IF X=OB(2) THEN M1$="A SWORD":M2$="Une épée":GOSUB 10000:Y=1
2330 IF X=OB(3) THEN M1$="A MAGIC SPRING":M2$="Un ressort magique":GOSUB 10000:Y=1
2340 IF X=OB(4) THEN M1$="A DRUMSTICK":M2$="Une baguette":GOSUB 10000:Y=1
2350 IF X=OB(5) THEN M1$="A MCRIB SANDWICH":M2$="Un sandwich":GOSUB 10000:Y=1
2360 IF X=OB(6) THEN M1$="A TOY DRUM":M2$="Un tambour jouet":GOSUB 10000:Y=1
2370 IF X=OB(7) THEN M1$="A DRAGON WAGON":M2$="Un chariot dragon":GOSUB 10000:Y=1
2380 IF Y=0 THEN M1$="NOTHING":M2$="Rien":GOSUB 10000
2390 PRINT
2400 Y=0
2410 RETURN
2500 REM ***********************  ROOM DATA STATEMENTS  ***********************
2510 DATA 0,6,2,0
2520 DATA 0,0,3,1
2530 DATA 0,0,4,2
2540 DATA 0,0,5,3
2550 DATA 0,10,0,4
2560 DATA 1,11,0,0
2570 DATA 0,0,8,0
2580 DATA 0,12,9,7
2590 DATA 0,0,0,8
2600 DATA 5,14,0,0
2610 DATA 6,0,12,0
2620 DATA 8,0,13,11
2630 DATA 0,0,14,12
2640 DATA 10,0,0,13
2650 DATA 0,19,16,0
2660 DATA 0,0,17,15
2670 DATA 0,0,18,16
2680 DATA 0,0,0,17
2690 DATA 15,20,0,0
2700 DATA 19,21,0,0
2710 DATA 20,22,0,0
2720 DATA 21,26,23,0
2730 DATA 0,27,24,22
2740 DATA 0,29,0,23
2750 DATA 0,30,0,0
2760 DATA 22,31,27,0
2770 DATA 23,0,28,26
2780 DATA 0,0,0,0
2790 DATA 24,0,30,28
2800 DATA 25,33,0,29
2810 DATA 26,0,0,0
2820 DATA 28,29,0,0
2830 DATA 30,0,0,0
3000 REM ************************  DRAWBRIDGE ROUTINES  ***********************
3010 IF S(11)=15 THEN PRINT :M1$="THE BRIDGE IS DOWN.":M2$="Le pont est abaissé.":GOSUB 10000:GOTO 3030
3020 PRINT :M1$="THE BRIDGE IS UP BUT THERE IS A LARGE BUTTON JUST OUT OF YOUR REACH."
3021 M2$="Le pont est levé mais il y a un grand bouton hors de portée.":GOSUB 10000
3030 PRINT :M1$="A SIGN UNDER THE BUTTON SAYS: 'UNDER NO CIRCUMSTANCES PUSH THIS BUTTON!'"
3031 M2$="Un écriteau sous le bouton indique : 'En aucun cas n'appuyez sur ce bouton !'":GOSUB 10000:RETURN
3040 PRINT :M1$="WHOEVER HEARD OF PRESSING A BUTTON WITH A "+N1$+"?"
3041 GOSUB 12000:M2$="Avez vous dejà vu quelqu'un appuyer sur un bouton avec "+AI$+N1$+" ?":GOSUB 10000:PRINT :GOTO 100
3050 PRINT :M1$= "YOU LEAP HIGH IN THE AIR AND PRESS THE BUTTON WITH YOUR HAND. THE POISONED LIZARD LIVING IN THE BUTTONHOLE PRESSES YOUR HAND WITH ITS FANGS AND...":
3051 M2$="Vous sautez en l'air appuyez sur le bouton avec votre main. Le lézard empoisonné qui vit à cet endroit plante ses crocs dans votre main et...":GOSUB 10000:GOTO 3700
3060 PRINT :M1$="I'LL PRESS THE BUTTON WITH YOUR STICK SO THE BRIDGE WILL DROP. OOPS, I'VE DROPPED THE STICK INTO THE RIVER"
3061 M2$="Je vais appuyer sur le bouton avec ton bâton pour abaisser le pont. Oups, j'ai laissé tombé le bâton dans la rivière":GOSUB 10000:OB(1)=0:S(11)=15:GOTO 100
3070 PRINT :M1$="AS YOU PASS OVER THE DRAWBRIDGE A THREE-TOED OGRE RUNS FROM UNDER THE BRIDGE CARRYING YOUR STICK. HE PRESSES THE BUTTON, CATCHES THE POISONED LIZARD FROM THE BUTTONHOLE AND EATS IT."
3071 M2$="Alors que vous passez sur le pont mobile, un ogre à trois doigts de pied surgit de dessous le pont, votre bâton à la main. Il appuie sur le bouton, attrape le lézard empoisonné et le mange.":GOSUB 10000
3080 PRINT :M1$="THE BRIDGE RAISES HIGH UP IN THE AIR, MAKING IT IMPOSSIBLE TO RETURN."
3085 M2$="Le pont se lève haut vers le ciel, rendant tout retour impossible":GOSUB 10000:RD(R)=1:RETURN
3100 REM ***********************  THRONE ROOM ROUTINES  ***********************
3110 IF OB(7)=34 AND OB(3)=34 THEN GOTO 3130
3120 PRINT :M1$="THE THRONE ROOM IS EMPTY AND FAIRLY CLEAN EXCEPT FOR A DUSTY TAPESTRY ON THE WALL. THE TAPESTRY DEPICTS A DRAGON IN A CAVE EATING A MCRIB SANDWICH."
3121 M2$="La salle du trône est vide et relativement propre, à l'exception d'une tapisserie poussiéreuse au mur. La tapisserie represente un dragon dans une grotte mangeant un sandwich ":GOSUB 10000:RETURN
3130 PRINT :M1$="THE KING JUMPS UP AND DOWN ON THE MAGIC SPRING WHICH ACTIVATES ITS CURATIVE POWERS. HE IS CURED. "
3131 M2$="Le roi saute sur le ressort magique, ce qui active ses pouvoirs curatifs. Il est guéri.":GOSUB 10000
3140 PRINT :PRINT :M1$="TO SHOW HIS GRATITUDE HE GIVES YOU THE DUSTY TAPESTRY, A DEED TO THE DRAGON'S CAVE, AND THE TAX BILL THAT THE DRAGON NEVER GOT AROUND TO PAYING ON THAT PARTICULAR PIECE OF PROPERTY."
3141 M2$="Pour vous remercier, il vous donne la tapisserie poussiéreuse, l'acte de propriété de la grotte du dragon et la facture des impôts de cette propriété que le dragon n'a jamais eu le temps de payer.":GOSUB 10000
3150 PRINT :M1$="HE ALSO GIVES YOU A COMMISSION FOR A MUCH MORE LUCRATIVE QUEST, BUT THAT IS ANOTHER ADVENTURE FOR ANOTHER TIME."
3151 M2$="Il vous donne également une avance pour une quête beaucoup plus lucrative, mais c'est une aventure pour une prochaine fois.":GOSUB 10000
3155 GOTO 3700
3200 REM ***********************  VOLCANIC ROCK ROUTINE  **********************
3210 PRINT :M1$="YOU ARE IN A WEIRD VALLEY. BLOCKING THE NORTH SIDE OF THE CLIFF IS A HUGE ROCK. THE ROCK IS CHIPPED AND PRETTY WELL BEATEN UP AND DENTED."
3211 M2$="Vous êtes dans une vallée étrange. Un énorme rocher bloque le coté nord de la falaise. Il est ébreché, assez abimé et bosselé.":GOSUB 10000
3215 PRINT :M1$="A DENTED WITCH'S KETTLE IS BOLTED DOWN HERE.":M2$="Une bouilloire de sorcière cabossée est boulonnée ici.":GOSUB 10000:RETURN
3220 PRINT :M1$="YOU PUSH AGAINST IT WITH ALL YOUR MIGHT BUT NOTHING SEEMS TO HAPPEN.":M2$="Vous poussez de toutes vos forces mais rien ne se passe.":GOSUB 10000:PRINT :GOTO 100
3230 IF N1$="KETTLE" OR N1$="BOUILLOIRE" THEN 3260
3240 M1$="YOU "+V1$+" THE SWORD AGAINST THE "+N1$+" BUT NOTHING HAPPENS."
3241 GOSUB 12000:GOSUB 12200:M2$="Vous "+V2$+" l'épée contre "+AD$+N1$+" mais rien ne se passe.":GOSUB 10000:GOTO 100
3250 PRINT :M1$="YOU "+V1$+" IT WITH YOUR HAND. NOTHING SEEMS TO HAPPEN EXCEPT YOUR HAND HURTS."
3251 GOSUB 12200:M2$="Vous le "+V2$+" avec votre main. Rien ne se passe, à part une douleur à la main.":GOSUB 10000:GOTO 100
3260 PRINT: M1$="YOU "+V1$+" THE SWORD AGAINST THE KETTLE. THE ROCK VIBRATES IN TUNE AND ROLLS ASIDE, REVEALING A PASSAGE TO THE NORTH."
3261 GOSUB 12200:M2$="Vous "+V2$+" l'épée contre la bouilloire. Le rocher vibre en harmonie et roule de coté, révelant un passage au nord.":GOSUB 10000
3270 N(18)=14:S(14)=18:GOTO 100
3300 REM *****************  MISC HITTING AND KILLING ROUTINES  ****************
3310 PRINT :M1$="WHAT, YOU DARE TO "+V1$+" IN THE PRESENCE OF THE KING? THE GUARDS SEIZE YOU AND DRAG YOU OFF KICKING AND SCREAMING TO BE FED TO THE DRAGON."
3311 M2$="Comment, vos osez "+V1$+" en présence du roi ? Les gardes vous saisissent et vous trainent, criant et vous débatant, pour nourrir le dragon.":GOSUB 10000:PRINT :GOTO 3700
3320 REM *************************  BEATING THE DRUM  *************************
3330 IF OB(4)=34 AND OB(6)=34 THEN GOTO 3370
3340 IF OB(4) <> 34 AND OB(6) <> 34 THEN M1$="YOU DON'T HAVE THAT.":M2$="Vous n'en avez pas.":GOSUB 10000:GOTO 100
3350 IF OB(4)=34 THEN PRINT :M1$="PERHAPS IF YOU HAD A DRUM...":M2$="Peut-être si vous aviez un tambour...":GOSUB 10000:GOTO 100
3360 IF OB(6)=34 THEN PRINT :M1$="YOU HIT THE DRUM WITH YOUR HAND AND PRODUCE A MUFFLED THUD.":M2$="Vous tappez sur le tambour avec votre main ce qui produit un bruit sourd.":GOSUB 10000:GOTO 100
3370 IF R=28 THEN GOTO 3620
3380 PRINT :M1$="KABOOM, KABOOM. HITTING THE DRUM WITH THE DRUMSTICK PRODUCES A NICE BEAT. YOU'RE NO GENE KRUPA (WHO?), BUT YOU'LL DO IN A PINCH."
3381 M2$="Boum, boum. Frapper le tambour avec la baguette produit un bon rythme. Tu n'es pas Gene Krupa (qui ?), mais tu feras l'affaire.":GOSUB 10000:GOTO 100
3390 REM ************************  GETTING THE SPRING  ************************
3400 PRINT :M1$="YOU PUSH AND TUG THE MAGIC METAL SPRING INTO THE WAGON AND FIND THAT YOU CAN NOW TRANSPORT IT. AREN'T YOU CLEVER, YOU RASCAL YOU."
3401 M2$="Vous poussez et tirez le ressort métallique magique dans le chariot et constatez que vous pouvez maintenant le transporter. Vous êtes un petit malin.":GOSUB 10000:GOTO 890
3410 PRINT :M1$="YOU CAN'T SEEM TO MOVE THE HEAVY SPRING.":M2$="Vous ne parvenez pas à déplacer le lourd ressort.":GOSUB 10000:GOTO 890
3420 OB(3)=R:PRINT :M1$="OH, OH, WITHOUT HAVING THE WAGON THE HEAVY METAL SPRING TUMBLES TO THE FLOOR."
3425 M2$="Zut, sans le chariot le lourd ressort métallique tombe au sol.":GOSUB 10000:GOTO 1070
3500 REM *************************  DRAGON ROUTINES   *************************
3510 PRINT:M1$="A HUGE, FIERCE, HUNGRY RED DRAGON GETS UP FROM ITS NEST IN THE MIDDLE OF THE CAVE.":M2$="Un enorme dragon rouge et affame se leve au milieu de la grotte.":GOSUB 10000
3515 PRINT:M1$="IT SNORTS FIRE FROM ITS NOSTRILS, BURPS, DOES A BIT OF THE OLD SOFT SHOE, AND SAYS TO YOU:"
3516 M2$="Il exhale du feu par ses narines, rotte et vous dis familièrement :":GOSUB 10000
3520 PRINT:M1$="'BOY I'M GLAD YOU MADE IT. NOT ONLY AM I BORED, BUT I'M STARVING. SHALL WE DANCE, OR SHALL YOU FEED ME FIRST?'"
3521 M2$="Mon Dieu, je suis content que tu sois venu. Non seulement je m'ennuie, mais je meurs de faim. On danse, ou tu me nourris d'abord ?":GOSUB 10000:GOTO 100
3530 PRINT :M1$="THE DRAGON LOOKS AT YOU IN DISGUST. HE GETS UP AND SAYS: 'THAT'S AWFUL. THIS IS HOW YOU DO IT.' HE IS EXTREMELY CLUMSY AND SAYS,'I JUST CAN'T SEEM TO GET THE TEMPO RIGHT.'"
3531 M2$="Le dragon vous regarde avec dégout. Il se lève et dit : 'C'est affreux. C'est comme ça qu'il faut faire.' Il est extremement maladroit et dit 'Je n'arrive pas à trouver le bon tempo.'":GOSUB 10000
3540 PRINT :M1$="HE IS GETTING MADDER AND MADDER. HE LOOKS AT YOU, SNARLS, AND SAYS: 'WELL, IF YOU WON'T HELP ME.....'CHOMP!!"
3541 M2$="Il devient de plus en plus furieux. Il vous regarde, grogne et dit :'Eh bien si vous ne m'aidez pas.....' Crunch!!":GOSUB 10000:GOTO 3700
3550 PRINT :M1$="YOU WHIP OUT YOUR TRUSTY SWORD AND LUNGE. THE DRAGON LOOKS AT YOU AND SAYS: 'HOW THOUGHTFUL, HE BROUGHT HIS OWN TOOTHPICK.' .....CHOMP!!!!"
3556 M2$="Vous sortez votre fidèle épée et vous élancez. Le dragon vous regarde et dit :'Comme il est gentil, il a apporte son propre cure-dent.' ....Crunch !!!!":GOSUB 10000:GOTO 3700
3560 PRINT :M1$="YOU ATTACK THE DRAGON FURIOUSLY WITH YOUR BARE HANDS. THE DRAGON CHUCKLES AT YOU..."
3561 M2$="Vous attaquez le dragon furieusement à main nue. Le dragon se moque de vous...":GOSUB 10000
3565 PRINT:M1$="'IF YOU HAD A MAGIC SWORD YOU MIGHT HAVE HAD A CHANCE.' .....CHOMP!!!!"
3566 M2$="'Si vous aviez une épée magique vous auriez eu une chance.' .....Crunch !!!!":GOSUB 10000:GOTO 3700
3570 PRINT :M1$="THE DRAGON NOTICES YOU REENTER. 'MY, THAT WAS A NICE DANCE. NOW, I'M HUNGRY!' .....CHOMP!!!!"
3571 M2$="Le dragon remarque que vous êtes ré-entré. 'Ma foi, c'etait une belle dance. Maintenant j'ai faim !' .....Crunch !!!!":GOSUB 10000:GOTO 3700
3580 PRINT :M1$="THE DRAGON GOBBLES UP THE "+N1$+". 'YUMMY, GOOD! WHAT (OR WHO) IS NEXT?'"
3581 GOSUB 12000:M2$="Le dragon engloutit "+AD$+N1$+". 'Miam, c'est bon ! Quoi (ou qui) ensuite ?'":GOSUB 10000:GOTO 100
3590 X=0:R=28:PRINT :M1$="YOU'RE TRAPPED IN THE DRAGON'S CAVE. IF YOU DON'T DO SOMETHING SOON YOU'RE IN BIG TROUBLE."
3591 M2$="Vous êtes pris au piege dans la grotte du dragon. A moins d'agir rapidement vous allez avoir de gros ennuis.":GOSUB 10000
3595 TC=TC+1:PRINT :M1$="YOU'VE ONLY GOT "+STR$(5-TC)+" MINUTES LEFT."
3596 M2$="Il vous reste seulement "+STR$(5-TC)+" minutes.":GOSUB 10000
3600 IF TC<5 THEN GOTO 100
3610 PRINT :M1$="OH, NO...THE DRAGON'S GETTING UP. HE'S GOING TO ....CHOMP!!!!"
3611 M2$="Oh non... Le dragon se lève. Il va vous .....Crunch !!!":GOSUB 10000:GOTO 3700
3620 PRINT :M1$="WOW!!! THE DRAGON IS FASCINATED.":M2$="Ouah !!! Le dragon est fasciné.":GOSUB 10000
3625 M1$="HE GETS UP, TAKES THE DRUM AND DRUMSTICK, SNIFFS IT, AND BEGINS TO DANCE AND BEAT THE DRUMP IN 3/4 TIME."
3626 M2$="Il se lève, prend le tambour et la baguette, les renifle puis dance en battant le tambour en 3/4 temps.":GOSUB 10000
3630 PRINT :M1$="WHILE HE'S SO OCCUPIED, YOU NOTICE HE HAS MOVED AWAY FROM A PASSAGE TO THE SOUTH."
3631 M2$="Etant ainsi occupé, vous remarquez qu'il a libéré un passage en direction du sud.":GOSUB 10000
3635 S(28)=32:GOTO 100
3700 PRINT :PRINT "AU REVOIR...GAME OVER...":END
9999 REM *********   SUB TO PRINT MSG DEPENDING ON SELECTED LANGAGE   *********
10000 IF FR=1 THEN M$=M2$:GOTO 10020
10010 M$=M1$
10020 IF NL=1 THEN GOSUB 20000:GOTO 10100
10030 NL=1:PRINT M$;
10100 RETURN
10999 REM ****** SUB THAT AFFECT M1$ OR M2$ TO DES$ DEPENDING ON LANGAGE ******
11000 IF FR=1 THEN DES$=M2$:RETURN
11010 DES$=M1$
11030 RETURN
11999 REM ******************** GET ARTICLE FOR FRENCH NOUN ********************
12000 IF N1$="EPEE" THEN AD$="l'":AI$="une ":GOTO 12100
12010 IF N1$="BOUILLOIRE" OR N1$="BAGUETTE" OR N1$="PIERRE" THEN AD$="la ":AI$="une ":GOTO 12100
12020 AD$="le ":AI$="un "
12100 RETURN
12199 REM ****************** VERBE AU 2EME GROUPE POUR LA VF ******************
12200 V2$=""
12205 IF V1$="PRENDRE" THEN V2$="prennez"
12210 IF V1$="APPUYER"  THEN V2$="appuyez"
12220 IF V1$="PRESSER" THEN V2$="pressez"
12230 IF V1$="POSER"THEN V2$="posez"
12240 IF V1$="QUITTER" THEN V2$="quittez" 
12250 IF V1$="FRAPPER" THEN V2$="frappez"
12260 IF V1$="ATTAQUER" THEN V2$="attaquez"
12270 IF V1$="TUER" THEN V2$="tuez"
12280 IF V1$="MANGER" THEN V2$="mangez"
12290 IF V1$="DONNER" THEN V2$="donnez"
12300 IF V1$="DANSER" THEN V2$="dansez"
12310 IF V1$="EXAMINER" THEN V2$="examinez"
12320 IF V1$="REGARDER" THEN V2$="regardez"
12400 RETURN
19999 REM ************************* SUB FANCY PRINT M$ ************************
20000 LM = LEN(M$)
20010 IB = 1 : IE = 1
20020 IF (IE < LM + 1) THEN 20030
20021 GOTO 20150
20030 IF (IB < LM + 1) AND (MID$(M$,IB,1) =" ") THEN IB = IB + 1 : GOTO 20030
20040 IF IB = LM THEN PRINT: GOTO 20150
20050 IE = IB + CL
20060 IF IE > LM THEN PRINT MID$(M$,IB, IE-IB): GOTO 20150
20070 IF (IE > IB) AND (MID$(M$,IE,1) <> " ") THEN IE = IE - 1: GOTO 20070
20080 IF IE = IB THEN IE = IB + CL
20090 PRINT MID$(M$, IB, IE-IB);
20095 IF (IE-IB) <= CL THEN PRINT
20100 IB = IE + 1
20140 GOTO 20020
20150 RETURN
29999 REM ****************************** INTRO ********************************
30000 CLS
30100 PRINT TAB(3);:COLOR 0,FCOL:PRINT " THE HORRIBLE ROTTEN DANCING DRAGON ":COLOR FCOL,0:PRINT:PRINT TAB(25);"...STRIKES!!!"
30101 PRINT:PRINT
30102 PRINT TAB(6);"                \||/"
30103 PRINT TAB(6);"                |  @___oo"
30104 PRINT TAB(6);"      /\  /\   / (__,,,,|"
30105 PRINT TAB(6);"     ) /^\) ^\/ _)"
30106 PRINT TAB(6);"     )   /^\/   _)"
30107 PRINT TAB(6);"     )   _ /  / _)"
30108 PRINT TAB(6);" /\  )/\/ ||  | )_)"
30109 PRINT TAB(6);"<  >      |(,,) )__)"
30110 PRINT TAB(6);" ||      /    \)___)\"
30111 PRINT TAB(6);" | \____(      )___) )___"
30112 PRINT TAB(6);"  \______(_______;;; __;;;"
30120 LOCATE 19,1:PRINT "Softline by Ken Rose...............1983"
30121                PRINT "Adapt. français-anglais D.Rioual...2025"
30140 LOCATE 23,1:PRINT "Game in English (1) Jeu en français (2)";
30150 A$ = INPUT$(1)
30170 IF A$="1" THEN FR=0:GOTO 30200
30180 IF A$="2" THEN FR=1:GOTO 30200
30190 GOTO 30150
30200 CLS:RETURN