0 REM <===== LA MAISON DU SAVANT FOU 2 =====>
1 REM Adaptation pour Apple II - 24/04/2024
2 REM 
3 REM
10 HOME
20 DIM B$(17)
25 B$(2)="O01E03N05SR"
30 B$(3)="O02E04N06SR"
35 B$(4)="O03ERN09SR"
40 B$(5)="ORE07N10S02"
45 B$(7)="O05E08N14S06"
50 B$(9)="O08ERN11S04"
55 B$(13)="O12E14NRS10"
60 B$(14)="O13E15N16S07"
61 B$(15)="O14ERS11N17"
62 B$(17)="OKE15S16N18"
70 VIE = 6
100 GOSUB 9600
102 HOME 
103 PRINT "VOUS ETES DEVANT LA RESIDENCE SECONDAIREDE COSINUS.":PRINT "QUE FAITE-VOUS ?"
105 FOR R=1 TO 5
110 GET Z$
120 IF Z$="E" OR Z$="e" THEN 190
130 IF Z$="R" OR Z$="r" THEN PRINT "ALLONS, UN PEU DE COURAGE..."
140 NEXT R
190 HOME
191 PRINT "LA PORTE VIENT DE SE REFERMER DERRIERE":PRINT "VOUS. VOUS ETES MON PRISONNIER...":PRINT "HE, HE, HE..."
192 GOSUB 10000
200 IF VIE = 0 THEN 9900
201 HOME
202 PRINT "(VOUS AVEZ ";VIE;" VIE(S))":PRINT
205 A=3
210 ON A GOSUB 7000,7010,7020,7030,7040,7050,7060,7070,7080,7090,7100,7110,7120,7130,7140,7150,7160,7170
220 PRINT : PRINT "QUE FAITES-VOUS ?"
230 GET A$ : IF A$="" THEN 230
240 FOR N=1 TO 12
250 IF MID$(B$(A),N,1)=A$ THEN 300
255 NEXT N
260 HOME 
265 PRINT "ERREUR"
266 GOSUB 10000
275 HOME
280 GOTO 210
300 HOME
312 IF MID$(B$(A),N+1,1)="R" THEN 260
314 IF MID$(B$(A),N+1,1)="K" THEN 9000
315 PRINT "O.K."
320 A=VAL(MID$(B$(A),N+1,2))
330 GOSUB 10000
335 HOME
340 GOTO 210
7000 PRINT "VOUS ETES TOMBE DANS UN BAC D'ACIDE.":PRINT "VOUS ETES RONGE JUSQU'AUX OS..."
7003 GOSUB 10000
7005 VIE = VIE - 1 : GOTO 200
7006 GOTO 9900
7010 PRINT "VOUS ETES DANS LA CUISINE. UNE ODEUR":PRINT "VOUS PIQUE LE NEZ.IL Y A UNE PORTE A":PRINT"L'OUEST,A L'EST ET AU NORD."
7015 RETURN
7020 PRINT "VOUS ETES DANS L'ENTREE DE LA MAISON.":PRINT "IL Y A UNE PORTE A L'EST, A L'OUEST ET":PRINT"AU NORD."
7025 RETURN
7030 PRINT "VOUS ETES DANS LA PENDERIE. IL Y A UNE":PRINT "TRAPPE AU NORD ET UNE PORTE A L'OUEST."
7035 RETURN
7040 PRINT "VOUS VOUS TROUVEZ DANS LA CHAMBRE DE":PRINT "COSINUS. IL Y A UNE PORTE A L'EST,AU SUDET AU NORD."
7045 RETURN
7050 PRINT "VOUS VOUS ETES FAIT EMBROCHE PAR DES":PRINT "PICS, VOUS ETES MORT."
7055 GOTO 7003
7060 PRINT "VOUS ETES AU SALON. IL Y A DE L'ELEC-":PRINT "TRICITE DANS L'AIR...":PRINT "IL Y A UNE PORTE POUR CHAQUE DIRECTION."
7065 RETURN
7070 PRINT "UN LASER,PLACE SOURNOISEMENT SUR LE MUR":PRINT "VOUS DESINTEGRE..."
7075 GOTO 7003
7080 PRINT "VOUS VOUS TROUVEZ DANS LA SALLE DE BAIN.CA SENT LE GAZ.IL Y A UNE PORTE AU NORD,AU SUD ET A L'OUEST."
7085 RETURN
7090 PRINT "LA PORTE DONNAIT SUR UN PRECIPICE.":PRINT "VOUS VOUS ECRASEZ EN BAS..."
7095 GOTO 7003
7100 PRINT "VOUS ETES AXPHIXIE DANS LA CHAMBRE A GAZET VOUS ETES MORT."
7105 GOTO 7003
7110 PRINT "UN MANIAQUE CACHE DERRIERE LA PORTE VOUSPULVERISE LA TETE A COUP DE MASSE..."
7115 GOTO 7003
7120 PRINT "VOUS VOUS TROUVEZ AU FUMOIR.IL YA UNE":PRINT "PORTE A L'EST,AU SUD ET A L'OUEST.":PRINT "ATTENTION, ON ENTEND UNE RESPIRATION."
7125 RETURN
7130 PRINT "VOUS ETES DANS LA CHAPELLE.":PRINT "IL Y A UNE PORTE DANS CHAQUE DIRECTION." 
7135 RETURN
7140 PRINT "VOUS AVEZ ACCEDE A LA PIECE SECRETE.":PRINT "CA SENT LE GAZ. IL Y A UNE PORTE AU SUD,A L'OUEST ET UNE TRAPPE AU NORD."
7145 RETURN
7150 PRINT "VOUS ETES BROYE DANS UN ETAU.":PRINT "ET VOUS ETES MORT."
7155 GOTO 7003
7160 PRINT "BRAVO,PAR LE BIAIS DU SOUS-TERRAIN,VOUS":PRINT "ETES AU LABO. MAIS ATTENTION, CA SENT LADYNAMITE. IL Y A UNE PORTE DANS CHAQUE":PRINT "DIRECTION."
7165 RETURN
7170 PRINT "EN OUVRANT LA PORTE, VOUS AVEZ RENVERSE":PRINT "DES TUBES A ESSAIS CONTENANT DE LA":PRINT "NITROGLYCERINE QUI A EXPLOSE":PRINT "NATURELLEMENT ET VOUS AVEC."
7175 GOTO 7003
9000 PRINT "BRAVISSIMO, VOUS ETES DOUE D'UN SENS DU":PRINT "HASARD INCROYABLE. MAIS MALHEUREUSEMENT,LA PORTE EST VERROUILLEE PAR UN CADENAS":PRINT "ELECTRONIQUE. INSERREZ-Y VOTRE CARTE EN":PRINT "APPUYANT SUR 'I'." 
9005 GET I$
9010 HOME
9020 PRINT "VOUS N'AVEZ VRAIMENT PAS DE CHANCE :":PRINT "LA CARTE QUE VOUS AVEZ UTILISE A UN CODEQUI N'EST PAS BON."
9030 PRINT "POUR CORRIGER CE CODE, VOUS UTILISEREZ":PRINT "UN STYLO MAGNETIQUE AVEC UN CODE DE 1 A":PRINT "99.":PRINT "L'ORDINATEUR DE CONTROLE VOUS DIRA SI":PRINT "VOUS APPROCHEZ DU CODE." 
9035 PRINT
9036 PRINT "VOUS AVEZ 6 CHANCES.":PRINT 
9040 X=INT (RND(0)*99)+1
9043 FOR H=1 TO 5
9045 INPUT D
9050 IF D<X THEN PRINT "LE CODE EST PLUS GRAND."
9055 IF D>X THEN PRINT "LE CODE EST PLUS PETIT."
9060 IF D=X THEN GOTO 9100
9061 NEXT H
9062 HOME
9065 PRINT "DESOLE, LA CARTE MAGNETIQUE EST FOUTUE.":PRINT "VOUS ALLEZ VOUS TROUVER DANS UNE PIECE":PRINT "AU HAZARD..."
9066 GOSUB 10000
9070 Z=INT (RND(0)*14)+1
9075 IF Z=3 OR Z=1 OR Z=6 OR Z=8 OR Z=10 OR Z=11 OR Z=12 THEN GOTO 9070
9080 LET A=Z
9090 GOTO 205
9100 HOME
9110 PRINT "BRAVO, FELICITATION.VOUS AVEZ REUSI A":PRINT "SORTIR DE CES LABYRINTHES. C'EST DU":PRINT "JAMAIS VU DANS L'HISTOIRE DU JEU":PRINT "D'AVENTURE." 
9112 GOSUB 10000
9115 END
9600 HOME
9620 PRINT "LA MAISON DE COSINUS - DEUXIEME PARTIE.":PRINT
9625 PRINT "APRES LES PERIPECIES DE LA PREMIERE":PRINT "MAISON, VOUS VOUS TROUVEZ DEVANT LA":PRINT "RESIDENCE SECONDAIRE DE COSINUS":PRINT "(ENCORE PLUS AFFREUX)."
9630 PRINT
9635 PRINT "(AVEC 6 VIES)"
9636 PRINT
9640 PRINT "TENTEZ-VOUS VOTRE CHANCE ?"
9645 PRINT
9647 FOR R=1 TO 5
9650 GET I$
9660 IF I$="O" OR I$="o" THEN RETURN
9670 IF I$="N" OR I$="n" THEN PRINT "ALLONS,UN PEU DE COURAGE." 
9680 NEXT R
9690 HOME
9700 PRINT "ON NE PEUT PAS ECHAPPER AU SAVANT COSINUS..." 
9710 GOSUB 10000
9730 RETURN
9900 HOME
9910 PRINT "DESOLE MAIS VOUS N'AVEZ PLUS DE VIE..."
9920 GOSUB 10000
9930 PRINT "AU REVOIR..."
9940 PRINT "J'AI BIEN RIGOLE."
9950 END
9999 REM <----- TEMPO ----->
10000 FOR W=1 TO 1400 : NEXT W
10010 RETURN