0 REM <===== LA MAISON DU SAVANT FOU 1 =====>
1 REM Adaptation pour Apple II - 24/04/2024
2 REM 
3 REM
10 HOME
20 DIM B$(13)
25 B$(2)="O01E03N07SR" 
30 B$(4)="O03E05N08SR"
35 B$(5)="O04E05N09SR"
40 B$(7)="O06E08N10S02"
45 B$(8)="O07E09N11S04"
50 B$(10)="O06E12NRS07"
55 B$(12)="O10E13NRS11" 
60 B$(13)="O12EKS09NR"
70 VIE = 5
100 GOSUB 9600
102 HOME
105 PRINT "VOUS ETES DEVANT UNE MAISON. QUE FAITES VOUS ?"
110 GET Z$
120 IF Z$="E" OR Z$="e" THEN 190
130 IF Z$="R" OR Z$="r" THEN PRINT "ALLONS, UN PEU DE COURAGE..."
140 GOTO 110
190 HOME
191 PRINT "LA PORTE VIENT DE SE REFERMER DERRIERE":PRINT "VOUS..."
195 GOSUB 10000
200 IF VIE = 0 THEN 9900
201 HOME
202 PRINT "(VOUS AVEZ ";VIE;" VIE(S))":PRINT
205 A=4
210 ON A GOSUB 7000,7010,7020,7030,7040,7050,7060,7070,7080,7090,7100,7110,7120
220 PRINT : PRINT "QUE FAITES-VOUS ?"
230 GET A$ : IF A$="" THEN 230
240 FOR N=1 TO 12
250 IF MID$(B$(A),N,1)=A$ THEN 300
255 NEXT N
260 HOME
265 PRINT "ERREUR"
270 GOSUB 10000
275 HOME  
280 GOTO 210
300 HOME
312 IF MID$(B$(A),N+1,1)="R" THEN 260
314 IF MID$(B$(A),N+1,1)="K" THEN 9000
315 PRINT "O.K."
320 A=VAL(MID$(B$(A),N+1,2))
325 GOSUB 10000
335 HOME
340 GOTO 210 
7000 PRINT "UN PIEU, LANCE DU MUR, VOUS TRANSPERCE L'ESTOMAC ET VOUS PLANTE SUR LA PORTE."
7003 GOSUB 10000
7005 VIE = VIE - 1 : GOTO 200
7006 GOTO 9900
7010 PRINT "VOUS ETES DANS LA CUISINE. IL Y A UNE":PRINT "PORTE L'OUEST, A L'EST ET AU NORD."
7015 RETURN
7020 PRINT "DERRIERE LA PORTE SE TROUVAIT UNE USINE":PRINT "DE CORNED-BEEF.":PRINT "VOUS RESSORTEZ EN CHAIR A PATE..." 
7025 GOTO 7003
7030 PRINT "VOUS ETES DANS L'ENTREE DE LA MAISON.":PRINT "IL Y A UNE PORTE A L'EST, A L'OUEST ET":PRINT"AU NORD."
7035 RETURN
7040 PRINT "VOUS ETES DANS LA PENDERIE. IL Y A UNE":PRINT "TRAPPE AU NORD ET UNE PORTE A L'OUEST.": PRINT"CA SENT LE GAZ."
7045 RETURN
7050 PRINT "LA PORTE DONNAIT SUR LE VIDE. VOUS VOUS":PRINT "ECRASEZ LAMENTABLEMENT EN BAS..."
7055 GOTO 7003
7060 PRINT "VOUS VOUS TROUVEZ DANS LA CHAMBRE DE":PRINT "COSINUS. ON SENT DU VENT.":PRINT "IL Y A UNE PORTE POUR CHAQUE DIRECTION."
7065 RETURN
7070 PRINT "VOUS ETES AU SALON. CA SENT LE GAZ.":PRINT "IL Y A UNE PORTE POUR CHAQUE DIRECTION."
7075 RETURN
7080 PRINT "VOUS ETES AXPHIXIE DANS LA CHAMBRE A GAZET VOUS ETES MORT."
7085 GOTO 7003
7090 PRINT "VOUS VOUS TROUVEZ AU FUMOIR.IL Y A UNE":PRINT "PORTE A L'EST, AU SUD ET A L'OUEST."
7095 RETURN
7100 PRINT "UNE BETE EXTRAVAGANTE VOUS DECHIQUETTE":PRINT "LE CORPS."
7105 GOTO 7003
7110 PRINT "VOUS AVEZ ACCEDE A LA PIECE SECRETE.":PRINT "CA SENT LE SANG.":PRINT "IL Y A UNE PORTE AU SUD, A L'OUEST ET":PRINT "UNE TRAPPE A L'EST."
7115 RETURN
7120 PRINT "BRAVO,VOUS ETES AU LABO MAIS ATTENTION,":PRINT "CA SENT LA POUDRE. IL Y A UNE PORTE AU":PRINT "SUD, A L'EST ET A L'OUEST."
7125 RETURN
9000 PRINT "VOUS ETES PRESQUE AU BOUT DE VOS PEINES.":PRINT "UNE BOMBE A ETE PLACEE ET POUR LA DESA-"
9005 PRINT "MORCER, VOUS COMPOSEREZ UN CODE DE":PRINT "1 A 50. MAIS VOUS N'AVEZ QUE CHANCES."
9010 X=INT(RND(0)*50)+1
9020 FOR F=1 TO 5
9030 INPUT A
9035 PRINT
9040 IF A=X THEN GOTO 9100
9045 IF A>X THEN PRINT "LE CODE EST PLUS PETIT."
9050 IF A<X THEN PRINT "LE CODE EST PLUS GRAND."
9055 NEXT F
9060 HOME
9065 PRINT "LA MAISON A VOLE EN ECLAT. VOUS ETES":PRINT "MORT, C'EST DOMMAGE, SI PRES DU BUT..."
9066 GOSUB 10000
9070 VIE = VIE - 1 : GOTO 200
9080 GOTO 9900
9100 HOME
9110 PRINT "BRAVO, VOUS ETES SORTI DE CETTE MAISON":PRINT "INFERNALE. UNE SURPRISE VOUS ATTEND..."
9115 GOSUB 10000
9116 HOME
9120 PRINT "APPUYEZ SUR UNE TOUCHE POUR CHARGER LA":PRINT "SUITE..."
9130 GET X$:PRINT
9140 PRINT CHR$(4);"RUN COSINUS2"
9150 REM
9160 END
9599 REM <----- INTRO ----->
9600 HOME
9620 PRINT "LA MAISON DE CE FOU DE SAVANT COSINUS"
9625 PRINT
9627 PRINT "VOUS ALLEZ ETRE ENFERME DANS UNE MAISON":PRINT "DIABOLIQUE EN ESSAYANT DE TROUVER LA":PRINT "SORTIE..."
9630 PRINT 
9635 PRINT "(AVEC ";VIE;" VIES)"
9636 PRINT
9640 PRINT "TENTEZ-VOUS VOTRE CHANCE ? (O/N)"
9645 PRINT
9647 FOR T=1 TO 5
9650 GET I$
9660 IF I$="O" OR I$="o" THEN RETURN
9670 IF I$="N" OR I$="n" THEN PRINT "ALLONS, UN PEU DE COURAGE." 
9680 NEXT T
9685 PRINT:PRINT "ON N'ECHAPPE PAS AU SAVANT COSINUS..." 
9687 GOSUB 10000
9690 RETURN
9900 HOME
9910 PRINT "DESOLE MAIS VOUS N'AVEZ PLUS DE VIE..."
9920 GOSUB 10000
9930 END
9999 REM <----- TEMPO ----->
10000 FOR W=1 TO 1400 : NEXT W
10010 RETURN