10 REM *************************
20 REM *     AMITYVILLE.II     *
25 REM *                       *
30 REM *     DE XAVIER LERAY   *
40 REM *     ET NICOLAS GOHIN  *
43 REM *************************
45 REM * AMELIORATION + DEBUG  *
46 REM * D. RIOUAL LE 31/07/23 *
60 REM **********************************
90 REM  DATAS
91 REM **********************************
92 REM ----- DATAS PRESENTATION ----------
93 DATA 1576,1,1595,217,1615,-1,1596,214,1576,1,1594,212
94 DATA 1615,-1,1597,201,1576,1,1593,201,1615,-1,1598,204,1576,1,1592,205
95 DATA 1615,-1,1599,204,1576,1,1591,193,1615,-1,1600,197,99,,,
97 PRINT CHR$(4)"PR#3":GOSUB 6000
100 DIM C$(3): FORI=1 TO 3:READ C$(I):NEXT
101 REM ---------- DATAS JEU ----------
103 DATA "fusil de chasse","revolver","coupe-coupe"
115 DIM B$(31):A$ = "    D'accord" 
120 FOR I= 1 TO 22: READ B$(I):NEXT I
121 DATA " Vous allez au nord"," Vous allez au sud"," Vous allez a l'est"
122 DATA " Vous allez a l'ouest"," Vous montez les escaliers"
123 DATA " Vous descendez les escaliers"
124 DATA " Vous attendez"," Vous appuyez sur le bouton vert"
125 DATA " Vous appuyez sur le bouton rouge"," Vous ne faites rien"
126 DATA " Vous partez"," Vous entrez dans le manoir"
127 DATA " Vous allez au nord-est"," Vous allez au centre-est"
128 DATA " Vous allez au sud-est"," Vous allez nord-ouest"
129 DATA " Vous allez au centre-ouest"," Vous allez au sud-ouest"
130 DATA " Vous essayez de l'ouvrir"," Vous saisissez une arme"
132 DATA " Vous prenez la clef"
133 DATA " Vous ramassez l'objet"
155 GOTO 200
160 PRINT : PRINT "> Que faites-vous ? ";: GET Q$:I = VAL (Q$): IF Q$ = "O" THEN PRINT: PRINT : PRINT " Vous possedez ";PO;" pieces d'OR.": GOTO160
161 IF Q$="F" THEN HOME:GOTO 270
162 IF Q$="V" THEN I=0:RETURN
163 IF Q$<>"I" THEN 190
170 PRINT: PRINT : PRINT " Vous avez sur vous :": PRINT: PRINT:PRINT "* ";PO;" pieces d'OR.": PRINT
171 IF T=1 THEN PRINT "* Une paire de tenailles.": PRINT
172 IF SM=1 THEN PRINT "* Une scie a metaux.": PRINT
173 IF PB=1 THEN PRINT "* Un pied de biche.": PRINT
174 IF CL=1 THEN PRINT "* Une clef en metal.": PRINT
175 IF CO=1 THEN PRINT "* Une clef en OR.": PRINT
176 IF BR=1 THEN PRINT "* Un briquet.": PRINT
177 IF MU=1 THEN PRINT "* Une boite de munitions.": PRINT
178 IF C$<>"" THEN PRINT "* Une arme: ";C$;".": PRINT
179 IF SS=1 THEN PRINT "* Un sac de sable.": PRINT
189 GOTO160
190 IF I = 0 THEN 160
195 RETURN
200 HOME : PRINT : PRINT "Vous vous promenez dans la campagne. Votre voiture tombe en panne."
210 PRINT "La nuit commence a tomber. En haut d'une colline, vous voyez un MANOIR."
220 PRINT : PRINT "Un violent orage se prepare."
230 PRINT : PRINT " 1 Vous vous dirigez vers le MANOIR": PRINT " 2";B$(10): GOSUB 160
240 IF I= 1 THEN 300
250 IF I < > 2 THEN 200
260 HOME : VTAB 6: PRINT "Un eclair s'abat sur un arbre.":PRINT "Celui-ci vous tombe dessus et vous ecrase !"
270 NORMAL : VTAB 12: HTAB 32: PRINT "VOUS MOURREZ !!!"
280 END
300 HOME : PRINT : PRINT "Vous devant la porte d'entree du MANOIR."
310 PRINT : PRINT " 1";B$(7):PRINT " 2";B$(12): GOSUB160
320 IF I = 1 THEN HOME : VTAB6: PRINT "Un eclair vous foudroie. Vous etes brule vif !": GOTO 270
330 IF I < > 2 THEN 3110
340 GOTO 355
345 REM ****************************
346 REM HALL D'ENTREE
347 REM ****************************
350 GOTO 361
355 HOME : PRINT : PRINT "Vous dans le HALL. La porte se referme violemment derriere vous."
360 PRINT "Vous ne pouvez plus sortir.": PRINT : PRINT " 1";B$(3): PRINT " 2";B$(4):GOSUB 160: GOTO 365 
361 HOME : PRINT : PRINT "Vous etes dans le HALL": PRINT :PRINT " 1";B$(3): PRINT " 2";B$(4): GOSUB 160
365 IF I= 1 THEN 500
370 IF I= 2 THEN 400
380 GOTO 350
395 REM ****************************
396 REM PIECE VIDE
397 REM ****************************
400 HOME : PRINT : PRINT "Vous vous trouvez dans une piece vide."
410 PRINT : PRINT " 1";B$(1): PRINT" 2";B$(3): PRINT " 3";B$(6): GOSUB 160
420 IF I = 3 THEN 1000
425 IF I = 2 THEN 361
427 IF I < > 1 THEN 400
430 GOTO 600
490 REM ***********************************
493 REM COULOIR
495 REM ***********************************
500 HOME : PRINT : PRINT "Vous etes dans un couloir. Il y a un escalier qui mene au 1er etage.": PRINT : PRINT " 1";B$(1): PRINT " 2";B$(4):PRINT" 3";B$(5): GOSUB 160
510 IF I = 1 THEN 550
515 IF I = 2 THEN 361
520 IF I = 3 THEN 2500
521 GOTO 500
540 REM ****************************
544 REM PETIT SALON
546 REM ****************************
550 HOME : PRINT : PRINT "Vous etes dans un petit salon."
555 IF BR = 0 THEN PRINT "Vous voyez un briquet pose sur la table."
560 PRINT : PRINT " 1";B$(1): PRINT" 2";B$(2): PRINT" 3";B$(3): IF BR = 0 THEN PRINT " 4";B$(22)
563 GOSUB 160
565 IF I = 1 THEN 700
567 IF I = 3 THEN 800
570 IF I = 2 THEN 500
575 IF I = 4 AND BR = 0 THEN BR= 1: PRINT : PRINT A$: FOR I= 1 TO 2000: NEXT : GOTO 550
580 GOTO 550
590 REM *******************************
592 REM BUREAU
594 REM *******************************
600 HOME : PRINT : PRINT "Vous etes dans un bureau. Il y a une armoire.": PRINT : PRINT" 1";B$(2):PRINT " 2";B$(19): GOSUB 160
610 IF I = 1 THEN 400
615 IF I < > 2 THEN 600
620 HOME : PRINT : PRINT "L'armoire dissimulait un passage secret.": PRINT
625 PRINT "Vous vous retrouvez a l'etage superieur."
630 FOR I = 1 TO 3100: NEXT : GOTO 2000
690 REM ****************************
692 REM SALLE A MANGER
694 REM ****************************
700 HOME : PRINT : PRINT "Vous etes dans la salle a manger.": PRINT "La table est dressee": PRINT : PRINT " 1 Vous mangez": PRINT " 2";B$(2): PRINT" 3";B$(4): PRINT " 4";B$(15): GOSUB 160
710 IF I = 2 THEN 550
715 IF I = 3 THEN 750
720 IF I = 4 THEN 850
725 IF I = 1 THEN PRINT A$: FOR I = 1 TO 2000:NEXT : HOME :VTAB 6: PRINT "La nourriture etait empoisonnee !": GOTO 270
730 GOTO 700
745 REM ****************************
746 REM PETIT COULOIR
747 REM ****************************
750 HOME : PRINT : PRINT "Vous etes dans un petit couloir": PRINT "Il y a un escalier qui monte."
755 PRINT "Il y a aussi une porte au sud et a l'est.": PRINT: PRINT " 1";B$(2): PRINT " 2";B$(3): PRINT " 3";B$(5): GOSUB160
760 IF I = 2 THEN 700
765 IF I = 3 THEN 2600
768 IF I <> 1 THEN 750
770 HOME : PRINT: PRINT "Devant la porte, une trappe s'ouvre sous vos pieds": PRINT "et vous vous retrouvez a l'etage inferieur"
775 FOR I = 1 TO 3000:NEXT : GOTO1200
790 REM ****************************
793 REM PIECE NOIRE
795 REM ****************************
800 HOME : PRINT : PRINT "Vous etes dans piece completement noire.": PRINT "Vous ne voyez strictement rien.": PRINT : PRINT " 1";B$(1): PRINT " 2";B$(3): PRINT " 3";B$(4): IF BR = 1 THEN PRINT " 4 Vous allumez votre briquet"
810 GOSUB 160: IF I = 1 THEN 900
820 IF I = 2 THEN 850
822 IF I = 3 THEN 550
825 IF I < > 4 THEN 800
830 HOME : PRINT : PRINT "La piece etait remplie d'un gaz explosif.": FOR I = 1 TO 2000:NEXT
832 K = 1
835 FOR I = 1 TO 30: FOR J = 1 TO 40: NEXT J:HOME: IF K = 1 THEN NORMAL :K = 0: GOTO 840
836 INVERSE :K = 1
840 HTAB 36: VTAB 12: PRINT "BAOUM !!": NEXT I
845 GOTO270
846 REM ****************************
847 REM SALON
848 REM ****************************
850 HOME : PRINT : PRINT "Vous etes dans le salon. Vous apercevez un bar.": PRINT "Il y a aussi un miroir a l'est": PRINT : PRINT " 1";B$(1):PRINT" 2";B$(3): PRINT " 3";B$(4): PRINT " 4 Vous allez au bar pour vous desalterer.": GOSUB160
860 IF I = 1 THEN 700
862 IF I < > 2 THEN 875
865 IF I = 2 THEN HOME : PRINT: PRINT "Le miroir n'etait qu'un mirage qui dissimulait un passage secret."
870 PRINT "Vous accedez au sous-sol.": FOR I = 1 TO 3000:NEXT : GOTO 1100
875 IF I = 3 THEN 800
877 IF I < > 4 THEN 850
880 IF CL = 0 THEN PRINT : PRINT: PRINT "Au milieu des bouteilles, vous voyez une cle.": PRINT "La prenez-vous ? ":GET R$: IF R$ = "O" THEN PRINT: PRINT : PRINT A$:FOR I=1 TO 2000: NEXT :CL = 1
885 GOTO850
890 REM ****************************
892 REM W.C.
894 REM ****************************
900 HOME : PRINT : PRINT "Vous etes devant les W.C. Vous pouvez entrer vous soulager (S) "
910 PRINT "ou rester dans la cuisine (R).": PRINT : PRINT "> Que faites-vous ? ";: GET R$
915 IF R$ = "R" THEN 800
920 IF R$ < > "S" THEN 900
940 HOME : PRINT : PRINT "En entrant dans les W.C., vous pouvez lire ce message sur la porte :"
945 PRINT : PRINT TAB(2);CHR$(34);"LA COLLECTE DES PIECES D'OR VOUS SERA BENEFIQUE"; CHR$(34): FOR I = 1 TO 3400:NEXT
950 PRINT : PRINT : PRINT "Vous retournez dans le couloir  apres vous etre soulage": FOR I = 1 TO 2400:NEXT : GOTO 900
990 REM ******************************
992 REM GRAND COULOIR
994 REM ******************************
1000 HOME : PRINT : PRINT "Vous etes dans un grand couloir.": PRINT : PRINT " 1";B$(3):PRINT " 2";B$(4): PRINT " 3";B$(5): GOSUB 160
1010 IF I = 1 THEN 1200
1020 IF I = 2 THEN 1300
1030 IF I = 3 THEN 400
1040 GOTO 1000
1090 REM ******************************
1092 REM ATELIER
1094 REM ******************************
1100 HOME : PRINT : PRINT "Vous etes dans un atelier. Il y a tout un eventail d'outils."
1105 PRINT
1110 PRINT " 1";B$(1): PRINT " 2";B$(2): PRINT " 3";B$(4): PRINT" 4 Vous prenez un outil"
1115 GOSUB 160
1120 IF I = 1 THEN 1200
1125 IF I = 2 THEN PRINT : PRINT"Vous remontez au rez-de-chaussee grace a ce passage secret.": FOR I = 1 TO 2200:NEXT : GOTO850
1130 IF I = 3 THEN 1400 
1150 IF I < > 4 THEN 1100
1160 HOME : PRINT : PRINT : PRINT" Vous avez le choix entre ces outils :": PRINT
1162 PRINT TAB(10)" 1 Une paire de tenailles": PRINT TAB(10)" 2 Une scie a metaux": PRINT TAB(10)" 3 Un pied de biche"
1165 PRINT : PRINT " Lequel choisissez-vous ? ";: GET B$:A =VAL (B$)
1167 PRINT B$
1168 IF A < 1 OR A > 3 THEN 1100
1170 IF A = 1 THEN T = 1
1175 IF A = 2 THEN SM = 1
1180 IF A = 3 THEN PB = 1
1183 PRINT : PRINT : PRINT A$: FOR I = 1 TO 2000:NEXT
1185 GOTO 1100
1190 REM ****************************
1192 REM DEBARRAS
1194 REM ****************************
1200 HOME : PRINT : PRINT "Vous etes dans un debarras. Toutes sortes d'objets y sont entreposes.": PRINT : PRINT " 1";B$(2): PRINT " 2";B$(4): GOSUB160
1210 IF I = 1 THEN 1100
1220 IF I = 2 THEN 1000
1230 GOTO 1200
1245 IF MT = 1 THEN 1300
1290 REM ****************************
1292 REM GRAND GARAGE
1294 REM ****************************
1300 HOME : PRINT : PRINT "Vous etes dans un grand garage."
1305 IF MT = 0 THEN PRINT "Un monstre hideux vous barre le passage !"
1310 PRINT : PRINT " 1";B$(3): IF MT = 0 THEN PRINT " 2";B$(20)
1315 IF MT = 1 THEN PRINT " 3";B$(1)
1317 GOSUB 160
1320 IF I = 1 THEN 1000
1325 IF I = 3 AND MT = 1 AND P1 = 0 THEN 1500
1327 IF I = 3 AND MT = 1 AND P1 = 1 THEN 1550
1330 IF I < > 2 THEN 1300
1340 IF NA = 0 THEN HOME : PRINT : PRINT : PRINT "Vous ne possedez pas d'arme.": FOR I =1 TO 2500:NEXT : GOTO 1300
1345 IF MU = 0 THEN HOME : PRINT : PRINT : PRINT " Elle n'est pas chargee!": FOR I= 1 TO 2500:NEXT : GOTO 1300
1350 HOME : PRINT : PRINT : PRINT" Vous utilisez votre ";C$;" .": FOR I = 1 TO 2100: NEXT
1385 W = A: GOSUB 4000
1387 IF FF = 1 THEN 1000
1390 GOTO 1300
1395 REM ****************************
1396 REM CHAUFFERIE
1397 REM ****************************
1400 HOME : PRINT : PRINT "Vous etes dans la chaufferie. Vous voyez un petit placard mural.": PRINT
1410 PRINT " 1";B$(3): PRINT " 2";B$(19): GOSUB 160
1420 IF I = 1 THEN 1100
1430 IF I < > 2 THEN 1400
1450 IF RND(1) > .3 AND DI = 0 THEN PRINT : PRINT "Vous y trouvez 7 pieces d'OR. Vous les prenez.":PO = PO + 7:DI = 1: FOR I = 1 TO 2000:NEXT : GOTO 1400
1460 PRINT : PRINT "Vous vous etes empale sur un pieu qui est sorti du mur.": GOTO 270
1490 REM ****************************
1492 REM PORTE BLINDEE
1494 REM ****************************
1500 HOME : PRINT : PRINT "Vous etes devant une porte blindee.": PRINT : PRINT " 1";B$(2)
1505 IF PB = 1 AND P1 = 0 THEN PRINT " 2 Vous forcez la porte avec le pied-de-biche"
1508 IF P1 = 1 THEN PRINT " 2 ";B$(1)
1510 GOSUB 160
1520 IF I = 1 THEN 1300
1525 IF I = 2 AND P1=1 THEN 1550
1530 IF I = 2 AND PB = 1 AND P1 = 0 THEN P1 = 1: GOTO 1550
1540 GOTO 1500
1545 REM ****************************
1546 REM LABORATOIRE
1547 REM ****************************
1550 HOME : PRINT : PRINT "Vous penetrez dans un etrange laboratoire."
1555 PRINT "Un message est ecrit sur le mur du fond :": PRINT
1560 PRINT : PRINT TAB(3); CHR$(34)"POUR SORTIR, VOUS DEVEZ TROUVER SUFFISAMENT DE PIECES D'OR POUR FABRIQUER"
1562 PRINT 
1565 PRINT TAB(4)"UNE CLEF DE CE METAL, QUI VOUS PERMETTRA ALORS D'OUVRIR TOUTES LES PORTES"; CHR$(34)
1570 PRINT : PRINT "Il y a aussi une table et une paillasse sur laquelle vous pouvez voir"
1580 PRINT "la machine a fondre les metaux.": PRINT : PRINT: PRINT " 1";B$(2): PRINT " 2 Vous vous approchez de la table": PRINT " 3 Vous vous approchez de la paillasse"
1585 GOSUB 160: IF I = 1 THEN 1300
1590 IF I = 2 THEN 1650
1600 IF I < > 3 THEN 1550
1610 IF PO < 40 THEN PRINT : PRINT" Vous n'avez pas assez de pieces d'or. La machine ne peut marcher.": FOR I= 1 TO 3000: NEXT : GOTO 1550
1620 PRINT : PRINT "Vous introduisez vos pieces d'or dans la machine.": PRINT "Appuyez deux fois sur la touche 'O' pour la mettre en marche.": GETB$
1630 IF B$ < > "O" THEN 1630
1635 PRINT : PRINT "La machine vibre quelques secondes."
1637 S = - 16336: FOR I = 1 TO 300:X = PEEK (S) - PEEK (S) + PEEK (S) - PEEK (S) + PEEK (S) - PEEK (S): NEXT
1640 PRINT "La machine libere une clef en OR. Vous la prenez.":CO = 1: FOR I= 1 TO 2400:NEXT : GOTO 1550
1650 HOME : PRINT : PRINT "Sur la table est inscrit le mode d'emploi , ainsi que ce message :"
1660 PRINT : PRINT " Une clef en OR pese 400 grammes. (40 pieces d'OR)"
1670 FOR I = 1 TO 4000:NEXT :GOTO 1550
1990 REM ****************************
1991 REM PETIT BUREAU
1992 REM ****************************
2000 HOME : PRINT : PRINT "Vous etes dans un petit bureau. Il y a un passage secret a l'ouest": PRINT : PRINT " 1";B$(1): PRINT " 2";B$(4):GOSUB160
2010 IF I = 2 THEN PRINT : PRINT : PRINT "Vous retournez au rez-de-chaussee": FOR I = 1 TO 2000:NEXT : GOTO 600
2020 IF I < > 1 THEN 2000
2090 REM ****************************
2091 REM PETIT COULOIR
2092 REM ****************************
2100 HOME : PRINT : PRINT "Vous etes dans un couloir."
2105 IF C3 = 0 THEN PRINT "Il y a une cassette fermee a clef."
2110 PRINT : PRINT " 1";B$(2): PRINT" 2";B$(3): PRINT " 3";B$(4)
2115 IF C3 = 0 THEN PRINT " 4";B$(19)
2117 GOSUB 160
2120 IF I = 1 THEN 2000
2130 IF I = 2 THEN 2600
2135 IF I = 3 THEN 2200
2140 IF I < > 4 THEN 2100
2145 IF C3 = 1 THEN 2100
2150 IF CO = 0 AND CL = 0 THEN PRINT : PRINT "Vous n'y parvenez pas.": FOR I = 1 TO 2000: NEXT : GOTO 2100
2160 PRINT "Votre cle ouvre la cassette. Elle contient 7 pieces d'or.":PO = PO + 7:C3 =1
2170 FOR I= I TO 2700: NEXT : GOTO 2100
2190 REM ****************************
2191 REM CHAMBRE
2192 REM ****************************
2200 HOME : PRINT : PRINT "Vous etes dans une chambre. Au milieu de la piece, vous voyez un petit sac": PRINT "pose sur un trone.": PRINT
2210 PRINT " 1";B$(3)
2215 IF SS = 0 THEN PRINT " 2 Vous prenez le sac": GOSUB 160
2220 IF I = 1 THEN 2100
2230 IF I < > 2 THEN 2200
2240 HOME : PRINT : PRINT "Vous avez declenche un mecanisme qui fait descendre le plafond.": PRINT "Pour l'arreter, pressez la bonne touche.": FOR I = 1 TO 2000:NEXT
2250 NORMAL : HOME :XX = 1: INVERSE
2260 VTAB XX : PRINT SPC(80);:XX = XX + 1
2265 FOR I = 1 TO 10
2270 IF PEEK ( - 16384) = 211 THEN2290
2271 X = PEEK (- 16336): NEXT I
2275 IF XX = 24 THEN PRINT "TROP TARD !!!": FOR I= 1 TO 2000: NEXT : HOME : GOTO 270
2280 S = - 16336:X = PEEK (S) - PEEK (S) + PEEK (S) - PEEK (S): GOTO 2260
2290 HOME : PRINT : PRINT "Bravo ? Vous etes sorti a temps.": PRINT "Le sac contient du sable.": FOR I = 1 TO 3000:NEXT :SS = 1: GOTO 2100
2295 REM ****************************
2296 REM W.C.
2297 REM ****************************
2300 HOME : PRINT : PRINT "Vous etes dans les W.C. voulez-vous vous soulager ? ";: GETB$
2310 IF B$ = "N" THEN 2500
2320 IF B$ < > "O" THEN 2300
2322 IF WC = 1 THEN PRINT : PRINT"Apres vous etre soulage, vous retournez dans le couloir.": FOR I= 1 TO 2500: NEXT: GOTO 2500
2325 PRINT : PRINT A$: FOR I = 1 TO 2000: NEXT :PRINT : PRINT"En tirant la chasse d'eau,vous faites tomber 4 pieces d'or.": PRINT "Vous les ramassez.":PO = PO + 4:WC = 1
2330 FOR I= 1 TO 3000: NEXT : GOTO 2500
2390 REM ****************************
2391 REM ARMURERIE
2392 REM ****************************
2400 HOME : PRINT : PRINT "Vous etes dans une armurerie. ";
2402 IF CH = 0 THEN PRINT "Mal heureusement, les armes qui s'y trouvent sont": PRINT "attachees par des chaines que vous ne pouvez briser."
2405 PRINT : PRINT
2410 PRINT " 1";B$(3): IF T = 1 AND CH = 0 THEN PRINT " 2 Vous coupez les chaines avec vos tenailles"
2412 IF CH = 1 THEN PRINT " 3 Vous choisissez une arme"
2413 GOSUB 160: IF I = 1 THEN 2500
2415 IF I = 2 AND T = 0 THEN 2400
2416 IF I = 3 AND CH = 1 THEN 2420
2417 IF I < > 2 OR NA = 1 THEN 2400
2418 CH = 1: PRINT : PRINT A$: FOR I= 1 TO 2000: NEXT : GOTO 2400
2420 HOME : PRINT : PRINT " Quelle arme choisissez-vous : ":CH = 1
2430 PRINT : PRINT TAB(10)" 1 Un fusil de chasse": PRINT TAB(10)" 2 Un revolver": PRINT TAB(10)" 3 Un coupe-coupe": PRINT : GET B$:A = VAL (B$): IF A < 1 OR A > 3 THEN 2420
2438 MU = 1
2440 NA = 1: IF A = 1 OR A = 2 THEN MU = 0
2450 C$ = C$(A): PRINT : PRINT "Vous venez de prendre le ";C$: FOR I= 1 TO 2300: NEXT :GOTO 2400
2490 REM ****************************
2491 REM GRAND COULOIR
2492 REM ****************************
2500 HOME : PRINT : PRINT "Vous etes dans long couloir mal eclaire.": PRINT "Sur le mur, sont accroches des chandeliers."
2510 PRINT : PRINT " 1";B$(1):PRINT " 2";B$(6): PRINT " 3";B$(13): PRINT " 4";B$(14):PRINT " 5";B$(15): PRINT " 6";B$(16): PRINT " 7";B$(17): PRINT " 8";B$(18)
2520 IF BR = 1 AND CD = 0 THEN PRINT " 9 vous allumez les chandeliers avec votre briquet."
2530 GOSUB 160: IF I = 1 THEN 2600
2535 IF I = 2 THEN 500
2540 IF I = 3 THEN 2700
2545 IF I = 4 THEN 2800
2550 IF I = 5 THEN 3000
2555 IF I = 6 THEN 2400
2560 IF I = 7 THEN 2300
2570 IF I = 8 THEN 2900
2580 IF I < > 9 THEN 2500
2585 IF BR = 0 OR CD = 1 THEN 2500
2590 PRINT : PRINT "Une fois le couloir eclaire, vous apercevez une petite boite": PRINT"que vous prenez. Elle contient 5 pieces d'OR.":PO = PO + 5:CD = 1
2595 FOR I= 1 TO 3500: NEXT : GOTO 2500
2597 REM ****************************
2598 REM CHAMBRE
2599 REM ****************************
2600 HOME : PRINT : PRINT "Vous etes dans une chambre. Le lit semble confortable."
2610 PRINT : PRINT " 1";B$(2): PRINT" 2";B$(4): PRINT " 3";B$(6): PRINT " 4 Vous vous reposez "
2620 GOSUB 160: IF I = 1 THEN 2500
2630 IF I = 2 THEN 2100
2640 IF I = 3 THEN 750
2645 IF I < > 4 THEN 2600
2650 PRINT : PRINT A$: FOR I=1 TO 2000: NEXT :KK = RND (1)
2660 IF KK > .33 THEN PRINT "Ce repos vous fait du bien.":FOR I= 1 TO 2100: NEXT : GOTO 2600
2670 PRINT : PRINT "Le lustre qui se trouvait au-dessus du lit vous tombe dessus"
2675 PRINT "et vous ecrase.": FOR I= 1 TO 2500: NEXT : GOTO 270
2690 REM ****************************
2691 REM PIECE TRES ETRANGE
2692 REM ****************************
2700 HOME : PRINT : PRINT "Vous entrez dans une piece bien etrange.": PRINT "Au milieu de celle-ci, se trouve un sac."
2705 PRINT "Dans chaque coin, une statue semble vous regarder d'un oeil hostile."
2710 PRINT : PRINT " 1";B$(4): PRINT" 2";B$(22): GOSUB 160
2715 IF I = 1 THEN 2500
2720 IF I < > 2 THEN 2700
2730 HOME : PRINT : IF SS = 1 THEN PRINT "Remplacez-vous le sac par un autre objet ? ": GETB$
2735 IF SS = 0 THEN 2755
2740 IF B$ = "O" THEN 2750
2745 IF B$ < > "N" THEN GET B$: GOTO 2740
2747 GOTO 2755
2750 PRINT : INPUT " LEQUEL ? ";B$: IF RIGHT$ (B$,12) = "SAC DE SABLE" THEN 2760
2755 PRINT : PRINT "Un rayon lumineux sort de la bouche de chacune des statues et vous desintegre.": FOR I = 1 TO 3500: NEXT : GOTO 270
2760 PRINT : PRINT A$: FOR I=1 TO 2000: NEXT :SS = 0: PRINT: PRINT "Cet exploit vous rapporte 3 pieces d'OR.": FOR I= 1 TO 2500: NEXT :PO = PO + 3: GOTO 2700
2790 REM ****************************
2791 REM BIBLIOTHEQUE
2792 REM ****************************
2800 HOME : PRINT : PRINT "Vous etes dans une bibliotheque.Vous voyez un grand coffre."
2810 PRINT : PRINT " 1";B$(4): PRINT" 2 Vous tentez de l'ouvrir": IF SM = 1 AND CF = 0 THEN PRINT " 3 Vous forcez la serrure avec votre scie a metaux"
2815 GOSUB 160
2820 IF I = 1 THEN 2500
2830 IF I = 2 THEN PRINT : PRINT"Vous vous electrocutez en touchant le metal.": FOR I = 1 TO 3000: NEXT : GOTO 270
2840 IF I = 3 AND SM = 1 AND CF= 0 THEN PRINT : PRINT "OK. C'est ouvert. Le coffre contient 8 pieces d'or.": FOR I = 1 TO 3100: NEXT :PO = PO + 8:CF = 1: GOTO 2800
2850 GOTO 2800
2890 REM ****************************
2891 REM SALLE DE BAINS
2892 REM ****************************
2900 HOME : PRINT : PRINT "Vous etes dans la salle de bain.": PRINT : PRINT " 1";B$(3):PRINT " 2";B$(10): GOSUB160
2910 IF I = 1 THEN TA = 0: GOTO 2500
2920 IF I < > 2 OR BO = 1 THEN TA = 0: GOTO 2900
2930 TA = TA + 1: IF TA = 3 THEN PRINT : PRINT "A force d'attendre, vous voyez enfin un bougeoir.": PRINT "Vous le prenez.":BO = 1: FOR I=1 TO 3000: NEXT : GOTO 2900
2940 GOTO 2900
2990 REM ****************************
2991 REM PALIER
2992 REM ****************************
3000 HOME : PRINT : PRINT "Vous etes sur un palier. Il y a un escalier en colimacon."
3010 PRINT : PRINT " 1";B$(4): PRINT " 2";B$(5): GOSUB 160
3020 IF I = 1 THEN 2500
3030 IF I < > 2 THEN 3000
3100 HOME : PRINT : PRINT : PRINT"Vous montez un escalier en colimacon eclaire par des meurtrieres": PRINT "trop etroites pour que vous puissiez sortir."
3110 PRINT "Une odeur fetide remplit l'air.": PRINT : PRINT " 1 Vous continuez a monter"
3115 PRINT " 2 Vous redescendez"
3120 IF BO = 1 AND BR = 1 AND LU = 0 THEN PRINT " 3 Vous allumez votre bougeoir avec votre briquet pour mieux voir"
3230 GOSUB 160: IF I = 1 THEN 5000
3235 IF I = 2 THEN 3000
3240 IF I = 3 AND BR = 1 AND BO=1 THEN 3247
3245 GOTO 3100
3247 IF M = 1 THEN 3100
3250 PRINT : PRINT A$: FOR I =1 TO 2000: NEXT : PRINT : PRINT"Vous y voyez deja mieux.": PRINT"Sur une des marches, vous trouvez une boite de munitions."
3255 LU = 1
3260 IF NA = 0 THEN PRINT : PRINT"Vous n'avez pas d'arme. Vous la laissez donc."
3270 IF NA = 1 THEN PRINT : PRINT"Vous la prenez."
3275 FOR I = 1 TO 4000: NEXT :M = 1: GOTO 3100
3990 REM ****************************
3991 REM BAGARRE DU GARAGE
3992 REM ****************************
4000 HOME : PRINT
4010 PRINT : PRINT "(1) Vous le frappez": PRINT"(2) Vous fuyez": PRINT : PRINT"> Que faites-vous ?": GET B$
4020 IF B$ = "2" THEN FF = 1: RETURN
4030 IF B$ < > "1" THEN 4000
4040 KK = RND (1): IF KK > .4 THEN MT = 1:FF = 0: PRINT "BRAVO ! Vous l'avez tue.": FOR I =1 TO 2400: NEXT : RETURN
4060 PRINT : PRINT "Le monstre n'est pas touche"
4100 KK = RND (1): IF KK > .4 THEN PRINT : PRINT "Le monstre essaie de vous toucher, mais n'y parvient pas.": GOTO 4010
4110 HOME : VTAB 3: PRINT " LE MONSTRE VOUS TOUCHE": GOTO270
4990 REM ****************************
4991 REM GRENIER 1
4992 REM ****************************
5000 HOME : PRINT : PRINT "Vous etes au grenier.": PRINT "Il y a une fenetre a l'est."
5010 PRINT "Il y a une porte au nord.": PRINT "Un tableau est accroche sur le mur ouest."
5020 PRINT : PRINT " 1";B$(1): PRINT" 2";B$(3): PRINT " 3";B$(4): PRINT " 4";B$(6): GOSUB160
5030 IF I = 1 AND RG = 0 THEN 5200
5032 IF I = 1 AND RG = 1 THEN 5300
5040 IF I = 2 THEN 5100
5050 IF I = 3 THEN 5150
5060 IF I = 4 THEN 3100
5070 GOTO 5000
5100 HOME : PRINT : PRINT "Vous vous approchez de la fenetre.": PRINT "Sur le mur exterieur, vous pouvez voir du lierre."
5110 PRINT : PRINT " 1 Vous essayez d'ouvrir la fenetre": PRINT" 2 Vous retournez au centre de la piece": GOSUB 160
5120 IF I = 2 THEN 5000
5126 IF I < > 1 THEN 5100
5130 PRINT : PRINT "La fenetre etait protegee par un rayon laser qui vous a desintegre.": FOR I = 1 TO 2900: NEXT :GOTO 270
5150 HOME : VTAB 6: PRINT "Vous etes devant le tableau. Le sol s'ouvre sous vos pieds."
5160 PRINT "Vous tombez dans un trou et ne pouvez en ressortir.": GOTO 270
5190 REM ****************************
5191 REM PORTE DU GRENIER 2
5192 REM ****************************
5200 HOME : PRINT : PRINT "Vous etes devant le second grenier.": IF RG = 0 THEN PRINT"La porte qui y mene est fermee.": PRINT
5210 PRINT " 1 Vous retournez au centre de la piece"
5215 IF CL = 1 AND RG = 0 THEN PRINT " 2 Vous ouvrez la porte avec votre clef "
5220 GOSUB 160
5230 IF I = 1 THEN 5000
5240 IF I < > 2 THEN 5200
5245 IF CL = 1 AND RG = 0 THEN PRINT : PRINT A$: PRINT : PRINT"Vous accedez au second grenier.": FOR I = 1 TO 3000: NEXT:RG = 1: GOTO 5300
5247 IF RG = 1 THEN 5300
5250 GOTO 5200
5290 REM ****************************
5291 REM GRENIER 2
5292 REM ****************************
5300 HOME : PRINT : PRINT "Vous etes dans le second grenier"
5305 PRINT "Il y a un vieux televiseur dans le coin nord-est."
5310 PRINT "Sur la table qui se trouve a l'ouest, vous voyez une balance."
5315 PRINT "Il y a aussi une porte au nord."
5320 PRINT : PRINT " 1";B$(1): PRINT" 2";B$(2): PRINT " 3";B$(4): PRINT " 4";B$(13): GOSUB160
5330 IF I = 1 THEN 5600
5340 IF I = 2 THEN 5000
5350 IF I = 3 THEN 5400
5360 IF I = 4 THEN 5500
5380 GOTO 5300
5400 HOME : PRINT : PRINT "Vous etes devant la balance.": PRINT: PRINT " 1 Vous retournez au centre de la piece"
5410 PRINT " 2 Vous pesez vos pieces": GOSUB 160
5420 IF I = 1 THEN 5300
5430 IF I < > 2 THEN 5400
5450 PRINT : PRINT "Vous mettez vos ";PO;" pieces d'OR sur le plateau de la balance."
5460 PRINT "Son cadran indique:"
5465 VTAB 12: HTAB 35: NORMAL :PRINT "          ": HTAB 35: VTAB 13: PRINT " ": VTAB 14: HTAB 35: PRINT "          "
5470 VTAB 13: HTAB 44: PRINT "     ": VTAB 13: HTAB 42: INVERSE: PRINT "g"
5475 PP = PO * 10: FOR I= 0 TO PP STEP 2:B$ = LEFT$ ("    ",4 - LEN ( STR$ (I))) + STR$(I)
5480 VTAB 13: HTAB 37: PRINT B$: NEXT I
5490 FOR I = 1 TO 2000: NEXT : GOTO5300
5500 HOME : PRINT : PRINT "Vous etes devant le televiseur."
5510 PRINT : PRINT " 1 Vous retournez au centre de la piece": PRINT " 2 Vous allumez le televiseur": GOSUB 160
5520 IF I = 1 THEN 5300
5530 IF I = 2 THEN 5550
5540 GOTO 5500
5550 HOME : PRINT : PRINT : PRINT "Allumez-le.";
5555 GET B$: IF B$ = "M" THEN 5570
5560 GOTO 5555
5570 PRINT : PRINT : PRINT "Un message apparait sur l'ecran :": SPEED= 1
5580 PRINT : PRINT "   LA CLEF DE LA REUSSITE SE TROUVE AU SOUS-SOL": SPEED= 255
5586 FOR I= 1 TO 2100: NEXT : GOTO 5300
5590 REM ****************************
5591 REM GRENIER 3
5592 REM ****************************
5600 HOME : PRINT : PRINT "Vous etes dans le troisieme grenier.": PRINT "A l'ouest se trouve un coffre."
5610 PRINT "A l'est, il y a une porte avec une serrure en OR.": PRINT
5620 PRINT " 1";B$(2): PRINT " 2";B$(3): PRINT " 3";B$(4): GOSUB160
5630 IF I = 1 THEN 5300
5640 IF I = 3 THEN 5700
5650 IF I = 2 THEN 5800
5670 GOTO 5600
5700 REM
5710 IF W < > 1 AND W < > 2 THEN PRINT "Vous ne pouvez rien faire.": FOR I= 1 TO 2500:NEXT: GOTO 5600
5720 IF MU = 0 OR C2 = 1 THEN 5600
5730 HOME : PRINT : PRINT "Vous etes devant le coffre. Il est ferme par une chaine reliee a un cadenas."
5740 PRINT : PRINT " 1 Vous faites sauter le cadenas avec votre arme": PRINT " 2 Vous retournez au centre de la piece"
5750 GOSUB 160: IF I = 2 THEN 5600
5760 IF I < > 1 THEN 5730
5765 PRINT : PRINT " Vous y trouvez 15 pieces d'or.": FOR I= 1 TO 2600: NEXT :C2 = 1:PO = PO + 15: GOTO 5600
5800 HOME : PRINT : PRINT "Vous etes devant la porte": PRINT: PRINT " 1 Vous retournez au centre de la piece"
5810 IF CO = 1 THEN PRINT " 2 Vous ouvrez la porte avec votre clef en OR."
5815 GOSUB 160
5820 IF I = 1 THEN 5600
5830 IF I < > 2 THEN 5800
5840 IF CO < > 0 THEN 5800
5850 HOME : VTAB 6: PRINT "La porte s'ouvre. Vous voyez une echelle sur le mur exterieur et la descendez."
5860 VTAB 12: HTAB 31: NORMAL :PRINT "TRIPLE BRAVO !!!":VTAB 15: HTAB 32: PRINT "Vous etes libre"
5870 END
6000 REM ****************************
6001 REM PRESENTATION
6002 REM ****************************
6010 HOME : VTAB 13
6100 READ D,S,A,C: IF D = 99 THEN 6200
6110 FOR I = D TO A STEP S
6120 POKE I - S,160: POKE I,C
6125 IF PEEK(-16384) > 127 THEN 6160
6130 FOR J = 1 TO 8:X = PEEK (-16336): NEXT
6140 NEXT I
6150 GOTO 6100
6160 READ D,S,A,C: IF D = 99 THEN 6600 
6170 GOTO 6160
6200 S = - 16336
6205 FOR I= 1 TO 20: IF D = 1 THEN D = 0: INVERSE : GOTO 6220
6210 D = 1: NORMAL
6220 HOME : VTAB 13: HTAB 32: PRINT"A M I T Y V I L L E"
6225 IF PEEK(-16384) > 127 THEN 6600
6230 FOR J = 1 TO 10:X = PEEK(S) + PEEK(S) - PEEK(S) + PEEK(S) - PEEK(S): NEXTJ
6250 NEXT I
6300 G$ = " pressez RETURN pour continuer "
6310 D = 1: A = 10:VTAB 24
6320 A = A + D: IF A = 1 OR A = 48 THEN D = - D
6330 POKE36,A:PRINT G$;
6335 IF A = 25 THEN FOR I = 0 TO 900: NEXT I
6340 FOR J = 1 TO 5: NEXT J
6350 IF PEEK(- 16384) = 141 THEN 6400
6360 GOTO 6320
6400 POKE - 16368,0
6405 HOME : VTAB 8: PRINT TAB(28);"Pour executer une action"
6410 VTAB10: PRINT TAB(32);"Pressez le numero"
6420 VTAB12: PRINT TAB(25);"Qui se trouve devant celle-ci."
6430 D = 1:A = 10:VTAB 24
6440 A = A + D: IF A = 3 OR A = 48 THEN D = - D
6450 POKE36,A:PRINT G$;
6460 IF A = 25 THEN FOR I= 0 TO 900: NEXT I
6470 FOR J = I TO 5: NEXT J
6480 IF PEEK( - 16384) = 141 THEN 6500
6490 GOTO 6440
6500 POKE - 16368,0
6505 HOME : VTAB 8: PRINT TAB(31);"Pour savoir combien"
6510 VTAB10: PRINT TAB(29);"De pieces vous possedez"
6520 VTAB12: PRINT TAB(35);"Pressez .. 'O' "
6521 VTAB14: PRINT TAB(35);"Inventaire 'I' "
6522 VTAB16: PRINT TAB(35);"Voir ..... 'V' "
6523 VTAB18: PRINT TAB(35);"Suicide .. 'F' "
6530 D = 1:A = 10:VTAB 24
6540 A = A + D: IF A = 3 OR A = 48 THEN D = - D
6550 POKE36,A:PRINT G$;
6560 IF A = 25 THEN FOR I = 0 TO 900: NEXT I
6570 FOR J = 1 TO 5: NEXT J
6580 IF PEEK ( - 16384) = 141 THEN 6600
6590 GOTO 6540
6600 INVERSE : POKE - 16368,0:RETURN