0 REM ======== The Treasure of Elgon ==========
1 REM
2 REM 2021/11/08	D. RIOUAL	Bugs fixed
3 REM
10 REM BA=BLUNT AXE / GG=GRUE GONE / DD=DRAGON DEAD / CL=CLIMB LADDER
11 REM CC=CLOSET CHOPPED / AD=APPLE DOWN / EI=ENOUGH INVENTORY
12 REM DF=DUG AND FOUND ALREADY / SA=SHOWED AMULET / DS=DUG IN SAND
20 REM AI=ANKH INSERTED / PR=PLANK REMOVED / PA=PLANK ATTACHED
21 REM MP=MERCHANT PAID / UH=USED HAMMER / PS=PADLOCK SAWN
22 REM MC=MOVED CHEST / ME=MERCHANT EATEN APPLE / FB=FIRE BREATHED
30 REM CM=COIN TO MERCHANT / AM=APPLE TO MERCHANT
50 DIM OB$(52): DIM OB(52): DIM RM$(40): DIM RM(40): DIM DI$(32)
60 TEXT : HOME : PRINT CHR$(4);"PR#3" : REM SWITCH TO 80-COLUMNS
70 BA=0:EG=0:GG=0:AD=0:CC=0:UH=0:PS=0:MP=0:WG=0:EI=0:CL=0:DF=0:DS=0:DD=0
71 AI=0:PA=0:PR=0:MC=0:ME=1:AM=0:CM=0:FB=0:AA=0
80 NO=52: NR=32
90 FOR I=1 TO NO
100 READ OB(I)
110 NEXT I
120 FOR I=1 TO NO
130 READ OB$(I)
140 NEXT I
150 RM$(1)="Je suis dans une fosse sombre, humide et lugubre. Les rayons lumineux venant du"+CHR$(13)+"haut sont la seule source de lumiere."
160 RM$(2)="Je suis dans une petite ouverture etroite."
170 RM$(3)="Je suis dans un tunnel."
180 RM$(4)="Je suis dans une grande caverne souterraine."
190 RM$(5)="Je suis dans une cavite souterraine."
200 RM$(6)="Je suis dans un champ ouvert."
210 RM$(7)="Je suis dans une cour."
220 RM$(8)="Je suis dans une vieille cabane abandonnee."
230 RM$(9)="Je suis dans une petite chambre miteuse."
240 RM$(10)="Je suis dans une cuisine."
250 RM$(11)="Je suis a l'interieur d'un poste de sentinelle."
260 RM$(12)="Je suis a cote d'un fosse."
270 RM$(13)="Je suis dans une tente de marchands."
280 RM$(14)="Je suis au bord d'une riviere."
290 RM$(15)="Je suis dans un cimetiere sinistre."
300 RM$(16)="Je suis pres d'un gouffre sans fond."
310 RM$(17)="Je suis dans une petite clairiere sablonneuse."
320 RM$(18)="Je suis dans une zone de falaises."
330 RM$(19)="Je suis dans un grand placard."
340 RM$(20)="Je suis dans une longue salle sans decoration."
350 RM$(21)="Je suis dans une ancienne archive."
360 RM$(22)="Je suis dans une cour du chateau."
370 RM$(23)="Je suis dans la salle des gardes"
380 RM$(24)="Je suis dans une petite piece secrete."
390 RM$(25)="Je suis dans la salle d'armes."
400 RM$(26)="Je suis dans un vieux donjon puant."
410 RM$(27)="Je suis dans une chambre avec des torches tachees de sang."
420 RM$(28)="Je suis dans une grotte secrete."
430 RM$(29)="Je suis en haut d'une echelle."
440 RM$(30)="Je suis dans l'antre d'un dragon."
450 RM$(31)="Je suis dans une piece aux murs d'or massif."
460 RM$(32)="Je suis dans un grand trou, avec des murs en or massif"
470 NO$="Nord. ": SO$="Sud. ": EA$="Est. ": WE$="Ouest. ": UP$="Haut. ": DO$="Bas. "
480 DI$(1)=NO$: DI$(2)=SO$: DI$(3)=EA$+WE$: DI$(4)=EA$+WE$: DI$(5)=EA$
481 DI$(6)=NO$+SO$+EA$+DO$: DI$(7)=SO$: DI$(8)=EA$+WE$+SO$: DI$(9)=EA$
482 DI$(10)=WE$: DI$(11)=SO$: DI$(12)=WE$: DI$(13)=NO$+WE$: DI$(14)=EA$
483 DI$(15)=SO$: DI$(16)=NO$: DI$(17)=WE$
490 DI$(18)=EA$: DI$(19)=WE$: DI$(20)=NO$: DI$(21)=WE$: DI$(22)=NO$+SO$+EA$+WE$
491 DI$(23)=WE$: DI$(24)=NO$: DI$(25)=EA$+SO$: DI$(26)=WE$+UP$: DI$(27)=EA$
492 DI$(28)=SO$: DI$(29)=DO$: DI$(30)=NO$+EA$: DI$(31)=WE$: DI$(32)=UP$
500 VI$=" Objets visibles :-"
510 GOSUB 7810
520 HOME
530 GOTO 6180
540 A$="": F$="": S$="": IF RM=2 THEN EG=EG+1: IF EG=10 AND GG<>1 THEN 7620
550 IF RM=30 AND DD<>1 THEN FB=FB+1
560 IF FB<>3 THEN 610
561 SH=SH+1
570 IF OB(44)<>-1 THEN PRINT"J'ai ete brule par un dragon cracheur de feu !": GOTO 7620
580 IF OB(44)=-1 THEN PRINT"Le dragon m'envoie un souffle de feu, mais il est renvoye par mon bouclier.":FB=0
590 IF SH=2 THEN PRINT"Je ne sais pas si je peux tenir le bouclier encore longtemps, car il est tres chaud !": GOTO 540
600 IF SH=3 THEN PRINT"Le bouclier est trop chaud, je le lache !": OB(44)=RM: GS=1: GOSUB 8090: GOTO 3630
610 INPUT"Quelle est votre commande >>";A$
620 IF LEN(A$)>30 THEN PRINT"Soyez raisonnable ! !!": GOTO 540
630 IF A$="" THEN 7310
640 GOSUB 7730
650 IF A$<>"" THEN A$=A$+" "
660 FOR I=1 TO LEN(A$)
670 IF MID$(A$,I,1)<>" " THEN NEXT I
680 F$=LEFT$(A$,I-1)
690 FOR I=LEN(A$) -1 TO 1 STEP-1
700 IF MID$(A$,I,1)<>" " THEN NEXT I
710 S$=MID$(A$,I+1,LEN(A$)-I-1)
720 IF F$< "A" OR F$> "Z" THEN GOTO 7310
750 REM ----------------------------------------------------------------------
760 IF F$<>"ACHETER" THEN 800
770 GOTO 3020
790 REM ----------------------------------------------------------------------
800 IF F$<>"GRIMPER" THEN 880
810 FOR I=1 TO NO: IF S$=OB$(I) THEN 830
811 NEXT I
820 GOTO 7310
830 IF OB(I)=-1 THEN 7360
840 IF OB(I)<>RM THEN 7360
850 IF S$=OB$(1) AND OB(1)=1 THEN CL=1: GOTO 7250
860 IF S$=OB$(1) THEN 7250
870 IF S$=OB$(49) THEN PRINT"Les murs sont bien trop glissants.":GOTO 540
879 REM ----------------------------------------------------------------------
880 IF F$<>"ABATTRE" THEN 1000
890 FOR I=1 TO NO: IF S$=OB$(I) THEN 940
900 NEXT I: GOTO 7310
910 IF OB(8)=-1 AND BA=0 THEN 950
920 IF OB(8)<>-1 THEN 7360
930 IF BA=1 THEN PRINT"Essayez d'examiner la hache !": GOTO 540
940 IF RM=6 AND S$=OB$(3) AND AD<>1 THEN PRINT"Les vibrations detachent la pomme de la branche, et elle tombe sur le sol.": AD=1: BA=1: GOTO 540
950 IF RM=20 AND S$=OB$(30) THEN PRINT"Je fais un trou assez grand pour pouvoir passer a travers.": CC=1: BA=1: GOTO 540
960 IF RM=7 AND S$=OB$(35) THEN PRINT"Vous vous amusez a couper la cloture en copeaux.": OB(35)=0: OB(48)=7: BA=1: GOTO 3630
970 IF RM=6 AND S$=OB$(3) THEN PRINT "Les vibrations causees par la hache font tomber la pomme.": AD=1: BA=1: GOTO 540
980 IF RM=1 OR RM=2 AND S$=OB$(1) THEN PRINT "Vous coupez violemment l'echelle en morceaux.": LD=1: BA=1: OB(1)=0: OB(50)=RM: GOTO 3630
990 GOTO 7580
999 REM ----------------------------------------------------------------------
1000 IF F$<>"COUPER" THEN 1030
1010 GOTO 5160
1020 REM ----------------------------------------------------------------------
1030 IF F$<>"B" THEN 1070
1040 IF RM=6 THEN 6180
1050 IF RM=29 AND SR=1 THEN 6180
1060 IF RM=29 AND SR=2 THEN 6210
1065 GOTO 7460
1069 REM ----------------------------------------------------------------------
1070 IF F$<>"POSER" THEN 1150
1080 FOR I=1 TO NO: IF S$=OB$(I) THEN 1100
1090 NEXT I: GOTO 7310
1100 IF OB(I)<>-1 THEN 7340
1110 IF S$=OB$(31) THEN WG=0
1120 IF S$=OB$(26) THEN 4280
1130 OB(I)=RM: EI=EI-1:GOTO 3630
1140 REM ----------------------------------------------------------------------
1150 IF F$<>"CREUSER" THEN 1280
1160 IF OB(9)<>-1 THEN 7360
1170 IF RM<>15 THEN 1220
1180 IF DF=1 THEN 7500
1190 IF SA<>1 THEN PRINT"Le fantome ne me laisse pas faire !": GOTO 540
1200 OB(13)=15: OB(15)=15: DF=1
1210 GOTO 7520
1220 IF RM<>17 THEN 7500
1230 IF DS=1 THEN 7500
1240 OB(10)=17: DS=1
1250 GOTO 7520
1260 REM
1270 REM ----------------------------------------------------------------------
1280 IF F$<>"E" THEN 1460
1290 IF RM=18 THEN 6660
1300 IF RM=14 THEN 6540
1310 IF RM=19 THEN 6760
1320 IF RM=6 THEN 6510
1330 IF RM=22 THEN 6790
1340 IF RM=5 THEN 6270
1350 IF RM=4 THEN 6240
1360 IF RM=3 THEN 6210
1370 IF RM=25 THEN 6850
1380 IF RM=27 THEN 6940
1390 IF RM=9 THEN 6390
1400 IF RM=8 THEN 6450
1410 IF RM<>30 THEN 1440
1420 IF DD<>1 THEN PRINT"Le dragon ne me laisse pas faire !": GOTO 540
1430 IF DD=1 THEN 7140
1440 GOTO 7460
1450 REM ----------------------------------------------------------------------
1460 IF F$<>"EXAMINER" THEN 2010
1470 FOR I=1 TO NO: IF S$=OB$(I) THEN 1500
1480 NEXT I
1490 GOTO 7310
1500 IF OB(I)<>RM AND OB(I)<>-1 THEN 7360
1501 GOTO 1510
1510 IF S$=OB$(1) THEN PRINT"Elle est plutot courte.": GOTO 540
1520 IF S$<>OB$(38) THEN 1550
1530 IF RM=16 OR RM=17 THEN PRINT"C'est un gouffre sans fond de 2 metres de large." : GOTO 1540
1531 GOTO 7360
1540 GOTO 540
1550 IF S$=OB$(2) THEN PRINT"Il vous fait un grand sourire, tout en se lechant les babines.": GOTO 540
1560 IF S$=OB$(18) THEN PRINT"Il y a quelque chose d'ecrit dessus.": GOTO 540
1570 IF S$=OB$(19) THEN PRINT"Il a l'air d'avoir de la valeur.": GOTO 540
1580 IF S$=OB$(44) AND SH=0 THEN PRINT"Il degage une impression de force !": GOTO 540
1590 IF S$=OB$(44) AND SH>1 THEN PRINT"Le bouclier est rouge brulant !": GOTO 540
1600 IF S$=OB$(3) AND AA=0 THEN 1610
1601 GOTO 1620
1610 PRINT"L'arbre est petrifie, mais il y a une pomme rouge sur l'une de ses branches.": OB(4)=RM: AA=1: GOSUB 8090: GOTO 3630
1620 IF S$=OB$(3) AND AA=1 AND AD=0 THEN 1610
1630 IF S$=OB$(3) AND AD=1 THEN PRINT"C'est petrifie !": GOTO 540
1640 IF S$="SYMBOLE" THEN PRINT "Il ressemble a un fantome.": GOTO 540
1650 IF S$=OB$(37) THEN PRINT"C'est rouille.": GOTO 540
1660 IF S$=OB$(4) THEN PRINT"C'est une belle grosse pomme rouge.": GOTO 540
1670 IF S$=OB$(21) THEN PRINT"C'est colle au mur": GOTO 540
1680 IF S$=OB$(22) THEN PRINT"C'est un cadavre puant en decomposition.": GOTO 540
1690 IF S$=OB$(51) THEN PRINT"C'est le tresor d'Elgon !!!!": GOTO 540
1700 IF S$=OB$(36) THEN PRINT"C'est une pierre a aiguiser.": GOTO 540
1710 IF S$=OB$(24) THEN PRINT"Il y a quelque chose d'ecrit dessus.": GOTO 540
1720 IF S$=OB$(6) THEN PRINT"Elle a l'air deserte.": GOTO 540
1730 IF S$=OB$(26) THEN PRINT"Il semble solide.": GOTO 540
1740 IF S$=OB$(7) AND MS=0 THEN PRINT"Il a l'air pauvre.": GOTO 540
1750 IF S$=OB$(7) AND MS=1 THEN PRINT"Il est mort ! Et je ne pense pas que son etat va s'ameliorer !": GOTO 540
1760 IF S$<> OB$(20) THEN 1790
1770 IF AI<>1 THEN PRINT"Il y a un petit trou rond au milieu.": GOTO 540
1780 PRINT"Il y a une croix inseree au milieu.": GOTO 540
1790 IF S$=OB$(8) THEN 1980
1800 IF S$=OB$(29) THEN PRINT"Le courant est tres fort.": GOTO 540
1810 IF S$<>OB$(30) THEN 1840
1820 IF CC<>1 THEN PRINT"C'est une vieille armoire en bois fermee a clef.": GOTO 540
1830 PRINT"Il y a un trou decoupe dedans.": GOTO 540
1840 IF S$=OB$(31) THEN PRINT"Ce sont des lunettes de lecture.": GOTO 540
1850 IF S$=OB$(10) THEN PRINT"Il y a un etrange symbole qui en sort.": GOTO 540
1860 IF S$=OB$(32) THEN PRINT"C'est de l'acier et semble tres epais.": GOTO 540
1870 IF S$=OB$(11) THEN PRINT"Il est grand, et semble etre tres fort.": GOTO 540
1880 IF S$<>OB$(35) THEN 1910
1890 IF PA=1 THEN 7420
1900 PRINT"Il a une planche branlante, clouee avec un seul clou.": GOTO 540
1910 IF S$=OB$(12) THEN PRINT"C'est une vieille tombe couverte de mauvaises herbes.": GOTO 540
1920 IF S$=OB$(34) THEN PRINT"Il a une tete griffue.": GOTO 540
1930 IF S$=OB$(38) THEN PRINT"Le coffre a l'air tres vieux et on sent qu'il est rempli de tresors.": GOTO 540
1940 IF S$=OB$(13) THEN PRINT"On dirait qu'ils sont humains.": GOTO 540
1950 IF S$=OB$(14) THEN PRINT"C'est un anneau avec une petite vis fine qui en sort.": GOTO 540
1960 IF S$=OB$(33) THEN PRINT"C'est un poste de sentinelle !": GOTO 540
1970 GOTO 7420
1980 IF BA<>1 THEN PRINT"C'est pointu": GOTO 540
1990 IF BA=1 THEN PRINT"C'est emousse": GOTO 540
2000 REM ----------------------------------------------------------------------
2010 IF F$<>"NOURRIR" THEN 2080
2020 IF S$<>OB$(2) THEN 2060
2030 IF OB(4)<>-1 THEN 7360
2040 IF RM<>2 THEN 7360
2050 PRINT"Le grue a vecu plus de 100 ans et au fil du temps, il a appris a se nourrir !!!": GOTO 540
2060 GOTO 7580
2070 REM ----------------------------------------------------------------------
2080 IF F$<>"PRENDRE" THEN 2560
2090 IF EI>4 THEN PRINT"Je porte trop de choses !": GOTO 540
2100 FOR I=1 TO NO: IF S$=OB$(I) THEN 2110
2101 NEXT I : GOTO 7310
2110 IF OB(I)<>-1 THEN 2120
2111 GOTO 2140
2120 IF S$<>OB$(26) THEN 2170
2130 IF PR=1 OR PA=0 AND RM=7 THEN PRINT "Comment ?": GOTO 540
2140 IF PA=1 AND OB(26)=RM THEN 2540
2150 IF RM<>7 THEN 7380
2160 IF OB(26)=-1 THEN 7480
2170 IF S$=OB$(52) THEN 2180
2171 GOTO 2200
2180 IF RM=31 AND MC=1 THEN 7400
2190 GOTO 7560
2200 IF OB(I)<>RM THEN 7380
2210 IF S$=OB$(36) THEN PRINT"C'est lourd !": GOSUB 8090: GOTO 2540
2220 IF S$=OB$(1) THEN 2540
2230 IF S$=OB$(48) THEN 2540
2240 IF S$=OB$(51) THEN 7190
2250 IF S$=OB$(44) AND GS=0 THEN 2540
2260 IF S$=OB$(44) AND GS=1 THEN PRINT"Trop chaud !": GOTO 540
2270 IF S$=OB$(43) THEN PRINT"Je ressens sa puissance !": GOSUB 8090: GOTO 2540
2280 IF S$=OB$(8) THEN 2540
2290 IF S$=OB$(9) AND MP<>1 THEN PRINT"Le marchand veut quelque chose.": GOTO 540
2300 IF S$=OB$(9) AND MP=1 THEN 2540
2310 IF S$=OB$(18) THEN PRINT"C'est trop lourd !": GOTO 540
2320 IF S$=OB$(38) THEN PRINT"C'est trop lourd !": GOTO 540
2330 FOR X=10 TO 11: IF S$=OB$(X) THEN 2540
2331 NEXT X
2340 FOR Y=13 TO 15: IF S$=OB$(Y) THEN 2540
2341 NEXT Y
2350 IF S$=OB$(18) THEN 7400
2360 IF S$=OB$(12) THEN 7400
2370 IF S$=OB$(19) THEN 2540
2380 IF S$=OB$(26) THEN 2540
2390 IF S$=OB$(27) THEN 2540
2400 IF S$=OB$(31) THEN 2540
2410 IF S$=OB$(7) AND MS=0 THEN PRINT"Il vous evite en disant 'Vous etes une chose bizarre ??'": GOTO 540
2420 IF S$=OB$(7) AND MS=1 THEN PRINT"Je ne veux pas ramasser un corps avec des boyaux partout !": GOTO 540
2430 IF S$=OB$(34) THEN 2540
2440 IF S$=OB$(35) AND UH=1 THEN 2540
2450 IF S$=OB$(37) AND PS=1 THEN 2540
2460 IF S$<>OB$(22) THEN 2490
2470 PRINT "Non merci !"
2480 GOTO 540
2490 IF S$=OB$(24) THEN PRINT"C'est coince !!": GOTO 540
2500 IF S$=OB$(4) AND AA=0 THEN PRINT"Je ne vois pas de pomme par ici !": GOTO 540
2510 IF S$=OB$(4) AND AD<>1 THEN PRINT"Je ne peux pas l'atteindre !": GOTO 540
2520 IF S$=OB$(4) AND AD=1 THEN OB(4)=-1: EI=EI+1 : GOTO 3630
2530 GOTO 7400
2540 OB(I)=-1: EI=EI+1: GOTO 3630 :REM EI = enough inventory
2550 REM ----------------------------------------------------------------------
2560 IF F$<>"ALLER" THEN 2930
2570 IF S$<>OB$(5) THEN 2630
2580 IF RM<>2 THEN 7360
2590 IF GG<>1 THEN 2790
2600 IF OB(1)=-1 THEN PRINT"Quelque chose ne rentre pas !": GOTO 540
2610 IF S$=OB$(5) AND RM<>2 THEN 7360
2620 GOTO 6240
2630 FOR I=1 TO NO: IF S$=OB$(I) THEN 2640
2631 NEXT I: GOTO 7360
2640 IF S$="PLANCHE" THEN 2750
2650 IF S$=OB$(52) AND RM=31 AND MC=1 THEN 7290
2660 IF OB(I)<>RM THEN 7360
2670 IF S$=OB$(6) AND RM=7 THEN 6390
2680 IF S$=OB$(25) THEN 6940
2690 IF S$=OB$(17) THEN 6880
2700 IF S$=OB$(1) THEN 830
2710 IF S$=OB$(42) THEN 6820
2720 IF S$=OB$(29) THEN PRINT "J'ai ete emporte par le courant, et je me noie.": GOTO 7620
2730 IF S$=OB$(23) THEN 7000
2740 IF S$<>OB$(26) THEN 2830
2750 IF PR<>1 THEN 7600
2760 IF RM=14 THEN 6600
2770 IF RM=15 THEN 6570
2780 GOTO 7600
2790 IF GG<> 1 THEN PRINT"Le grue ne me laisse pas faire !": GOTO 540
2800 GOTO 6240
2810 IF AI<>1 THEN PRINT"Je ne comprends pas ce que vous voulez dire.": GOTO 540
2820 GOTO 7000
2830 IF S$<>OB$(33) THEN 2860
2840 IF RM<>12 THEN 7360
2850 GOTO 6480
2860 IF S$<>OB$(30) THEN 2890
2870 IF CC<>1 THEN PRINT "Seuls les fantomes peuvent passer les portes !": GOTO 540
2880 IF CC=1 THEN 6730
2890 IF S$<>OB$(32) THEN 2910
2900 IF PS=1 AND DO=1 THEN 7060
2901 GOTO 7360
2910 GOTO 7310
2920 REM ----------------------------------------------------------------------
2930 IF F$<>"DONNER" THEN 3110
2940 FOR I=1 TO NO: IF S$=OB$(I) THEN 2960
2950 NEXT I: GOTO 7310
2960 IF S$<>OB$(4) THEN 3010
2970 IF RM=13 THEN 3060
2980 IF RM<>2 THEN 7360
2990 IF OB(4)<>-1 THEN 7360
3000 PRINT"A qui ?": GOTO 540
3010 IF S$<>OB$(19) THEN 3050
3020 IF RM<>13 THEN 7360
3030 IF OB(19)<>-1 THEN 7360
3040 CM=1: GOTO 3000
3050 IF S$<>OB$(4) THEN 7600
3060 IF OB(4)<>-1 THEN 7360
3070 PRINT"A qui ?": ME=1: AM=1: GOTO 540
3080 GOTO 7600
3090 REM
3100 REM ----------------------------------------------------------------------
3110 IF F$<>"I" THEN 3200
3120 Z=0: FOR I=1 TO NO: IF OB(I)=-1 THEN Z=Z+1
3130 NEXT I
3140 IF Z=0 THEN PRINT"Je n'ai rien sur moi.": GOTO 540
3150 PRINT:PRINT"Je transporte ce qui suit :"
3160 FOR I=1 TO NO
3170 IF OB(I)=-1 THEN PRINT OB$(I)+". ";
3180 NEXT I: PRINT
3190 GOTO 540
3200 IF F$<>"INSERER" THEN 3310
3210 FOR I=1 TO NO: IF S$=OB$(I) THEN  3230
3220 NEXT I: GOTO 7310
3230 IF S$<>OB$(14) THEN 3290
3240 IF OB(14)<>-1 THEN 7360
3250 IF RM<>18 THEN 7360
3260 PRINT"Elle rentre parfaitement dans le trou.": GOSUB 8090
3270 OB(14)=0:EI=EI-1:AI=1
3280 GOTO 3630
3290 GOTO 7580
3300 REM ----------------------------------------------------------------------
3310 IF F$<>"SAUTER" THEN 3520
3320 IF RM<>29 THEN 3370
3330 IF CL=1 THEN 6330
3340 PRINT" Je saute, et heureusement retombe sur l'echelle - sauter depuis une echelle n'est pas une chose a faire !"
3350 CL=0
3360 GOTO 540
3370 IF RM<>16 THEN 3410
3380 PRINT"Je saute a travers le gouffre, et arrive de justesse de l'autre cote."
3390 GOSUB 8090
3400 GOTO 6660
3410 IF RM<>17 THEN 3460
3420 IF OB(36)=-1 THEN PRINT"Le poids de la pierre raccourcit le saut, et je tombe dans le gouffre.": GOTO 7620
3430 PRINT"Je saute par dessus le gouffre, et j'arrive juste a l'autre cote."
3440 GOSUB 8090
3450 GOTO 6630
3460 IF RM<>1 THEN 3480
3470 PRINT"Je saute le plus loin possible, mais il me manque quelques centimetres pour atteindre le sommet.": GOTO 540
3480 IF RM<>2 THEN 3500
3490 PRINT"Je me cogne la tete sur le toit.": GOTO 540
3500 PRINT"Whee !!": GOTO 540
3510 REM ----------------------------------------------------------------------
3520 IF F$<>"TUER" THEN 3620
3530 IF S$=OB$(7) AND RM=13 AND MS=0 THEN 3570
3540 IF S$=OB$(46) AND RM=30 AND DD=0 THEN 3580
3550 IF S$=OB$(2) AND RM=2 AND GG=0 THEN 3560
3551 GOTO 7600
3560 IF S$<>OB$(2) AND RM<>2 THEN 3570
3561 GOTO 3590
3570 IF S$<>OB$(7) AND RM<>13 THEN 3580
3571 GOTO 3590
3580 IF S$<>OB$(46) AND RM<>30 THEN 3600
3581 GOTO 3590
3590 PRINT"Comment ?": GOTO 540
3600 GOTO 7580
3610 REM ----------------------------------------------------------------------
3620 IF F$<>"REGARDER" THEN 3750
3630 HOME
3640 PRINT RM$(RM)+VI$
3650 PRINT
3670 FOR I=1 TO NO: IF OB(I)=RM THEN PRINT OB$(I)+". ";
3680 NEXT I
3700 PRINT:PRINT
3710 PRINT"Les sorties visibles sont : -";
3720 PRINT DI$(RM)
3721 FOR I = 1 TO 80 : PRINT CHR$(45); : NEXT I
3722 PRINT
3730 GOTO 540
3740 REM ----------------------------------------------------------------------
3750 IF F$<>"DEPLACER" THEN 3850
3760 FOR I=1 TO NO: IF OB$(I)=S$ THEN 3770
3761 NEXT I: GOTO 7310
3770 IF S$<>OB$(38) THEN 3810
3780 IF RM<>31 THEN 7360
3790 IF MC=1 THEN 3800
3791 PRINT"Apres avoir deplace le coffre, vous decouvrez un petit trou en dessous.": GOSUB 8090: OB(52)=31: MC=1: GOTO 3630
3800 PRINT"OK, je le deplace a nouveau sur le trou.": OB(52)=0: MC=0: GOSUB 8090: GOTO 3630
3810 IF S$=OB$(36) THEN PRINT"OK": GOTO 540
3820 FOR I=1 TO NO: IF S$=OB$(I) THEN 7580
3821 NEXT I
3830 GOTO 7310
3840 REM ----------------------------------------------------------------------
3850 IF F$<>"N" THEN 3980
3860 IF RM=1 THEN 6210
3870 IF RM=16 THEN 6600
3880 IF RM=13 THEN 6330
3890 IF RM=20 THEN 6820
3900 IF RM=24 THEN 6790
3910 IF RM=6 THEN 6360
3920 IF RM<>30 THEN 3950
3930 IF DD<>1 THEN PRINT "Le dragon ne me laisse pas faire !": GOTO 540
3940 GOTO 6300
3950 IF RM=22 THEN 6910
3960 GOTO 7460
3970 REM ----------------------------------------------------------------------
3980 IF F$<>"OUVRIR" THEN 4160
3990 FOR I=1 TO NO: IF S$=OB$(I) THEN 4010
4000 NEXT I:GOTO 7310
4010 IF S$<>OB$(21) THEN 4070
4020 IF BO=1 THEN PRINT"C'est deja ouvert !": GOTO 540
4030 IF RM<>11 THEN 7360
4040 IF BU<>1 THEN PRINT "C'est ferme !":GOTO 540
4050 OB(16)=11:BO=1
4060 GOTO 3630
4070 IF S$<>OB$(32) THEN 4120
4080 IF RM<>5 THEN 7360
4090 IF PS<>1 THEN 7360
4100 PRINT"Ok.": DO=1
4110 GOTO 540
4120 IF S$<>OB$(38) THEN 7580
4130 IF RM<>31 THEN 7360
4140 PRINT"Ca ne bougera pas !": GOTO 540
4150 REM ----------------------------------------------------------------------
4160 IF F$<>"PAYER" THEN 4220
4170 IF S$<>OB$(7) THEN 4250
4180 IF MP=1 AND OB(19)=-1 THEN PRINT"OK": OB(19)=0: EI=EI-1: GOTO 540
4190 IF RM<>13 THEN 7360
4200 IF OB(19)<>-1 THEN 7360
4210 OB(19)=0: EI=EI-1:MP=1:PRINT"Le marchand vous offre la pelle.": GOTO 540
4219 REM ----------------------------------------------------------------------
4220 IF F$<>"METTRE" THEN 4330
4230 FOR I=1 TO NO: IF S$=OB$(I) THEN 4260
4240 NEXT I: GOTO 7310
4250 GOTO 7580
4260 IF S$<>OB$(26) THEN 4320
4270 IF OB(26)<>-1 THEN 7360
4280 IF RM<>14 THEN 4320
4290 PRINT"La planche est placee au-dessus de la riviere."
4300 GOSUB 8090
4310 OB(41)=15: OB(26)=RM:PR=1
4320 OB(I)=RM: EI=EI-1:GOTO 3630
4330 IF F$<>"TIRER" THEN 4380
4340 IF S$<>OB$(16) THEN 4390
4350 PRINT"Vous entendez un bruit sourd, mais rien ne semble se passer."
4360 OB(42)=12: DB=1
4370 GOTO 540
4379 REM ----------------------------------------------------------------------
4380 IF F$<>"PLACER" THEN 4410
4390 GOTO 4230
4400 REM ----------------------------------------------------------------------
4410 IF F$<>"QUITTER" THEN 4480
4420 PRINT"Etes-vous sur de vouloir Quitter <O/N> ?"
4430 GOSUB 7730
4440 GET Z$ : IF Z$="O" OR Z$="o" THEN 7630
4450 IF Z$="N" OR Z$="n" THEN 4460
4451 GOTO 4440
4460 PRINT"OK": GOTO 540
4470 REM ----------------------------------------------------------------------
4480 IF F$<>"LIRE" THEN 4600
4490 FOR I=1 TO NO: IF S$=OB$(I) THEN 4510
4500 NEXT I: GOTO 7310
4510 IF S$<>OB$(24) THEN 4560
4520 IF WG<>1 THEN 7360
4530 IF RM<>1 THEN 7360
4540 PRINT: PRINT"                         Si vous etes COLLE,": PRINT"                         alors le mot magique est ":PRINT"                         dans l'ordre alphabetique ;"
4550 PRINT"                         et 5 de long ; et n'oubliez pas ": PRINT"                         le premier est aussi le ": PRINT "                         dernier...": PRINT: GOTO 540
4560 IF S$<>OB$(18) THEN 4580
4570 IF RM<>21 OR WG<>1 THEN 7360
4580 PRINT"Le Livre n'a qu'un seul mot ecrit :": PRINT:PRINT" RACK": PRINT:OB(17)=21: GOSUB 8090
4590 GOTO 3630
4599 REM ----------------------------------------------------------------------
4600 IF F$<>"RESTAURER" THEN 4700
4610 IF S$<>"JEU" THEN 7310
4620 PRINT CHR$(4);"OPEN ELGON.SAV"
4621 PRINT CHR$(4);"READ ELGON.SAV"
4630 FOR I=1 TO NO: INPUT OB(I) : NEXT I
4640 INPUT RM
4650 INPUT BA:INPUT GG:INPUT DD:INPUT CL:INPUT CC:INPUT AD:INPUT EI:INPUT DF:INPUT SA
4655 INPUT DS:INPUT AI:INPUT PR:INPUT PA:INPUT MP:INPUT UH:INPUT PS:INPUT EG
4660 INPUT DO:INPUT YS:INPUT BO:INPUT BU:INPUT SA:INPUT CR:INPUT WG:INPUT CM
4665 INPUT AM:INPUT ME:INPUT SH:INPUT GS:INPUT MS:INPUT AA:INPUT MC:INPUT AD
4670 PRINT CHR$(4);"CLOSE ELGON.SAV"
4680 GOTO 3630
4690 REM ----------------------------------------------------------------------
4700 IF F$<>"S" THEN 4810
4710 IF RM=22 THEN 6760
4720 IF RM=6 THEN 6540
4730 IF RM=2 THEN 6180
4740 IF RM=7 THEN 6330
4750 IF RM=8 THEN 6360
4760 IF RM=11 THEN 6510
4770 IF RM=25 THEN 6820
4780 IF RM=15 THEN 6630
4790 IF RM=28 THEN 6700
4800 GOTO 7460
4809 REM ----------------------------------------------------------------------
4810 IF F$<>"OCCIRE" THEN 4900
4820 IF S$<>OB$(46) THEN 4870
4830 IF RM<>30 THEN 7360
4840 IF OB(43)<>-1 THEN 7360
4850 IF DD=1 THEN PRINT"Quel Dragon ?": GOTO 540
4860 GOTO 5690
4870 IF S$<>OB$(7) THEN 7610
4880 IF OB(43)<>-1 OR RM<>13 THEN 7360
4890 MS=1: PRINT"Vous tuez le pauvre marchand.": GOTO 540
4899 REM ----------------------------------------------------------------------
4900 IF F$<>"MONTRER" THEN 4990
4910 FOR I=1 TO NO: IF S$=OB$(I) THEN 4930
4920 NEXT I: GOTO 7310
4930 IF S$<>OB$(10) THEN 5460
4940 IF OB(10)<>-1 THEN 7360
4950 IF RM<>15 THEN 7440
4960 PRINT"Le fantome pousse un cri strident en se desintegrant.": GOSUB 8090
4970 OB(11)=0: SA=1
4980 GOTO 3630
4989 REM ----------------------------------------------------------------------
4990 IF F$<>"DIRE" THEN 5090
5000 IF S$<>"ACKRA" THEN 5080
5010 IF CR=1 THEN PRINT"OK": PRINT S$: GOTO 540
5020 IF RM<>18 THEN PRINT"OK": PRINT S$: GOTO 540
5030 IF AI<>1 THEN PRINT"OK": PRINT S$: GOTO 540
5040 PRINT"Un faisceau de lumiere descend du ciel, et se reflete a travers la croix, ouvrant un petit passage dans la falaise."
5050 OB(23)=18:CR=1
5060 GOSUB 8090
5070 GOTO 3630
5080 PRINT"OK": PRINT S$: GOTO 540
5089 REM ----------------------------------------------------------------------
5090 IF F$<>"AIGUISER" THEN 5150
5100 IF S$<>OB$(8) THEN 7580
5110 IF OB(8)<>-1 THEN 7360
5120 IF RM<>28 THEN 7360
5130 PRINT"La hache est tranchante comme a l'origine.": BA=0: GOTO 540
5140 GOTO 7580
5149 REM ----------------------------------------------------------------------
5150 IF F$<>"SCIER" THEN 5210
5160 IF S$<>OB$(37) THEN 7580
5170 IF OB(27)<>-1 THEN 7360
5180 IF RM<>5 THEN 7360
5190 IF PS=1 THEN PRINT "Je l'ai deja fait !": GOTO 540
5200 PRINT"Le cadenas cede facilement, et tombe sur le sol.": PS=1: GOTO 540
5209 REM ----------------------------------------------------------------------
5210 IF F$<>"SECOUER" THEN 5250
5220 IF S$<>OB$(3) THEN 7580
5230 IF RM<>6 THEN 7360
5240 PRINT"Je secoue l'arbre aussi fort que je peux, mais il est aussi dur que la pierre - la pomme ne bouge meme pas": GOTO 540
5249 REM ----------------------------------------------------------------------
5250 IF F$<>"SAUVEGARDER" THEN 5350
5260 IF S$<>"JEU" THEN 7320
5270 SV$="ELGON.SAV"
5280 PRINT CHR$(4);"OPEN ELGON.SAV"
5285 PRINT CHR$(4);"WRITE ELGON.SAV"
5290 FOR I=1 TO NO: PRINT OB(I): NEXT I
5300 PRINT RM
5310 PRINT BA:PRINT GG:PRINT DD:PRINT CL:PRINT CC:PRINT AD:PRINT EI:PRINT DF:PRINT SA
5311 PRINT DS:PRINT AI:PRINT PR:PRINT PA:PRINT MP:PRINT UH:PRINT PS:PRINT EG
5320 PRINT DO:PRINT YS:PRINT BO:PRINT BU:PRINT SA:PRINT CR:PRINT WG:PRINT CM
5321 PRINT AM:PRINT ME:PRINT SH:PRINT GS:PRINT MS:PRINT AA:PRINT MC:PRINT AD
5330 PRINT CHR$(4);"CLOSE ELGON.SAV": PRINT "OK": GOTO 540
5340 REM ----------------------------------------------------------------------
5350 IF F$<>"AU" THEN 5530
5360 IF AM=1 THEN 5380
5370 IF CM=1 THEN 5480
5371 GOTO 5440
5380 IF ME<>1 THEN 5430
5390 IF OB(4)<>-1 THEN 7360
5400 IF RM<>13 THEN 7360
5410 IF MP=1 THEN PRINT"OK": OB(4)=0: EI=EI-1:AM=0: ME=0: GOTO 540
5420 IF MP<>1 THEN PRINT"Le marchand vous donne la pelle.": MP=1: OB(4)=0:EI=EI-1: ME=0: AM=0: GOTO 540
5430 FOR I=1 TO NO: IF S$=OB$(I) THEN 5440
5431 NEXT I: GOTO 7580
5440 IF S$<>OB$(2) THEN 7310
5450 IF OB(4)<>-1 THEN 7360
5460 IF RM<>2 THEN 7360
5470 GG=1: OB(4)=0: EI=EI-1:OB(2)=0: PRINT"Le grue disparait dans le mur.": GOSUB 8090: GOTO 3630
5480 IF S$<>OB$(7) THEN 7580
5490 IF RM<>13 THEN 7360
5500 IF MP=1 THEN PRINT"OK": OB(19)=0: EI=EI-1:CM=0: GOTO 540
5510 IF OB(19)<>-1 THEN 7360
5511 PRINT"Le marchand vous donne la pelle": MP=1: OB(19)=0:EI=EI-1: CM=0: GOTO 540
5520 REM ----------------------------------------------------------------------
5530 IF F$<>"H" THEN 5580
5540 IF RM=32 THEN 7140
5550 IF RM<>26 THEN 5570
5560 GOTO 6850
5570 GOTO 7460
5579 REM ----------------------------------------------------------------------
5580 IF F$<>"UTILISER" THEN 5760
5590 FOR I=1 TO NO: IF S$=OB$(I) THEN 5610
5600 NEXT I: GOTO 7310
5610 IF S$<>OB$(34) THEN 5660
5620 IF OB(34)<>-1 THEN 7360
5630 IF PA=1 THEN 7600
5640 IF RM<>7 THEN 7440
5650 PA=1: OB(26)=7: PRINT"OK": GOTO 3630
5660 GOTO 5710
5670 REM
5680 REM
5690 PRINT"Vous tuez le dragon avec une force incroyable, et il disparait dans le neant."
5700 GOSUB 8090: DD=1: OB(46)=0: GOTO 3630
5710 IF S$<>OB$(43) THEN 5740
5720 IF RM=13 AND MS=0 THEN 4890
5730 IF RM=30 AND DD=0 THEN 5690
5740 PRINT"Ca ne marche pas.": GOTO 540
5750 GOTO 7580
5759 REM ----------------------------------------------------------------------
5760 IF F$<>"DEVERROUILLER" THEN 5840
5770 FOR I=1 TO NO: IF S$=OB$(I) THEN 5790
5780 NEXT I: GOTO 7310
5790 IF S$<>OB$(21) THEN 5880
5800 IF OB(15)<>-1 THEN 7360
5810 IF RM<>11 THEN 7360
5820 IF BU=1 THEN PRINT"C'est deja deverrouille !": GOTO 540
5830 BU=1: PRINT"OK": GOTO 540
5840 IF F$<>"OTER" THEN 5891
5850 IF S$<>OB$(31) THEN PRINT"Ce serait difficile de mettre ca.": GOTO 540
5860 IF OB(31)<>-1 AND WG<>0 THEN PRINT"Je ne les porte pas.": GOTO 540
5870 PRINT"OK": WG=0: GOTO 540
5880 GOTO 7580
5890 REM ----------------------------------------------------------------------
5891 IF F$<> "V" AND F$ <> "VOC" THEN 5910
5892 PRINT:PRINT "Les actions possibles sont :"
5893 PRINT "ACHETER,GRIMPER,ABATTRE,COUPER,POSER,CREUSER,EXAMINER,NOURRIR,PRENDRE,ALLER,"
5894 PRINT "DONNER,INSERER,SAUTER,TUER,REGARDER,DEPLACER,OUVRIR,PAYER,METTRE,TIRER,PLACER,"
5895 PRINT "QUITTER,LIRE,RESTAURER,OCCIRE,MONTRER,DIRE,AIGUISER,SCIER,SECOUER,SAUVEGARDER,  AU,UTILISER,DEVERROUILLER,OTER,PASSER,AVEC"
5896 PRINT:GOTO 540
5900 REM ----------------------------------------------------------------------
5910 IF F$<>"O" THEN 6060
5920 IF RM=3 THEN 6270
5930 IF RM=4 THEN 6300
5940 IF RM=8 THEN 6420
5950 IF RM=10 THEN 6390
5960 IF RM=26 THEN 6970
5970 IF RM=23 THEN 6910
5980 IF RM=21 THEN 6820
5990 IF RM=12 THEN 6330
6000 IF RM=13 THEN 6570
6010 IF RM=17 THEN 6700
6020 IF RM=22 THEN 6510
6030 IF RM=19 THEN 6760
6040 IF RM=31 THEN 7060
6050 GOTO 7460
6059 REM ----------------------------------------------------------------------
6060 IF F$<>"PASSER" THEN 6130
6070 FOR I=1 TO NO: IF S$=OB$(I) THEN 6090
6080 NEXT I: GOTO 7310
6090 IF S$<>OB$(31) THEN 6120
6100 IF OB(31)<>-1 THEN 7360
6110 WG=1: PRINT"OK": GOTO 540
6120 GOTO 7600
6129 REM ----------------------------------------------------------------------
6130 IF F$<>"AVEC" THEN 7310
6140 GOTO 5590
6150 REM
6160 REM
6170 GOTO 7310
6180 REM *** Room 1 ***
6190 RM=1
6200 GOTO 3630
6210 REM *** Room 2 ***
6220 RM=2
6230 GOTO 3630
6240 REM *** Room 3 ***
6250 RM=3
6260 GOTO 3630
6270 REM *** Room 4 ***
6280 RM=4
6290 GOTO 3630
6300 REM *** Room 5 ***
6310 RM=5
6320 GOTO 3630
6330 REM *** Room 6 ***
6340 RM=6
6350 GOTO 3630
6360 REM *** Room 7 ***
6370 RM=7
6380 GOTO 3630
6390 REM *** Room 8 ***
6400 RM=8
6410 GOTO 3630
6420 REM *** Room 9 ***
6430 RM=9
6440 GOTO 3630
6450 REM *** Room 10 ***
6460 RM=10
6470 GOTO 3630
6480 REM *** Room 11 ***
6490 RM=11
6500 GOTO 3630
6510 REM *** Room 12 ***
6520 RM=12
6530 GOTO 3630
6540 REM *** Room 13 ***
6550 RM=13
6560 GOTO 3630
6570 REM *** Room 14 ***
6580 RM=14
6590 GOTO 3630
6600 REM *** Room 15 ***
6610 RM=15
6620 GOTO 3630
6630 REM *** Room 16 ***
6640 RM=16
6650 GOTO 3630
6660 REM *** Room 17 ***
6670 RM=17
6680 OB(47)=17
6690 GOTO 3630
6700 REM *** Room 18 ***
6710 RM=18
6720 GOTO 3630
6730 REM *** Room 19 ***
6740 RM=19
6750 GOTO 3630
6760 REM *** Room 20 ***
6770 RM=20
6780 GOTO 3630
6790 REM *** Room 21 ***
6800 RM=21
6810 GOTO 3630
6820 REM *** Room 22 ***
6830 RM=22
6840 GOTO 3630
6850 REM *** Room 23 ***
6860 RM=23
6870 GOTO 3630
6880 REM *** Room 24 ***
6890 RM=24
6900 GOTO 3630
6910 REM *** Room 25 ***
6920 RM=25
6930 GOTO 3630
6940 REM *** Room 26 ***
6950 RM=26
6960 GOTO 3630
6970 REM *** Room 27 ***
6980 RM=27
6990 GOTO 3630
7000 REM *** Room 28 ***
7010 RM=28
7020 GOTO 3630
7030 REM *** Room 32 ***
7040 RM=29
7050 GOTO 3630
7060 REM *** Room 30 ***
7070 RM=30
7080 IF DD=1 THEN 3630
7090 HOME: PRINT RM$(RM)+VI$: PRINT
7091 FOR I=1 TO NO: IF OB(I)=RM THEN PRINT OB$(I) : GOTO 7100
7092 NEXT I
7100 PRINT: PRINT"Sorties visibles :- ";DI$(RM)
7101 FOR I = 1 TO 80 : PRINT CHR$(45); : NEXT I
7102 PRINT
7110 IF OB(44)<>-1 THEN PRINT"J'ai ete brule par un dragon cracheur de feu !": GOTO 7620
7120 IF OB(44)=-1 THEN PRINT"Le dragon m'envoie son souffle enflamme, mais il est renvoye par mon bouclier.":FB=0
7130 GOTO 540
7140 REM *** Room 31 ***
7150 RM=31
7160 OB(38)=RM
7170 GOTO 3630
7180 HOME
7190 FA$="FANTASTIQUE !!!! Vous l'avez resolu !"
7200 FOR X=13 TO 20: PRINT: NEXT X
7210 FOR I=1 TO LEN(FA$)
7220 PRINT MID$(FA$,I,1);
7230 NEXT I
7240 GOTO 7630
7250 REM *** Ladder Room ***
7260 SR=RM
7270 RM=29
7280 GOTO 3630
7290 REM *** Room 32 ***
7300 RM=32: OB(51)=RM: GOTO 3630
7310 REM *** Errors ***
7320 PRINT"Je ne comprends pas !"
7330 GOTO 540
7340 PRINT"Je ne porte rien !"
7350 GOTO 540
7360 PRINT"Je ne peux pas faire ca...pour l'instant !"
7370 GOTO 540
7380 PRINT"Je ne peux pas le voir ici."
7390 GOTO 540
7400 PRINT"C'est au-dela de mes pouvoirs."
7410 GOTO 540
7420 PRINT"Je ne vois rien de special."
7430 GOTO 540
7440 PRINT"Il ne se passe rien."
7450 GOTO 540
7460 PRINT"Je ne peux pas aller par la !"
7470 GOTO 540
7480 PRINT"J'ai deja ca."
7490 GOTO 540
7500 PRINT"Je n'ai rien trouve !"
7510 GOTO 540
7520 PRINT"J'ai trouve quelque chose !"
7530 GOSUB 8090: GOTO 3630
7540 PRINT"Hein ?"
7550 GOTO 540
7560 PRINT"Quoi ?"
7570 GOTO 540
7580 PRINT"Je ne peux pas faire ca."
7590 GOTO 540
7600 PRINT"Desole."
7610 GOTO 540
7620 PRINT"Je suis mort !"
7630 PA$="Rejouer (O/N) ? "
7640 FOR I = 1 TO 78 : PRINT CHR$(32); : NEXT I
7645 PRINT
7650 FOR I=1 TO LEN(PA$)
7660 PRINT MID$(PA$,I,1);
7670 FOR K=1 TO 40: NEXT K
7680 NEXT I
7690 GET P$
7700 IF P$="O" OR P$="o" THEN RESTORE: CLEAR : GOTO 10
7710 IF P$="N" OR P$="n" THEN PRINT:PRINT:PRINT TAB(35);"Au revoir...":END
7720 GOTO 7690
7729 REM <---- Function to replace lowercases by uppercases ---->
7730 IF A$="" THEN RETURN
7735 FOR J=1 TO LEN(A$)
7740 C$=MID$(A$,J,1): IF ASC(C$)<97 THEN 7760
7750 X$ = CHR$(ASC(C$)-32)
7751 IF J=1 THEN A$ = X$ + MID$(A$, J+1, LEN(A$)) : GOTO 7760
7752 A$ = LEFT$(A$,J-1) + X$ + MID$(A$, J+1, LEN(A$))
7760 NEXT J
7770 RETURN
7780 DATA 2,2,6,0,2,7,13,7,13,0,15,15,0,27,0,0,0,21,4,18
7781 DATA 11,23,0,1,23,0,19,0,14,20,9,5,12,10,7,28,5,31,16,15
7782 DATA 0,0,25,24,0,30,17,0,1,0,0,0
7790 DATA "ECHELLE","GRUE","ARBRE","POMME","TUNNEL","CABANE","MARCHAND"
7791 DATA "HACHE","PELLE","AMULETTE","FANTOME","TOMBE","OS","CROIX"
7792 DATA "CLEF","LEVIER","PASSAGE","LIVRE","PIECE","SOUCHE","BOITE"
7793 DATA "SQUELETTE","SOUTERRAIN","PANNEAU","ESCALIERS","PLANCHE","SCIE","TROU"
7794 DATA "RIVIERE","PLACARD"
7800 DATA "LUNETTES","PORTE","POSTE","MARTEAU","CLOTURE","PIERRE","CADENAS"
7801 DATA "COFFRE","GOUFFRE","RIVIERE","PLANCHE","PONT-LEVIS","EPEE","BOUCLIER"
7802 DATA "VOUTE","DRAGON","GOUFFRE","COPEAUX","FOSSE","COPEAUX","TRESOR","TROU"
7810 REM *** Heading ***
7820 HOME: PRINT:PRINT
7825 PRINT TAB(18);"    L E   T R E S O R   D ' E L G O N ":PRINT:PRINT
7830 PRINT"        A         V    V   EEEEE  N     N  TTTTT  U    U  RRRR   EEEEE"
7840 PRINT"       A A        V    V   E      NN    N    T    U    U  R   R  E"
7850 PRINT"      AAAAA        V  V    EEE    N NN  N    T    U    U  RRRRR  EEE"
7860 PRINT"     A     A       V  V    E      N  NN N    T    U    U  R RR   E"
7870 PRINT"     A     A        VV     EEEEE  N    NN    T    UUUUUU  R   R  EEEEE"
7880 PRINT:PRINT
7890 PRINT"                            Par : Keith Hawthorn."
7900 PRINT"                            --------------------"
7905 PRINT:PRINT"                  <Modifie pour l'Apple II par D.Rioual>"
7910 PRINT:PRINT:PRINT"             Appuyez sur n'importe quelle touche pour demarrer le jeu !"
7920 GET Z$ : IF Z$="" THEN 7920
7930 HOME
7940 PRINT"                             Le tresor d'Elgon."
7950 PRINT"                             ------------------"
7960 PRINT:PRINT:PRINT
7970 PRINT"         Dans cette aventure, vous devez trouver le tresor d'Elgon,": PRINT: PRINT"       mais sur votre chemin, vous rencontrerez de nombreux obstacles."
7980 PRINT: PRINT"    Sont acceptees les commandes en deux mots : examiner grue, grimper fosse": PRINT
7990 PRINT "          Vous pouvez aussi SAUVEGARDER LE JEU, et RESTAURER LE JEU.":PRINT
8000 PRINT"           GGGG  OOO   OOO  DDDD      L     U   U  CCCC K   K   ! ! !"
8010 PRINT"          G     O   O O   O D   D     L     U   U C     K KK    ! ! !"
8020 PRINT"          G  GG O   O O   O D   D     L     U   U C     KK      ! ! !"
8030 PRINT"          G   G O   O O   O D   D     L     U   U C     K KK"
8040 PRINT"           GGG   OOO   OOO  DDDD      LLLLL  UUU   CCCC K   K   ! ! !"
8050 PRINT:PRINT:PRINT:PRINT"               Voulez-vous restaurer une partie sauvegardee ?"
8060 GET Z$:IF Z$="O" OR Z$="o" THEN PRINT CHR$(4):GOTO 4620
8070 IF Z$="N" OR Z$="n" THEN RETURN
8080 GOTO 8060
8090 REM <==== WAIT FOR KEY ====>
8100 PRINT:PRINT"Appuyez sur une touche pour continuer."
8110 GET Z$ :IF Z$="" THEN 8110
8111 RETURN