1 REM *********************************
2 REM * L'ivresse de l'or,Ver 1       *
3 REM * (c) 1984 by Walkowiak         *
4 REM *********************************
5 REM 16/09/2022 - Correctifs sous VSC
50 TEXT:HOME
100 D$=CHR$(4)
110 AR=31:REM nb de lieux
120 AO=45:REM nb OBJET
130 AV=11
140 AF=7:REM nb verbes
150 JOUEUR=1
160 WL=4
170 WMAX=60
171 EVL=0
180 COUP=0
185 IMAX=4
186 LM=0:LUMIERE=-1:LW=1:L1=20
190 DIM LIEU$(AR):DIM PASSAGE(AR,6):DIM OB$(AO):DIM NOM$(AO):DIM OB(AO):DIM VERB$(AV)
191 DIM M$(10):DIM DDIRECT$(6):DIM FL(7)
195 DEBUG=0
200 REM ************************* VERBES
210 DATA "EXAMINE","PRENDS","POSE","OUVRE","UTILISE","DETRUIS","ALLUME","REMPLIS","ENTRE","SUPPRIME","FIXE"
300 REM ******************* OBJETS
301 DATA"beaucoup de grands arbres","ARBRES",1
302 DATA"beaucoup de grands arbres","ARBRES",2
303 DATA"quelques rochers","ROCHERS",2
304 DATA"une cabane en bois en ruine","CABANE",3
305 DATA"une bonbonne sale","BONBONNE",0
306 DATA"du miel","MIEL",0
307 DATA"une caisse en bois","CAISSE",3
308 DATA"une etagere branlante","ETAGERE ",0
309 DATA"un peu d'explosif","EXPLOSIF",0
310 DATA"un sombre puits naturel","PUITS",0
311 DATA"un coffre de fer rouille","COFFRE",0
312 DATA"* des pieces d'argent *","PIECES",0
313 DATA"une sombre grotte dans la roche","GROTTE",5
314 DATA"un ours a l'air mechant","OURS",0
315 DATA"d'innombrables petits arbustes","ARBUSTES",4
316 DATA"de nombreuses barres de fer","BARRE",6
317 DATA"* des pepites *","PEPITES",5
318 DATA"une barre de fer","FER",0
319 DATA"une chaine de fer","CHAINE",0
320 DATA"des rails rouilles","RAILS",7
321 DATA"une corde","CORDE",0
322 DATA"un lourd piolet","PIOLET",8
323 DATA"une vieille lampe","LAMPE",8
324 DATA "le bout de la galerie","BOUT",9
325 DATA "un crochet de fer","CROCHET",0
326 DATA "une mine","MINE",9
327 DATA "une cloison de planches","CLOISON",10
328 DATA "des decombres","DECOMBRES",11
329 DATA "de vieux sacs","SACS",0
330 DATA "des parois de pierre humides","PAROIS",13
331 DATA "un liquide nauseabond","LIQUIDE",17
332 DATA "un cadavre","CADAVRE",18
333 DATA "*des blocs d'argent*","BLOCS",0
334 DATA "*des louis d'or*","LOUIS",0
335 DATA "des toiles d'araignee","TOILES",20
336 DATA "un mur d'or","MUR",22
337 DATA "une pancarte","PANCARTE",22
338 DATA "*de l'or*","OR",31
339 DATA "une rive de 1ac","RIVE",30
340 DATA "le 1ac","LAC",30
341 DATA "des minerais d'or","MINERAI",0
342 DATA "une meche","MECHE",0
343 DATA "un luntero","LUNTERO",-1
344 DATA "-","PARADIS",0
345 DATA "un vieux wagonnet","WAGONNET",7
500 REM ********* description des lieux
501 DATA "dans la foret",1,1,1,2,0,0
502 DATA "dans la foret",2,1,1,3,0,0
503 DATA "dans la foret devant un versant de rocher",0,4,2,0,0,0
504 DATA "dans une clairiere",3,0,5,0,0,0
505 DATA "dans une clairiere",0,0,6,4,0,0
506 DATA "devant une galerie de mine. ",7,0,1,5,0,0
507 DATA "dans la galerie d'entree",8,6,0,0,0,0
508 DATA "dans un renfoncement de la galerie",9,7,8,10,0,0
509 DATA "au bout de la galerie",0,8,0,0,0,0
510 DATA "dans une galerie secondaire",11,0,8,0,0,0
511 DATA "dans une vieille mine",0,10,0,0,0,0
512 DATA "dans la grotte",0,5,0,13,0,0
513 DATA "dans la grotte",0,0,12,14,0,0
514 DATA "dans la grotte",0,16,13,15,0,0
515 DATA "dans la grotte",0,0,14,0,0,0
516 DATA "dans une galerie",14,0,0,17,0,0
517 DATA "dans une grotte secondaire",0,0,16,0,0,0
518 DATA "sur le sol de la mine",0,0,19,0,0,0
519 DATA "dans une galerie sinueuse",24,0,20,18,0,0
520 DATA "dans une galerie large",0,0,21,19,0,0
521 DATA "dans une vielle voie de taille",22,11,11,20,11,0
522 DATA "dans une coupole rocheuse",0,21,0,0,27,0
523 DATA "dans un paradis souterrain",0,0,0,0,0,0
524 DATA "dans une galerie sinueuse",26,19,24,24,24,24
525 DATA "dans une galerie sinueuse",27,24,24,29,26,24
526 DATA "dans une galerie sinueuse",27,24,26,27,27,24
527 DATA "dans une galerie sinueuse",25,24,26,27,26,24
528 DATA "dans une galerie sinueuse",24,26,26,27,0,0
529 DATA "dans une galerie sinueuse",0,27,30,27,0,0
530 DATA "devant un lac souterrain",28,0,0,0,0,0
531 DATA "dans une petite grotte",30,0,0,0,10,0
600 REM ******************* MESSAGES
601 M$(1)="Je ne vois rien de special"
602 M$(2)="Je ne suis pas si fort!"
603 M$(3)="Comment vois-tu cela ?"
604 M$(4)="L'ours prend le miel et disparait"
605 M$(5)="dans les profondeurs de la grotte. "
690 OK$="D'accord"
699 REM *********** 2eme TITRE:INTRODUCTION
700 HOME:PRINT TAB(11);:INVERSE:PRINT"  BIENVENUE DANS LA ":NORMAL
701 PRINT TAB(13);:INVERSE:PRINT" RUEE VERS L'OR ":NORMAL:PRINT
705 FOR I=1 TO 40:PRINT "_";:NEXT I
710 PRINT"A la poursuite de la fortune dans le":PRINT "nouveau monde,vous avez rencontre il y aquelques jours un vieillard agonisant"
715 PRINT"auquel vous avez porte assistance dans":PRINT "ses derniers moments."
720 PRINT"Par reconnaissance il vous a parle de savieille mine d'or et des restes de son"
725 PRINT"tresor qui y sont caches."
730 PRINT"Sur le chemin de cette mine vous avez":PRINT "echappe a d'innombrables perils."
735 PRINT "Vous aurez bientot atteint votre but et":PRINT "vous saurez enfin si le vieillard a dit vrai ou s'il delirait."
740 FOR I=1 TO 40:PRINT "_";:NEXT I:PRINT
810 FOR I=1 TO AV
815 READ VERB$(I):VERB$(I)=LEFT$(VERB$(I),WL)
820 NEXT I
830 FOR OBJET=1 TO AO
835 READ OB$(OBJET),NOM$(OBJET),OB(OBJET):NOM$(OBJET)=LEFT$(NOM$(OBJET),WL)
840 NEXT OBJET
845 FOR LIEU=1 TO AR
850 READ LIEU$(LIEU)
855 FOR DDIRECT=1 TO 6
860 READ PASSAGE(LIEU,DDIRECT)
865 NEXT DDIRECT
870 NEXT LIEU
880 PRINT:INPUT"--> Voulez-vous des conseils ?";ENTREE$
890 IF LEFT$(ENTREE$,1)="O" THEN GOSUB 900
895 GOTO 1000
899 REM ******** 3eme TITRE:INSTRUCTIONS
900 TEXT:HOME
910 PRINT"CPC Ventures - 1984 by Jorg Walkowiak"
925 FOR I=1 TO 40:PRINT "_";:NEXT I:PRINT
926 PRINT"Imaginez un robot que vous pourriez":PRINT "commander avec de nombreux ordres."
930 PRINT"Je suis ce robot et je vais m'exposer":PRINT"pour vous aux aventures les plus":PRINT"risquees."
940 PRINT"Pour que vous puissiez me diriger":PRINT"utilement je vous decrirai chaque fois"
945 PRINT "precisement la situation dans laquelle":PRINT "je me trouve."
950 PRINT"Vous me direz ensuite avec deux mots":PRINT "comme par exemple PRENDS COUTEAU ce que je dois faire.":PRINT
960 PRINT"Je comprends en outre les instructions":PRINT"INVENTAIRE,SCORE,VOCABULAIRE,HELP,SAVE & LOAD ainsi que END."
970 FOR I=1 TO 40:PRINT "_";:NEXT I:PRINT
980 PRINT TAB(6);:INVERSE : PRINT "  APPUYEZ <SUR UNE TOUCHE>  ";:NORMAL
990 GET ENTREE$
995 HOME:RETURN
1000 TEXT:HOME
1010 LIGNEVIDE$="                                        "
1020 DATA "le Nord", "le Sud", "l'Ouest", "l'Est", "en haut", "en bas"
1030 FOR DDIRECT=1 TO 6
1040 READ DDIRECT$(DDIRECT)
1050 NEXT DDIRECT
1070 HOME
1080 PRINT:PRINT:COUP=COUP+1:LW=LW+1
1084 IF LW=LM THEN GOSUB 3000
1085 IF EVL=WMAX THEN GOTO 4800
1090 HTAB 1 : VTAB 1
1091 REM ******************** PAS DE LUMIERE
1092 IF LUMIERE=-1 THEN 1100
1093 PRINT"Je ne sais pas exactement ou je suis. Il fait trop sombre pour y voir quoi que ce soit."
1095 PRINT:PRINT"Je ne vois meme plus les issues! ":GOTO 1330
1100 FOR LL=1 TO 10
1110 PRINT LIGNEVIDE$;
1120 NEXT LL
1130 VTAB 1: HTAB 1
1140 PRINT"Je suis ";
1150 PRINT LIEU$(JOUEUR);".";:IF DEBUG THEN PRINT "(";JOUEUR;")";
1151 PRINT
1160 PRINT"Je vois ";
1170 FOR I=1 TO AO
1180 IF OB(I)<>JOUEUR THEN 1210
1190 IF PEEK(36)+LEN(OB$(I))+2<=39 THEN PRINT OB$(I);", ";:GOTO 1210
1200 IF PEEK(36)+LEN(OB$(I))+2>39 THEN PRINT:GOTO 1190
1210 NEXT I
1220 PRINT CHR$(8);CHR$(8);"."
1230 PRINT LIGNEVIDE$
1240 PRINT"Je peux aller vers ";:DISP=0
1250 FOR DDIRECT=1 TO 6
1260 IF PASSAGE(JOUEUR,DDIRECT)=0 THEN GOTO 1300
1265 DISP=-1
1270 IF PEEK(36)=19 THEN PRINT DDIRECT$(DDIRECT);:GOTO 1300
1280 IF PEEK(36)+LEN(DDIRECT$(DDIRECT))<37 THEN PRINT", ";DDIRECT$(DDIRECT);:GOTO 1300
1290 PRINT",":PRINT DDIRECT$(DDIRECT);:GOTO 1300
1300 NEXT DDIRECT
1310 IF DISP=0 THEN PRINT"nulle part";
1320 PRINT"."
1330 FOR I=1 TO 40:PRINT "_";:NEXT I:PRINT
1340 IF EVL=WMAX THEN GOTO 4800
1350 IF JOUEUR=15 THEN M$(0)="Malheureusement c'est la que l'ours etait.":FOR I=1 TO 1000:NEXT I:GOTO 4500
1360 IF LW<=0 THEN LUMIERE=0
1370 IF EX=COUP AND JOUEUR=20 THEN M$(0) ="Aie ! Moi aussi j'ai ete dechiquete.":GOTO 4500
1380 IF JOUEUR>18 AND OB(23)<>-1 THEN LUMIERE=0
1390 HTAB 1:VTAB 24:INPUT"Que dois-je faire ?";ENTREE$
1395 RL=LM-LW:IF (RL>0 AND RL<15) THEN PRINT"dans";LM-LW;"coups je serai dans l'obscurite !"
1400 IF LEN(ENTREE$)>2 THEN 1500
1410 IF ENTREE$="N" AND PASSAGE(JOUEUR,1)<>0 THEN JOUEUR=PASSAGE(JOUEUR,1):PRINT OK$:GOTO 1080
1420 IF ENTREE$="S" AND PASSAGE(JOUEUR,2)<>0 THEN JOUEUR=PASSAGE(JOUEUR,2):PRINT OK$:GOTO 1080
1430 IF ENTREE$="O" AND PASSAGE(JOUEUR,3)<>0 THEN JOUEUR=PASSAGE(JOUEUR,3):PRINT OK$:GOTO 1080
1440 IF ENTREE$="E" AND PASSAGE(JOUEUR,4)<>0 THEN JOUEUR=PASSAGE(JOUEUR,4):PRINT OK$:GOTO 1080
1450 IF ENTREE$="H" AND PASSAGE(JOUEUR,5)<>0 THEN JOUEUR=PASSAGE(JOUEUR,5):PRINT OK$:GOTO 1080
1460 IF ENTREE$="B" AND PASSAGE(JOUEUR,6)<>0 THEN JOUEUR=PASSAGE(JOUEUR,6):PRINT OK$:GOTO 1080
1470 IF LEN(ENTREE$)<3 THEN PRINT"Aucun chemin n'y mene !":GOTO 1080
1480 IF LEN(ENTREE$)>8 THEN GOTO 2000
1499 REM **************** DEBUT INVENTAIRE
1500 IF LEFT$(ENTREE$,3)<>"INV" THEN GOTO 1560
1510 PRINT"Voici ce que je porte sur moi :"
1520 FOR OBJET=1 TO AO
1530 IF OB(OBJET) =-1 THEN PRINT OB$(OBJET)
1540 NEXT OBJET
1550 GOTO 1080
1560 IF LEFT$(ENTREE$,3)<>"SCO" THEN GOTO 1600
1561 PRINT"Sur";WMAX;"points,tu as obtenu en":PRINT COUP; "coups:":PRINT EVL;"points! ":PRINT"Cela correspond a une moyenne de"; EVL/COUP; "points.":GOTO 1080
1599 REM ********************* SAVE GAME
1600 IF LEFT$(ENTREE$,3)<>"SAV" THEN GOTO 1700
1610 INPUT "Sauvegarder sous quel nom ?"; ENTREE$
1620 IF LEN(ENTREE$)>8 THEN PRINT"Pas plus de 8 characteres SVP !":GOTO 1610
1621 ENTREE$=ENTREE$+".JEU":PRINT D$;"OPEN ";ENTREE$:PRINT D$;"WRITE ";ENTREE$
1625 PRINT JOUEUR
1630 FOR OBJET=1 TO AO
1631 PRINT OB(OBJET)
1632 NEXT OBJET
1635 FOR LIEU=1 TO AR
1636 FOR DDIRECT=1 TO 6
1637 PRINT PASSAGE(LIEU,DDIRECT)
1638 NEXT DDIRECT
1639 NEXT LIEU
1645 FOR FLAG=1 TO AF
1646 PRINT FL(FLAG)
1647 NEXT FLAG
1650 PRINT D$;"CLOSE ";ENTREE$
1660 PRINT OK$
1670 GOTO 1080
1699 REM ********************* LOAD GAME
1700 IF LEFT$(ENTREE$,3)<>"LOA" THEN GOTO 1800
1710 INPUT"Quel jeu faut-il charger ";ENTREE$
1720 IF LEN(ENTREE$)>8 THEN PRINT"Pas plus de 8 characteres SVP !":GOTO 1710
1721 ENTREE$=ENTREE$+".JEU":PRINT D$;"OPEN ";ENTREE$:PRINT D$;"READ ";ENTREE$
1725 INPUT JOUEUR
1730 FOR OBJET=1 TO AO
1731 INPUT OB(OBJET)
1732 NEXT OBJET
1735 FOR LIEU=1 TO AR
1736 FOR DDIRECT=1 TO 6
1737 INPUT PASSAGE(LIEU,DDIRECT)
1738 NEXT DDIRECT
1739 NEXT LIEU
1745 FOR FLAG=1 TO AF
1746 INPUT FL(FLAG)
1747 NEXT FLAG
1750 PRINT D$;"CLOSE ";ENTREE$
1760 PRINT OK$
1770 GOTO 1080
1780 PRINT"Attention erreur! ":RESUME
1800 IF LEFT$(ENTREE$,3)<>"VOC" THEN GOTO 1900
1805 HOME:PRINT"Je comprends les verbes suivants :":PRINT:RESTORE
1810 FOR I=1 TO AV
1820 READ MOT$:PRINT MOT$
1830 NEXT I
1840 GOSUB 1890
1845 HOME:PRINT"Et je connais les objets suivants :":PRINT
1849 LL=0:CL=0
1850 FOR I=1 TO AO
1860 READ MOT$,MOT$,X
1861 VTAB LL+3:HTAB 1+CL*11:PRINT MOT$
1865 LL=LL+1
1866 IF LL=20 THEN LL=0:CL=CL+1
1870 NEXT I
1880 GOSUB 1890:HOME:GOTO 1080
1890 HTAB 1:VTAB 24:PRINT "Appuyer sur une touche...";
1895 GET ENTREE$
1896 HOME:RETURN
1900 IF LEFT$(ENTREE$,3)<>"INS" THEN GOTO 1950
1910 GOSUB 900
1920 GOTO 1080
1950 IF LEFT$(ENTREE$,3)<>"END" THEN GOTO 1970
1955 HOME
1960 PRINT"Nous esperons que vous aurez plus":PRINT"de succes la prochaine fois !":PRINT:PRINT:PRINT:END
1970 IF LEFT$(ENTREE$,3)<>"HEL" THEN GOTO 2000
1971 IF JOUEUR=4 AND OB(10)=0 THEN PRINT "J'ai failli tomber dans une fosse":GOTO 1080
1972 IF JOUEUR=4 AND OB(11)<>JOUEUR AND NOT FL(2) THEN PRINT"Il me faut quelque chose pour briser la chaine !":GOTO 1080
1975 PRINT "D'abord voir,puis ref1echir !":PRINT"Et enfin agir.":GOTO 1080
1979 REM ******************** FIN HELP
2000 LG=LEN(ENTREE$)
2010 FOR LL=1 TO LG
2020 TESTE$=MID$(ENTREE$,LL,1)
2030 IF TESTE$<>" " THEN NEXT LL
2040 EVERB$=LEFT$(ENTREE$,WL)
2050 RL=LG-LL
2060 IF RL<0 THEN 2090
2070 EOBJET$=RIGHT$(ENTREE$,RL)
2080 EOBJET$=LEFT$(EOBJET$,WL)
2090 FOR NUMEROVERB=1 TO AV
2100 IF EVERB$=VERB$(NUMEROVERB) THEN 2130
2110 NEXT NUMEROVERB
2120 PRINT"Je ne comprends pas ce verbe ! ":GOTO 1080
2130 FOR OO=1 TO AO
2140 IF EOBJET$=NOM$(OO) THEN 2200
2150 NEXT OO
2160 PRINT"Je ne connais pas cet objet ! ":GOTO 1080
2190 REM    exam pren pos ouvre utilise detruis
2200 ON NUMEROVERB GOTO 5000,2210,7000,8000,9000,10000,11000,12000,13000,14000,15000
2209 REM ***************** LIMITER INV
2210 NOMBRE=0:FOR I=1 TO AO
2220 IF OB(I)=-1 THEN NOMBRE=NOMBRE+1
2230 IF NOMBRE=IMAX THEN PRINT"Non merci ! Je porte deja assez de choses.":GOTO 1080
2240 NEXT I
2250 GOTO 6000
2260 REM ****************** fin test inv
2999 REM UP commutateur
3000 IF LUMIERE=-1 THEN LUMIERE=0:GOTO 3020
3010 IF LUMIERE=0 THEN LUMIERE=-1
3020 LW=0:RETURN
4500 HOME:REM JOUEUR MORT
4600 PRINT"AIE AIE AIE !":PRINT:PRINT M$(0)
4610 PRINT:PRINT"Je suis mort ! ":PRINT
4620 INPUT"Dois-je essayer encore une fois ? ";ENTREE$
4630 IF LEFT$(ENTREE$,1)="O" THEN CLEAR:RESTORE:GOTO 1
4640 GOTO 1960
4800 HOME:REM JOUEUR GAGNE
4810 PRINT"Toutes nos felicitations !"
4820 PRINT:PRINT"Vous avez resolu l'epreuve qui vous etait imposee et vous pouvez maintenant vous lancer dans une autre aventure."
4830 PRINT:PRINT:PRINT:PRINT:PRINT:END
4999 REM *********** JOUER UN COUP
5000 IF OB(OO)<>JOUEUR AND OB(OO)<>-1 THEN GOTO 5900
5002 IF OO=1 THEN PRINT M$(1):GOTO 1080
5003 IF OO=3 THEN PRINT M$(1):GOTO 1080
5004 IF OO=4 THEN PRINT"Il y a une etagere dans un coin.":OB(8)=JOUEUR:GOTO 1080
5005 IF OO=5 THEN PRINT"La bonbonne est pleine de miel.":GOTO 1080
5006 IF OO=6 THEN PRINT M$(1):GOTO 1080
5007 IF OO=7 AND OB(9)=0 THEN PRINT"Il y a des explosifs dans la caisse. ":GOTO 1080
5008 IF OO=8 AND OB(5)=0 THEN PRINT"Il y a une bonbonne sur l'etagere.":OB(5)=JOUEUR:GOTO 1080
5009 IF OO=8 AND OB(5)<>0 THEN PRINT M$(1):GOTO 1080
5010 IF OO=10 THEN PRINT"Il y a un coffre d'acier dans le puits.":OB(11)=JOUEUR:GOTO 1080
5011 IF OO=11 AND NOT FL(1) THEN PRINT"Il est ferme par une chaine de fer.":OB(19)=JOUEUR:GOTO 1080
5012 IF OO=11 AND FL(1) AND NOT FL(2) THEN PRINT"Je ne vois rien de special exterieurement. ":GOTO 1080
5013 IF OO=11 AND FL(1) AND FL(2) AND OB(12)=0 THEN PRINT"Il est plein de pieces d'argent.":OB(12)=JOUEUR:GOTO 1080
5014 IF OO=12 THEN PRINT"C'est exactement ce que je cherche !":GOTO 1080
5015 IF OO=13 THEN PRINT"J'ai effraye un ours!":OB(14)=JOUEUR:FL(3)=0:GOTO 1080
5017 IF OO=15 THEN PRINT"Il y a un puits naturel entre les arbustes.":OB(10)=JOUEUR:GOTO 1080
5018 IF OO=16 THEN PRINT"Elles ont l'air tres stables.":GOTO 1080
5019 IF OO=17 THEN PRINT"C'est de l'or pur !":GOTO 1080
5020 IF OO=45 AND OB(21)=0 THEN PRINT"Le cable y est encore accroche.":OB(21)=JOUEUR:GOTO 1080
5021 IF OO=23 THEN PRINT"C'est une vieille lampe a huile.":GOTO 1080
5022 IF OO=24 THEN PRINT"Il y a un crochet au mur.":OB(25)=JOUEUR:GOTO 1080
5023 IF OO=25 THEN PRINT"Je regrette,il est trop enfonce. ":GOTO 1080
5024 IF OO=26 THEN M$(0)="C'est tres profond et,j'etais trop pres du bord.":GOTO 4500
5025 IF OO=27 THEN PRINT"Le menuisier etait un expert.":GOTO 1080
5026 IF OO=28 AND OB(OO)=0 THEN PRINT"J'ai decouvert deux sacs.":OB(29)=JOUEUR:GOTO 1080
5027 IF OO=29 THEN PRINT"Ils sont pleins de poussiere d'or !":GOTO 1080
5028 IF OO=31 THEN PRINT"Il est tellement huileux qu'il colle aux doigts.":GOTO 1080
5029 IF OO=32 THEN PRINT"Il pue!"
5030 IF OO=32 AND OB(34)=0 THEN PRINT"Il y a des pieces d'or dans la poche de la veste.":OB(34)=JOUEUR:GOTO 1080
5031 IF OO=35 THEN PRINT"Il n'y a pas de toiles d'araignees. ":OB(OO)=0:OB(42)=JOUEUR:PRINT"C' est une meche.":GOTO 1080
5033 IF OO=36 THEN PRINT"C'est vraiment de l'or pur.":GOTO 1080
5034 IF OO=37 THEN PRINT"Elle porte l'inscription:":PRINT"Lorsque l'avidite se reveille la mort fait alors souvent de bonnes affaires.":GOTO 1080
5036 IF OO=42 THEN PRINT"Elle va jusqu'au plafond.":GOTO 1080
5037 IF OO=43 THEN PRINT"C'est un arme a feu courante au Farwest.":GOTO 1080
5038 IF OO=32 AND FL(4)=-1 AND OB(33)<>-2 THEN PRINT"Il reposait sur des morceaux d'argent.":OB(33)=JOUEUR:GOTO 1080
5800 PRINT M$(1):GOTO 1080
5900 REM objet manquant
5901 IF OO=1 AND JOUEUR=2 THEN PRINT M$(1):GOTO 1080
5902 IF OO=6 AND OB(5)=-1 THEN PRINT"Il est doux et delicieux.":GOTO 1080
5903 IF OO=6 AND OB(5)<>-1 THEN PRINT"Je n'ai pas de miel !":GOTO 1080
5904 IF OO=9 AND (OB(7)=JOUEUR OR OB(7)=1) THEN PRINT"Il a l'air tres puissant! ":GOTO 1080
5905 IF OO=16 AND OB(18)=-1 THEN PRINT"A peine rouillees - vraiment stables! ":GOTO 1080
5910 IF OO=14 AND JOUEUR=5 AND OB(14)=5 THEN PRINT"Il semble que j'eveille son appetit. ":GOTO 1080
5911 IF OO=20 AND JOUEUR=22 THEN PRINT"Lorsque l'avidite se reveille la mort fait alors souvent de bonnes affaires. ":GOTO 1080
5912 IF OO=44 AND JOUEUR=23 THEN M$(0)="Je suis au royaume des morts.":GOTO 4500
5990 PRINT"Je ne vois rien de tel ici!":GOTO 1080
6000 IF OB(OO)<>JOUEUR AND OB(OO)<>-1 THEN GOTO 6900
6001 IF OO=1 THEN PRINT M$(2):GOTO 1080
6002 IF OO=3 THEN PRINT M$(2):GOTO 1080
6003 IF OO=4 THEN PRINT M$(3):GOTO 1080
6004 IF OO=8 THEN PRINT M$(2):GOTO 1080
6005 IF OO=11 THEN PRINT M$(2):GOTO 1080
6006 IF OO=10 THEN PRINT M$(3):GOTO 1080
6007 IF OO=13 THEN PRINT M$(3):GOTO 1080
6008 IF OO=15 THEN PRINT M$(2):GOTO 1080
6010 IF OO=5 THEN OB(5)=-1:PRINT OK$:GOTO 1080
6011 IF OO=6 THEN OB(5)=-1:PRINT OK$:GOTO 1080
6012 IF OO=7 THEN OB(OO)=-1:PRINT OK$:GOTO 1080
6014 IF OO=12 THEN OB(OO)=-2:EVL=EVL+10:PRINT OK$:GOTO 1080
6015 IF OO=14 AND JOUEUR=5 THEN M$(0)="L'ours m'a tue. ":GOTO 4500
6016 IF OO=16 THEN OB(18)=-1:PRINT OK$:GOTO 1080
6017 IF OO=17 AND FL(3) THEN PRINT OK$:OB(OO)=-1:GOTO 1080
6018 IF OO=17 AND NOT FL(3) THEN M$(0)="Un ours se jette sur moi. Il m'a tue.":GOTO 4500
6019 IF OO=12 AND OB(OO)=-2 THEN PRINT"J'ai deja l'argent.":GOTO 1080
6020 IF OO=17 AND OB(OO)=-2 THEN PRINT"J'ai deja l'or.":GOTO 1080
6021 IF OO=45 THEN PRINT M$(2):GOTO 1080
6022 IF OO=21 AND FL(4)=-1 THEN PRINT OK$:OB(OO)=-1:GOTO 1080
6023 IF OO=22 THEN PRINT OK$:OB(OO)=-1:GOTO 1080
6024 IF OO=24 THEN PRINT OK$:OB(OO)=-1:GOTO 1080
6025 IF OO=25 THEN PRINT"Il est enfonce trop profondement dans le rocher.":GOTO 1080
6026 IF OO=27 THEN PRINT M$(3):GOTO 1080
6027 IF OO=28 THEN PRINT"Et que dois-je en faire ?":GOTO 1080
6030 IF OO=31 AND OB(5)<>-1 THEN PRINT"Avec quoi donc ?":GOTO 1080
6031 IF OO=31 AND OB(5)=-1 THEN PRINT OK$ ;" La bouteille est pleine.":FL(6)=-1:GOTO 1080
6032 IF OO=32 THEN PRINT OK$;" - oh qu'est-ce donc ?":FL(5)=-1:GOTO 1080
6033 IF OO=33 AND OB(OO)=JOUEUR THEN PRINT OK$:OB(OO)=-2:EVL=EVL+10:GOTO 1080
6034 IF OO=34 AND OB(OO)=JOUEUR THEN PRINT OK$:OB(OO)=-2:EVL=EVL+10:GOTO 1080
6035 IF OO=35 THEN PRINT"Il n'y a pas de toiles d'araignees,	c'etait une meche. ":GOTO 1080
6037 IF OO=37 THEN PRINT OK$:OB(OO)=-1:GOTO 1080
6038 IF OO=41 THEN PRINT OK$:OB(OO)=-1:GOTO 1080
6039 IF OO=42 THEN PRINT OK$:OB(OO)=-1:GOTO 1080
6040 IF OO=43 THEN PRINT OK$:OB(OO)=-1:GOTO 1080
6041 IF OO=21 AND NOT FL(4) THEN PRINT "Elle est attachee au wagonnet.":GOTO 1080
6042 IF OO=23 THEN PRINT OK$:OB(OO)=-1:GOTO 1080
6043 IF OO=29 AND OB(OO)=JOUEUR THEN PRINT OK$:OB(OO)=-2:EVL=EVL+10:GOTO 1080
6044 IF OO=38 AND OB(OO)=JOUEUR THEN PRINT OK$:OB(OO)=-2:EVL=EVL+10:GOTO 1080
6900 IF OO=9 AND (OB(7)=JOUEUR OR OB(7)=1) THEN M$(0)="Les explosifs ont explose lorsque je les ai touches! ":GOTO 4500
6901 IF OO=16 AND OB(18)=JOUEUR THEN PRINT OK$:OB(18)=-1:GOTO 1080
6910 IF OO=1 AND JOUEUR=2 THEN PRINT M$(2):GOTO 1080
6911 IF OO=20 AND JOUEUR=22 THEN PRINT"Lorsque l'avidite se reveille la mort fait alors souvent de bonnes affaires. ":GOTO 1080
6999 PRINT"Je ne vois rien de tel ici!":GOTO 1080
7000 IF OO=16 AND OB(18)=-1 THEN PRINT OK$:OB(18)=JOUEUR:GOTO 1080
7001 IF OB(OO)<>-1 THEN PRINT"Mais je ne possede pas encore une telle chose! ":GOTO 1080
7010 IF OO=6 AND JOUEUR=5 THEN OB(6)=0:FL(3)=-1:PRINT M$(4):PRINT M$(5):OB(14)=0:GOTO 1080
7020 IF OO=5 AND JOUEUR=5 THEN OB(5)=0:FL(3)=-1:PRINT M$(4):PRINT M$(5):OB(14)=0:GOTO 1080
7900 OB(OO)=JOUEUR:PRINT OK$:GOTO 1080
8000 IF OB(OO)<>JOUEUR AND OB(OO)<>-1 THEN PRINT"Il n'y a rien de tel ici !":GOTO 1080
8005 IF OO=4 AND JOUEUR=3 THEN PRINT"La cabane etait deja ouverte. ":GOTO 1080
8010 IF OO=5 THEN PRINT OK$:GOTO 1080
8020 IF OO=11 AND NOT FL(1) THEN PRINT"La chaine ne le permet pas.":GOTO 1080
8025 IF OO=11 AND FL(1) THEN PRINT OK$;" le couvercle s'ouvre et retombe en arriere.":FL(2)=-1:GOTO 1080
8030 IF OO=23 THEN PRINT OK$:GOTO 1080
8035 IF OO=29 THEN PRINT OK$:GOTO 1080
8040 IF OO=32 THEN PRINT"Je regrette - Je ne suis pas Frankenstein !":GOTO 1080
8045 IF OO=36 THEN PRINT"Comment ?":GOTO 1080
8999 PRINT"Je ne comprends pas ce que tu veux dire.":GOTO 1080
9000 IF OO=16 AND OB(18)=-1 AND JOUEUR=4 THEN PRINT"La chaine se brise.":FL(1)=-1:GOTO 1080
9005 IF OB(OO)<>JOUEUR AND OB(OO)<>-1 THEN GOTO 9900
9010 IF OO=16 AND JOUEUR=4 THEN PRINT"La chaine se brise.":FL(1)=-1:GOTO 1080
9020 IF OO=45 THEN PRINT"Comment et dans quel but ?":GOTO 1080
9030 IF OO=21 THEN PRINT"Comment et dans quel but ?":GOTO 1080
9900 PRINT"Je ne comprends pas ce que tu veux dire.":GOTO 1080
10000 IF OO=16 AND JOUEUR=4 AND OB(18)=-1 THEN PRINT"La chaine se brise.":FL(1)=1:GOTO 1080
10010 IF OO=16 AND JOUEUR=4 AND OB(18)<>1 THEN PRINT"Avec quoi ?":GOTO 1080
10020 IF OO=36 AND OB(22)=-1 THEN PRINT OK$:PASSAGE(22,1)=23:GOTO 1080
10030 IF OO=21 AND (OB(OO)=JOUEUR OR OB(OO)=-1) THEN PRINT OK$:FL(4)=-1:GOTO 1080
10040 IF OO=27 AND OB(22)=-1 THEN PRINT OK$:PASSAGE(10,2)=12:GOTO 1080
10050 IF OO=27 AND OB(22)<>-1 THEN PRINT" Avec quoi ?":GOTO 1080
10999 PRINT"Je ne comprends pas ce que tu veux dire. ":GOTO 1080
11000 IF OB(43)<>-1 THEN PRINT"Je n'ai rien pour allumer.":GOTO 1080
11010 IF OO=8 AND LZ<=0 THEN PRINT"Il n'y a plus d'huile dans la lampe !":GOTO 1080
11020 IF OO=42 AND (OB(43)=-1 OR LUMIERE=-1) THEN PRINT"psssss ... !":FL(7)=-1:EX=COUP+3:OB(OO)=0:PASSAGE(30,2)=31:PASSAGE(31,1)=30:GOTO 1080
11030 IF OO=23 AND OB(23)=-1 THEN PRINT OK$;" - la lampe brule.":LM=L1:LW=1:GOTO 1080
11040 IF OO=43 THEN PRINT Ok$;" - la meche luit.":GOTO 1080
11098 PRINT"Je ne te comprends pas. ":GOTO 1080
12000 IF OO=23 AND (FL(6) AND OB(23)=-1) THEN LM=60:FL(6)=0:LW=0:PRINT OK$:GOTO 1080
12020 IF OO=5 AND JOUEUR=17 THEN FL(6)=-1:PRINT"La bouteille est pleine.":GOTO 1080
12030 IF OO=43 AND OB(OO)=-1 THEN PRINT"la meche luit.":GOTO 1080
12998 PRINT"Je ne comprends pas ce que tu veux dire.":GOTO 1080
13000 IF OO=13 AND JOUEUR=5 THEN JOUEUR=12:PRINT OK$:GOTO 1080
13998 PRINT"Je ne sais pas ce que tu veux. ":GOTO 1080
14000 IF OO=23 AND OB(OO)=-1 THEN L1=LM-LW:PRINT OK$:GOTO 1080
14998 PRINT"Je ne sais pas ce que tu veux. ":GOTO 1080
15000 IF OO=21 AND JOUEUR=9 THEN PRINT OK$:OB(OO)=9:PASSAGE(9,6)=18:PASSAGE(18,5)=9:GOTO 1080