10 REM Auteurs : DIEUDONNE P. NOEL H.
20 SUBINIT = 5000 : SUBINTRO = 6000 : SUBCLS = 2500
25 SUBENTER = 2000 : SUBKEYP = 2100 : SUBTEMPO = 2200
30 LERROR = 20000
110 GOSUB SUBINIT : GOSUB SUBINTRO
120 SETCOLOR 2,0,0:PRINT CS$
160 PRINT "Vous etes devant une vieille maison";EL$;"abandonnee.":PRINT:PRINT
165 PRINT B10$:PRINT B11$:PRINT B12$:PRINT
170 GOSUB SUBENTER
180 IF INT(I)<>I OR I<10 THEN GOTO 170
190 ON I-9 GOTO 191,191,200:GOTO 170
191 PRINT CS$;"Vous avez raison,la curiosite est un";EL$;"vilain defaut."
192 END
200 PRINT CS$;"La porte se referme derriere vous,";EL$;"impossible de l'ouvrir."
201 GOSUB SUBTEMPO
220 GOSUB SUBCLS:PRINT "Vous etes dans l'entree,il y a une porte";"a l'est et a l'ouest."
230 PRINT:PRINT B3$:PRINT B4$:PRINT
231 GOSUB SUBENTER
232 IF INT(I)<>I OR I<3 THEN GOTO 231
233 ON I-2 GOTO 250,650:GOTO 231
250 ET=0:GOSUB SUBCLS:PRINT "Vous etes dans un hall, il y a une porte au nord et a l'ouest et des escaliers";EL$;"qui montent a l'est."
260 PRINT:PRINT B1$:PRINT B4$:PRINT B5$:PRINT
261 GOSUB SUBENTER
262 IF INT(I)<>I OR I<1 THEN GOTO 261
263 ON I GOTO 300,261,261,220,350:GOTO 261
300 GOSUB SUBCLS:PRINT "Vous etes dans une penderie, il y a une";EL$;"porte a l'est,au nord et au sud."
310 PRINT:PRINT B1$:PRINT B2$:PRINT B3$:PRINT
311 GOSUB SUBENTER
312 IF INT(I)<>I OR I<1 THEN GOTO 311
313 ON I GOTO 1300,250,500:GOTO 311
350 ET=1:GOSUB SUBCLS:PRINT "Vous etes dans un long couloir,il y a 3";EL$;"portes a l'est:au nord,au centre et au";EL$;"sud."
351 PRINT "Il y a 3 portes a l'ouest:au nord, au";EL$;"centre et au sud."
352 PRINT "Il y a une porte au nord et au sud et";EL$;"des escaliers descendant a l'ouest."
354 PRINT "Et un monte-charges avec des boutons";EL$;"MONTEE et DESCENTE."
356 IF MCH=0 THEN GOTO 360
357 PRINT"Le plateau du monte-charges est la."
358 IF CO=0 THEN PRINT"Il y a une clef en OR." 
359 GOTO 361
360 PRINT"Le plateau du MC n'est pas la."
361 PRINT "...":GOSUB SUBKEYP:IF MCH=1 AND CO=0 THEN PRINT B21$
362 Z=Z+1
364 PRINT B1$:PRINT B2$:PRINT B6$:PRINT B13$:PRINT B14$:PRINT B15$
365 PRINT B16$:PRINT B17$:PRINT B18$:PRINT B19$:PRINT B20$:PRINT
366 GOSUB SUBENTER
367 IF INT(I)<>I OR I<1 THEN GOTO 366
368 ON I GOTO 600,370,366,366,366,250:IF I<13 THEN GOTO 366
369 ON I-12 GOTO 1200,1220,400,1240,1260,1280,379,377,373:GOTO 366
370 PRINT CS$;"Impossible,la porte ne s'ouvre pas."
371 IF CP=1 OR CO=1 THEN GOTO 380
372 GOSUB SUBTEMPO:GOTO 350
373 IF MCH=0 OR CO=1 THEN GOTO 366
374 PRINT:PRINT A$:CO=1
375 GOSUB SUBTEMPO:GOTO 350
377 PRINT:PRINT A$:MCH=0:MCB=1:GOTO 375
379 PRINT:PRINT"Impossible, le bouton ne s'enfonce pas.":GOTO 375
380 PRINT:IF CO=1 THEN PRINT"1.Vous ouvrez avec votre clef en OR"
381 IF CP=1 THEN PRINT"2.Vous ouvrez avec votre petite clef"
382 PRINT"3.Vous retournez dans le couloir"
383 PRINT:GOSUB SUBENTER
384 IF INT(I)<>I OR I<1 OR I>3 THEN GOTO 383
385 ON I GOTO 386,390,350
386 IF CO=0 THEN GOTO 383
387 PRINT:PRINT"Impossible,elle n'entre pas dans la";EL$;"serrure."
388 GOSUB SUBTEMPO:GOTO 383
390 IF CP=0 THEN GOTO 383
391 PRINT:PRINT"La clef ouvre la porte, mais vous";EL$;"decouvrez un mur derriere elle."
392 GOTO 388
400 ET=1:GOSUB SUBCLS:PRINT "Vous etes dans une petite piece, il y a";EL$;"des escaliers qui montent au nord, une";EL$;"porte a l'ouest et une a l'est."
410 PRINT:PRINT B3$:PRINT B4$:PRINT B5$:PRINT
411 GOSUB SUBENTER
412 IF INT(I)<>I OR I<3 THEN GOTO 411
413 ON I-2 GOTO 415,350,950:GOTO 411
415 PRINT CS$;"En appuyant sur la clanche, vous ouvrez";EL$;"une trappe sous vos pieds et vous";EL$;"tombez dans un trou profond."
417 PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT TAB$(1,10);"VOUS MOUREZ !"
418 END
450 GOSUB SUBCLS:PRINT "Vous etes dans un grand garage,il y a";EL$;"une porte a l'est et au nord."
452 PRINT"Il y a aussi un disjoncteur avec une";EL$;"inscription:ligne HT du toit"
453 PRINT"A cote,il y a un bouton vert et un";EL$;"bouton rouge."
460 PRINT:PRINT B1$:PRINT B3$:PRINT B8$:PRINT B9$:PRINT
461 GOSUB SUBENTER
462 IF INT(I)<>I OR I<1 THEN GOTO 461
463 ON I GOTO 1050,461,700,461,461,461,461,467,469:GOTO 461
467 PRINT:PRINT A$:HT=0:GOTO 461
469 PRINT:PRINT A$:HT=1:GOTO 461
500 ET=-1:GOSUB SUBCLS:PRINT "Vous etes dans un petit couloir,il y a";EL$;"une porte a l'est,une a l'ouest et une";EL$;"au nord."
510 PRINT:PRINT B1$:PRINT B3$:PRINT B4$:PRINT
511 GOSUB SUBENTER
512 IF INT(I)<>I OR I<1 THEN GOTO 511
513 ON I GOTO 1100,511,550,300:GOTO 511
550 GOSUB SUBCLS:PRINT "Vous etes dans une cuisine, il y a une";EL$;"porte a l'est, une a l'ouest et une au";EL$;"nord."
552 PRINT"Il y a aussi un monte-charges, un bouton";"Montee et un bouton Descente."
553 IF MCB=0 THEN GOTO 557
554 PRINT"Le plateau du monte-charges est la."
555 IF CO=0 THEN PRINT"Il y a une clef en OR."
556 GOTO 558
557 PRINT"Le plateau du monte-charges n'est pas";EL$;"la."
558 PRINT:IF MCB=1 AND CO=0 THEN PRINT B21$
560 PRINT B1$:PRINT B3$:PRINT B4$:PRINT B19$:PRINT B20$:PRINT
561 GOSUB SUBENTER
562 IF INT(I)<>I OR I<1 THEN GOTO 561
563 ON I GOTO 1300,561,1000,500:IF I<19 THEN GOTO 561
564 ON I-18 GOTO 570,573,565:GOTO 561
565 IF MCB=0 OR CO=1 THEN GOTO 561
566 PRINT:PRINT A$:CO=1
567 GOSUB SUBTEMPO:GOTO 550
570 PRINT:PRINT A$:MCB=0:MCH=1:GOTO 567
573 PRINT:PRINT"Impossible,le bouton ne s'enfonce pas.":GOTO 567
600 ET=1:GOSUB SUBCLS:PRINT "Vous etes dans une chambre,il y a une";EL$;"porte a l'ouest et au sud et des";EL$;"escaliers qui descendent a l'est."
610 PRINT:PRINT B2$:PRINT B4$:PRINT B6$:PRINT
611 GOSUB SUBENTER
612 IF INT(I)<>I OR I<2 THEN GOTO 611
613 ON I-1 GOTO 350,611,850,611,800:GOTO 611
650 ET=0:GOSUB SUBCLS:PRINT "Vous etes dans une petite piece,il y a";EL$;"une porte a l'est et une au nord et des";EL$;"escaliers qui descendent a l'ouest."
660 PRINT:PRINT B1$:PRINT B3$:PRINT B6$:PRINT
661 GOSUB SUBENTER
662 IF INT(I)<>I OR I<1 THEN GOTO 661
663 ON I GOTO 750,661,220,661,661,700:GOTO 661
700 ET=-1:GOSUB SUBCLS:PRINT "Vous etes dans un couloir,il y a des";EL$;"escaliers qui montent a l'est, une porte";"a l'est, une a l'ouest et une au nord."
705 Z=Z+2
710 PRINT:PRINT B1$:PRINT B3$:PRINT B4$:PRINT B5$:PRINT
711 GOSUB SUBENTER
712 IF INT(I)<>I OR I<1 THEN GOTO 711
713 ON I GOTO 1000,711,900,450,650:GOTO 711
750 GOSUB SUBCLS:PRINT "Vous etes dans un grand salon, il y a";EL$;"une porte au sud et une a l'est. Il y a";EL$;"aussi un bar dans le coin nord-ouest."
759 PRINT:PRINT"1.Vous allez au bar vous desalterer"
760 PRINT B2$:PRINT B3$:PRINT
761 GOSUB SUBENTER
762 IF INT(I)<>I OR I<1 THEN GOTO 761
763 ON I GOTO 764,650,1100:GOTO 761
764 IF CP=1 THEN GOTO 773
765 PRINT "Au milieu des bouteilles,vous voyez une";EL$;"petite clef."
766 PRINT:PRINT"Vous la prenez(1) ou pas(0) ";
767 INPUT I
768 IF I=1 THEN GOTO 771
769 IF I<>0 THEN GOTO 767
770 PRINT:PRINT A$:GOTO 772
771 PRINT:PRINT A$:CP=1
772 GOSUB SUBTEMPO:GOTO 750
773 PRINT:PRINT"Vous choisissez une des nombreuses";EL$;"bouteilles pour vous desalterer."
775 GOSUB SUBTEMPO:GOTO 750
800 ET=0:GOSUB SUBCLS:PRINT "Vous etes dans un couloir,il y a des";EL$;"escaliers qui montent a l'ouest, une";EL$;"porte au sud et une a l'est." 
810 PRINT:PRINT B2$:PRINT B3$:PRINT B5$:PRINT
811 GOSUB SUBENTER 
812 IF INT(I)<>I OR I<2 THEN GOTO 811 
813 ON I-1 GOTO 900,1300,811,600:GOTO 811
850 ET=1:GOSUB SUBCLS:PRINT "Vous etes dans une salle de bains, il y";EL$;"a une porte a l'ouest, une a l'est et";EL$;"une au sud." 
860 PRINT:PRINT B2$:PRINT B3$:PRINT B4$:PRINT 
861 GOSUB SUBENTER 
862 IF INT(I)<>I OR I<2 THEN GOTO 861 
863 ON I-1 GOTO 1100,600,1150:GOTO 861
900 GOSUB SUBCLS:PRINT "Vous etes dans une salle de projection,";EL$;"il y a une porte au nord, une au sud et";EL$;"une a l'ouest." 
910 PRINT:PRINT B1$:PRINT B2$:PRINT B4$:PRINT 
911 GOSUB SUBENTER
912 IF INT(I)<>I OR I<1 THEN GOTO 911
913 ON I GOTO 800,1000,911,700:GOTO 911 
950 ET=2:GOSUB SUBCLS:PRINT "Vous etes sur un toit plat,une barriere";EL$;"electrique H.T. en fait le tour et des";EL$;"escaliers en descendent au sud." 
960 PRINT:PRINT B1$:PRINT B2$:PRINT B3$:PRINT B4$:PRINT B6$:PRINT 
961 GOSUB SUBENTER
962 IF INT(I)<>I OR I<1 THEN GOTO 961
963 ON I GOTO 964,964,964,964,961,400:GOTO 961
964 IF HT=1 THEN GOTO 966
965 PRINT CS$;"Vous vous electrocutez.":GOTO 417 
966 PRINT:PRINT"Il y a des pointes sur le mur qui";EL$;"entoure la maison." 
967 PRINT:PRINT"1.Vous sautez du toit en prenant de nombreux risques."
968 PRINT B6$:PRINT 
969 GOSUB SUBENTER
970 IF I=6 THEN GOTO 400 
971 IF I<>1 THEN GOTO 969 
972 IF Z=10 THEN GOTO 975 
973 PRINT CS$;"Vous tombez sur les pointes qui";EL$;"entourent la maison."
974 GOTO 417
975 PRINT CS$;"Vous avez eu de la chance, votre saut a";EL$;"ete assez important pour franchir les";EL$;"pointes. Malheureusement,vous vous etes";EL$;"casse la jambe en tombant mal." 
978 PRINT"Enfin,vous vous en etes sorti et c'est";EL$;"le principal."
979 PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT TAB$(1,10);"BRAVO !"
980 END 
1000 GOSUB SUBCLS:PRINT "Vous etes dans un auditorium,il y a une";EL$;"porte au nord, une au sud et une a";EL$;"l'ouest." 
1010 PRINT:PRINT B1$:PRINT B2$:PRINT B4$:PRINT 
1011 GOSUB SUBENTER 
1012 IF INT(I)<>I OR I<1 THEN GOTO 1011
1013 ON I GOTO 900,700,1011,550:GOTO 1011
1050 GOSUB SUBCLS:PRINT "Vous etes dans un atelier. Il y a une";EL$;"porte au sud."
1060 PRINT:PRINT B2$:PRINT 
1061 GOSUB SUBENTER 
1062 IF I=2 THEN GOTO 450
1063 GOTO 1061 
1100 ET=0:GOSUB SUBCLS:PRINT "Vous etes sur un escalier, il y a une";EL$;"porte en haut au nord et 2 portes en";EL$;"bas : au sud et a l'ouest."
1110 PRINT:PRINT B1$:PRINT B2$:PRINT B4$:PRINT
1111 GOSUB SUBENTER
1112 IF INT(I)<>I OR I<1 THEN GOTO 1111
1113 ON I GOTO 850,500,1111,750:GOTO 1111
1150 GOSUB SUBCLS:PRINT "Vous etes dans une chambre ou il y a";EL$;"une porte a l'est." 
1152 PRINT"Il y a aussi une armoire a l'ouest." 
1153 IF A0=0 THEN GOTO 1159
1154 PRINT"L'armoire est ouverte."
1155 PRINT:PRINT"1.Vous regardez dans l'armoire"
1156 GOTO 1160
1159 PRINT:PRINT"1.Vous essayez d'ouvrir l'armoire"
1160 PRINT B3$:PRINT
1161 GOSUB SUBENTER
1162 IF I=3 THEN GOTO 850
1163 IF I<>1 THEN GOTO 1161
1165 IF A0=1 THEN GOTO 1320
1166 PRINT:PRINT"Impossible de l'ouvrir."
1167 IF CO=0 AND CP=0 THEN GOTO 1161
1168 PRINT:IF CO=1 THEN PRINT"1.Vous essayez d'ouvrir la porte avec";EL$;"votre clef en OR"
1169 IF CP=1 THEN PRINT"2.Vous essayez d'ouvrir la porte avec";EL$;"votre petite clef"
1170 PRINT B3$:PRINT
1171 GOSUB SUBENTER
1172 IF INT(I)<>I OR I<1 THEN GOTO 1171
1173 ON I GOTO 1319,1174,850:GOTO 1171
1174 IF CP=0 THEN GOTO 1171
1175 PRINT CS$;"Impossible de l'ouvrir, la clef ne";EL$;"convient pas."
1176 GOSUB SUBTEMPO:GOTO 1150
1200 GOSUB SUBCLS:PRINT "Vous etes dans une chambre. Il y a une";EL$;"porte a l'ouest."
1201 PRINT"Il y a aussi un telephone sur une table."
1210 PRINT:PRINT B4$:PRINT"5.Vous essayez d'appeler police-secours.":PRINT
1211 GOSUB SUBENTER
1212 IF I=4 THEN GOTO 350
1213 IF I<>5 THEN GOTO 1211
1214 PRINT:PRINT"En decrochant le telephone, vous n'en-";EL$;"tendez aucune tonalite.":PRINT"En regardant sous la table, vous voyez";EL$;"que les fils sont arraches."
1216 GOSUB SUBTEMPO:GOTO 1200
1220 GOSUB SUBCLS:PRINT "Vous etes dans une chambre,il y a une";EL$;"porte a l'ouest. Il y a aussi une";EL$;"commode avec 6 tiroirs."
1225 PRINT:PRINT B4$:PRINT"5.Vous cherchez dans les tiroirs":PRINT
1226 GOSUB SUBENTER
1227 IF I=4 THEN GOTO 350
1228 IF I<>5 THEN GOTO 1226
1229 IF LA=0 THEN GOTO 1231
1230 PRINT:PRINT A$:GOTO 1226
1231 PRINT:PRINT"En ouvrant le tiroir en bas a droite,";EL$;"vous trouvez une lampe de poche.":PRINT:PRINT"Vous la prenez(1) ou pas(2)."
1233 PRINT:GOSUB SUBENTER
1234 IF I=1 THEN GOTO 1238
1235 IF I<>2 THEN GOTO 1233
1236 PRINT:PRINT A$
1237 GOSUB SUBTEMPO:GOTO 1220
1238 PRINT:PRINT A$:LA=1:GOTO 1237
1240 GOSUB SUBCLS:PRINT "Vous etes dans une chambre, il y a une";EL$;"porte a l'est."
1250 PRINT:PRINT B3$:PRINT B7$:PRINT
1251 GOSUB SUBENTER
1252 IF I=3 THEN GOTO 350
1253 IF I<>7 THEN GOTO 1251
1254 GOSUB SUBTEMPO:GOTO 1251
1260 GOSUB SUBCLS:PRINT "Vous etes dans une salle de bains, il y";EL$;"a une porte a l'est."
1270 PRINT:PRINT B3$:PRINT B7$:PRINT
1271 GOSUB SUBENTER
1272 IF I=3 THEN GOTO 350
1273 IF I<>7 THEN GOTO 1271
1274 GOSUB SUBTEMPO:GOTO 1271
1280 GOSUB SUBCLS:PRINT "Vous etes devant les WC, vous pouvez";EL$;"soit entrer vous soulager(1) ou rester";EL$;"dans le couloir(0)."
1285 PRINT:GOSUB SUBENTER
1286 IF I=0 THEN GOTO 350
1287 IF I<>1 THEN GOTO 1285
1288 PRINT CS$;"En entrant dans les WC, vous pouvez lire ce message sur la porte:"
1289 PRINT"IL FAUT BEAUCOUP D'AMPOULES POUR";EL$;"ECLAIRER NEW-YORK, MAIS UNE LAMPE DE";EL$;"POCHE PERMET DE SORTIR DE CETTE MAISON."
1291 GOSUB SUBTEMPO
1292 PRINT CS$;"Vous retournez dans le couloir apres";EL$;"vous etre soulage."
1293 GOSUB SUBTEMPO:GOTO 350
1300 GOSUB SUBCLS:PRINT "Vous etes dans une salle-a-manger, il y a";"une porte a l'ouest et 2 au sud: une a";EL$;"l'est et une a l'ouest."
1310 PRINT:PRINT B4$:PRINT B15$:PRINT B18$:PRINT
1311 GOSUB SUBENTER
1312 IF INT(I)<>I OR I<4 THEN GOTO 1311
1313 ON I-3 GOTO 800:IF I<15 THEN GOTO 1311
1314 ON I-14 GOTO 550,1311,1311,300:GOTO 1311
1319 IF CO=0 THEN GOTO 1171:A0=1
1320 SETCOLOR 2,0,0:PRINT CS$;"Derriere le faux fond de l'armoire se";EL$;"trouve une grotte sombre. Des bruits";EL$;"etranges d'animaux sauvages vous font";EL$;"tressaillir."
1322 PRINT"Mais le jour vous apparait deja la-bas, tout";EL$;"au fond de la grotte."
1328 PRINT:PRINT"1.Vous avancez":PRINT"2.Vous retournez dans la chambre."
1329 IF LA=1 AND LAA=0 THEN PRINT"3.Vous allumez la lampe de poche"
1330 PRINT:GOSUB SUBENTER
1331 IF INT(I)<>I OR I<1 THEN GOTO 1330
1332 ON I GOTO 1333,1150,1350:GOTO 1330
1333 IF LAA=1 THEN GOTO 1335
1334 PRINT CS$;"Vous tombez dans un trou.":GOTO 417
1335 PRINT CS$;"Vous voyez apparaitre un trou devant";EL$;"vous que vous contournez."
1336 GOSUB SUBTEMPO
1337 PRINT:PRINT"Vous continuez ensuite d'avancer. Les";EL$;"rats vous font encore quelques frayeurs."
1339 GOSUB SUBTEMPO
1340 PRINT:PRINT"Mais finalement le jour se rapproche";EL$;"et vous etes bientot libre."
1341 GOSUB SUBTEMPO
1342 PRINT:PRINT"Ca y est, vous vous en etes tout de meme sorti."
1343 PRINT:PRINT:PRINT:PRINT:PRINT TAB$(1,20);"TRIPLES BRAVOS !!!!!!!!!!!!!"
1344 END
1350 IF LA=0 THEN GOTO 1330
1351 PRINT:PRINT A$
1352 GOSUB SUBTEMPO:LAA=1:GOTO 1320
1995 REM **********************************************************************
1996 REM ** SUB-ROUTINES
1997 REM **********************************************************************
1998 REM
1999 REM ***** SAISIE D UN NOMBRE
2000 PRINT "--> QUE FAITES VOUS ";:INPUT I$
2005 IF I$="Q" THEN END
2010 I = VAL(I$)
2020 RETURN
2098 REM
2099 REM ***** WAIT FOR KEY PRESSED
2100 IF PEEK(764)= 255 THEN 2100
2110 POKE 764,255 : REM CLEAR LAST KEY PRESSED
2120 RETURN
2198 REM
2199 REM ***** TEMPORISATION
2200 POKE 20,0
2210 IF PEEK(20) < TMAX THEN 2210
2230 RETURN
2498 REM ***** CLEAR SCREEN AND SET COLOR DEPENDING ON FLOOR
2499 REM
2500 PRINT CS$
2510 IF ET = 0 THEN SETCOLOR 2,3,0
2520 IF ET = 1 THEN SETCOLOR 2,5,0
2530 IF ET = 2 THEN SETCOLOR 2,14,0
2540 IF ET = -1 THEN SETCOLOR 2,12,0
2550 RETURN
4997 REM **********************************************************************
4998 REM ** INIT
4999 REM **********************************************************************
5000 DIM TAB$(30),A$(12),I$(10)
5010 TAB$="                              "
5020 A$="D'accord"
5030 DIM B1$(60),B2$(60),B3$(60),B4$(60),B5$(60),B6$(60),B7$(60),B8$(60),B9$(60),B10$(60),B11$(60)
5040 DIM B12$(60),B13$(60),B14$(60),B15$(60),B16$(60),B17$(60),B18$(60),B19$(60),B20$(60),B21$(60)
5050 B1$="1.Vous allez au nord":B2$="2.Vous allez au sud":B3$ ="3.Vous allez a l'est"
5060 B4$="4.Vous allez a l'ouest":B5$="5.Vous montez les escaliers"
5070 B6$="6.Vous descendez les escaliers"
5080 B7$="7.Vous attendez":B8$="8.Vous appuyez sur le bouton vert"
5090 B9$="9.Vous appuyez sur le bouton rouge":B10$="10.Vous ne faites rien"
5110 B11$="11.Vous partez":B12$="12.Vous entrez dans la maison"
5120 B13$="13.Vous allez au nord-est":B14$="14.Vous allez au centre-est"
5130 B15$="15.Vous allez au sud-est":B16$="16.Vous allez au nord-ouest"
5140 B17$="17.Vous allez au centre-ouest":B18$="18.Vous allez au sud-ouest"
5150 B19$="19.Vous pressez le bouton Montee du MC"
5160 B20$="20.Vous pressez le bouton Descente du MC"
5170 B21$="21.Vous prenez la clef"
5200 DIM CS$(1),EL$(1)
5210 CS$ = CHR$(125) : REM Clear Screen
5215 EL$ = CHR$(155) : REM End of Line
5250 TMAX = 150
5260 ET = 0
5290 TRAP LERROR
5400 RETURN
5997 REM **********************************************************************
5998 REM ** INTRO
5999 REM **********************************************************************
6000 GRAPHICS 1 : SETCOLOR 2,0,0
6010 POSITION 1,4 : PRINT #6;"LA MAISON DU FOU"
6011 POSITION 1,5 : PRINT #6;"________________"
6020 POSITION 0,16 : PRINT #6;"instructions"
6025 POKE 82,0
6030 PRINT "Pour executer une action, entrez le";EL$;"nombre devant l'action."
6040 PRINT:PRINT "Appuyez sur CR pour continuer...";
6050 GOSUB SUBKEYP
6100 GRAPHICS 0
6120 RETURN
19997 REM **********************************************************************
19998 REM ** TRAITEMENT DES ERREURS
19999 REM **********************************************************************
20000 ERR = PEEK(195) : ERL = PEEK(187)*256+ PEEK(186)
20020 IF ERR = 18 AND ERL = 2010 THEN TRAP LERROR : GOTO 2000