100 REM Auteurs : DIEUDONNE P. NOEL H.
105 REM Adaptation ZBasic : D. RIOUAL (09/11/2020)
110 CLS : PRINT TAB(30);CHR$(14);" LA MAISON DU FOU ";CHR$(15)
115 DIM B$(21):A$="    D'accord"
116 IQ$ = "Que faites-vous "
117 TEMPO = 1300
120 FOR I=1 TO 21:READ B$(I):NEXT I
121 DATA " 1 Vous allez au nord"," 2 Vous allez au sud"," 3 Vous allez a l'est"
122 DATA " 4 Vous allez a l'ouest"," 5 Vous montez les escaliers"
123 DATA " 6 Vous descendez les escaliers"
124 DATA " 7 Vous attendez"," 8 Vous appuyez sur le bouton vert"
125 DATA " 9 Vous appuyez sur le bouton rouge","10 Vous ne faites rien"
126 DATA "11 Vous partez","12 Vous entrez dans la maison"
127 DATA "13 Vous allez au nord-est","14 Vous allez au centre-est"
128 DATA "15 Vous allez au sud-est","16 Vous allez au nord-ouest"
129 DATA "17 Vous allez au centre-ouest","18 Vous allez au sud-ouest"
130 DATA "19 Vous appuyez sur le bouton Montee du monte-charges"
131 DATA "20 Vous appuyez sur le bouton Descente du monte-charges"
132 DATA "21 Vous prenez la clef"
135 PRINT:PRINT:PRINT:PRINT:PRINT TAB(10);"INSTRUCTIONS POUR EXECUTER UNE ACTION"
136 PRINT:PRINT TAB(14);"Entrez le nombre qui se trouve devant l'action"
140 PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT "Appuyez sur CR pour continuer..."
150 PRINT:PRINT:PRINT:INPUT I$
160 CLS:PRINT "Vous etes devant une vieille maison abandonnee.":PRINT:PRINT
165 PRINT B$(10):PRINT B$(11):PRINT B$(12):PRINT
170 PRINT IQ$;:INPUT I
180 IF INT(I)<>I OR I<10 THEN GOTO 170
190 ON I-9 GOTO 191,191,200:GOTO 170
191 CLS:PRINT "     Vous avez raison, la curiosite est un vilain defaut..."
192 END
200 CLS:PRINT "La porte se referme derriere vous, impossible de l'ouvrir."
201 FOR I=1 TO TEMPO*3:NEXT I
220 CLS:PRINT "Vous etes dans l'entree, il y a une porte a l'est et a l'ouest."
230 PRINT:PRINT B$(3):PRINT B$(4):PRINT
231 PRINT IQ$;:INPUT I
232 IF INT(I)<>I OR I<3 THEN GOTO 231
233 ON I-2 GOTO 250,650:GOTO 231
250 CLS:PRINT "Vous etes dans un hall, il y a une porte au nord et a l'ouest"
251 PRINT"et des escaliers qui montent a l'est."
260 PRINT:PRINT B$(1):PRINT B$(4):PRINT B$(5):PRINT
261 PRINT IQ$;:INPUT I
262 IF INT(I)<>I OR I<1 THEN GOTO 261
263 ON I GOTO 300,261,261,220,350:GOTO 261
300 CLS:PRINT "Vous etes dans une penderie, il y a une porte a l'est, au nord"
301 PRINT"et au sud"
310 PRINT:PRINT B$(1):PRINT B$(2):PRINT B$(3):PRINT
311 PRINT IQ$;:INPUT I
312 IF INT(I)<>I OR I<1 THEN GOTO 311
313 ON I GOTO 1300,250,500:GOTO 311
350 CLS:PRINT "Vous etes dans un long couloir, il y a 3 portes a l'est : une au"
351 PRINT"nord, une au centre et une au sud. Il y a 3 portes a l'ouest : une au"
352 PRINT"nord, une au cntre et une au sud. Il y a aussi une porte au nord et au"
353 PRINT"sud et des escaliers qui descendent a l'ouest."
354 PRINT"Il y a aussi un monte-charges avec un bouton Montee et un bouton"
355 PRINT"Descente."
356 IF MCH=0 THEN GOTO 360
357 PRINT"Le plateau du monte-charges est la."
358 IF CO=0 THEN PRINT"Il y a une clef en OR" 
359 GOTO 361
360 PRINT"Le plateau du monte-charges n'est pas la."
361 PRINT:IF MCH=1 AND CO=0 THEN PRINT B$(21)
362 Z=Z+1
364 PRINT B$(1):PRINT B$(2):PRINT B$(6):PRINT B$(13):PRINT B$(14):PRINT B$(15)
365 PRINT B$(16):PRINT B$(17):PRINT B$(18):PRINT B$(19):PRINT B$(20):PRINT
366 PRINT IQ$;:INPUT I
367 IF INT(I)<>I OR I<1 THEN GOTO 366
368 ON I GOTO 600,370,366,366,366,250:IF I<13 THEN GOTO 366
369 ON I-12 GOTO 1200,1220,400,1240,1260,1280,379,377,373:GOTO 366
370 CLS:PRINT "Impossible,la porte ne s'ouvre pas."
371 IF CP=1 OR CO=1 THEN GOTO 380
372 FOR I=1 TO TEMPO*2:NEXT I:GOTO 350
373 IF MCH=0 OR CO=1 THEN GOTO 366
374 PRINT:PRINT A$:CO=1
375 FOR I=1 TO TEMPO*2:NEXT I:GOTO 350
377 PRINT:PRINT A$:MCH=0:MCB=1:GOTO 375
379 PRINT:PRINT"       Impossible,le bouton ne s'enfonce pas.":GOTO 375
380 PRINT:IF CO=1 THEN PRINT" 1 Vous ouvrez avec votre clef en OR"
381 IF CP=1 THEN PRINT" 2 Vous ouvrez avec votre petite clef"
382 PRINT" 3 Vous retournez dans le couloir"
383 PRINT:PRINT IQ$;:INPUT I
384 IF INT(I)<>I OR I<1 OR I>3 THEN GOTO 383
385 ON I GOTO 386,390,350
386 IF CO=0 THEN GOTO 383
387 PRINT:PRINT"Impossible, elle n'entre pas dans la serrure."
388 FOR I=1 TO TEMPO*2:NEXT I:GOTO 383
390 IF CP=0 THEN GOTO 383
391 PRINT:PRINT"La clef ouvre la porte, mais vous decouvrez un mur derriere elle."
392 GOTO 388
400 CLS:PRINT "Vous etes dans une petite piece, il y a des escaliers qui"
401 PRINT"montent au nord, une porte a l'ouest et une a l'est."
410 PRINT:PRINT B$(3):PRINT B$(4):PRINT B$(5):PRINT
411 PRINT IQ$;:INPUT I
412 IF INT(I)<>I OR I<3 THEN GOTO 411
413 ON I-2 GOTO 415,350,950:GOTO 411
415 CLS:PRINT "En appuyant sur la clanche, vous ouvrez une trappe sous vos"
416 PRINT"pieds et vous tombez dans un trou profond."
417 PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT TAB(30)"VOUS MOUREZ !"
418 END
450 CLS:PRINT "Vous etes dans un grand garage, il y a une porte a l'est et"
451 PRINT"au nord."
452 PRINT"Il y a aussi un disjoncteur avec une inscription : ligne HT du toit."
453 PRINT"A cote, il y a un bouton vert et un bouton rouge."
460 PRINT:PRINT B$(1):PRINT B$(3):PRINT B$(8):PRINT B$(9):PRINT
461 PRINT IQ$;:INPUT I
462 IF INT(I)<>I OR I<1 THEN GOTO 461
463 ON I GOTO 1050,461,700,461,461,461,461,467,469:GOTO 461
467 PRINT:PRINT A$:HT=0:GOTO 461
469 PRINT:PRINT A$:HT=1:GOTO 461
500 CLS:PRINT "Vous etes dans un petit couloir, il y a une porte a l'est,"
501 PRINT"une a l'ouest et une au nord."
510 PRINT:PRINT B$(1):PRINT B$(3):PRINT B$(4):PRINT
511 PRINT IQ$;:INPUT I
512 IF INT(I)<>I OR I<1 THEN GOTO 511
513 ON I GOTO 1100,511,550,300:GOTO 511
550 CLS:PRINT "Vous etes dans une cuisine, il y a une porte a l'est, une a" 
551 PRINT"l'ouest et une au nord."
552 PRINT"Il y a aussi un monte-charges, un bouton Montee et un bouton Descente."
553 IF MCB=0 THEN GOTO 557
554 PRINT"Le plateau du monte-charges est la."
555 IF CO=0 THEN PRINT"Il y a une clef en OR."
556 GOTO 558
557 PRINT"Le plateau du monte-charges n'est pas la."
558 PRINT:IF MCB=1 AND CO=0 THEN PRINT B$(21)
560 PRINT B$(1):PRINT B$(3):PRINT B$(4):PRINT B$(19):PRINT B$(20):PRINT
561 PRINT IQ$;:INPUT I
562 IF INT(I)<>I OR I<1 THEN GOTO 561
563 ON I GOTO 1300,561,1000,500:IF I<19 THEN GOTO 561
564 ON I-18 GOTO 570,573,565:GOTO 561
565 IF MCB=0 OR CO=1 THEN GOTO 561
566 PRINT:PRINT A$:CO=1
567 FOR I=1 TO TEMPO*2:NEXT I:GOTO 550
570 PRINT:PRINT A$:MCB=0:MCH=1:GOTO 567
573 PRINT:PRINT"       Impossible, le bouton ne s'enfonce pas.":GOTO 567
600 CLS:PRINT "Vous etes dans une chambre, il y a une porte a l'ouest et"
601 PRINT"au sud et des escaliers qui descendent a l'est."
610 PRINT:PRINT B$(2):PRINT B$(4):PRINT B$(6):PRINT
611 PRINT IQ$;:INPUT I
612 IF INT(I)<>I OR I<2 THEN GOTO 611
613 ON I-1 GOTO 350,611,850,611,800:GOTO 611
650 CLS:PRINT "Vous etes dans une petite piece, i1 y a une porte a l'est et"
651 PRINT"une au nord et des escaliers qui descendent a l'ouest."
660 PRINT:PRINT B$(1):PRINT B$(3):PRINT B$(6):PRINT
661 PRINT IQ$;:INPUT I
662 IF INT(I)<>I OR I<1 THEN GOTO 661
663 ON I GOTO 750,661,220,661,661,700:GOTO 661
700 CLS:PRINT "Vous etes dans un couloir, il y a des escaliers qui montent"
701 PRINT"a l'est, une porte a l'est, une a l'ouest et une au nord."
705 Z=Z+2
710 PRINT:PRINT B$(1):PRINT B$(3):PRINT B$(4):PRINT B$(5):PRINT
711 PRINT IQ$;:INPUT I
712 IF INT(I)<>I OR I<1 THEN GOTO 711
713 ON I GOTO 1000,711,900,450,650:GOTO 711
750 CLS:PRINT "Vous etes dans un grand salon, il y a une porte au sud et"
751 PRINT"une a l'est. Il y a aussi un bar dans le coin nord-ouest."
759 PRINT:PRINT" 1 Vous allez au bar pour vous desalterer"
760 PRINT B$(2):PRINT B$(3):PRINT
761 PRINT IQ$;:INPUT I
762 IF INT(I)<>I OR I<1 THEN GOTO 761
763 ON I GOTO 764,650,1100:GOTO 761
764 IF CP=1 THEN GOTO 773
765 PRINT"Au milieu des bouteilles, vous voyez une petite clef."
766 PRINT:PRINT"Vous la prenez(1) ou pas(0) ";
767 INPUT I
768 IF I=1 THEN GOTO 771
769 IF I<>0 THEN GOTO 767
770 PRINT:PRINT A$:GOTO 772
771 PRINT:PRINT A$:CP=1
772 FOR I=1 TO TEMPO:NEXT I:GOTO 750
773 PRINT:PRINT"Vous choisissez une des nombreuses bouteilles pour vous"
774 PRINT"desalterer."
775 FOR I=1 TO TEMPO*2:NEXT I:GOTO 750
800 CLS:PRINT "Vous etes dans un couloir, il y a des escaliers qui montent" 
801 PRINT"a l'ouest, une porte au sud et une a l'est." 
810 PRINT:PRINT B$(2):PRINT B$(3):PRINT B$(5):PRINT
811 PRINT IQ$;:INPUT I 
812 IF INT(I)<>I OR I<2 THEN GOTO 811 
813 ON I-1 GOTO 900,1300,811,600:GOTO 811
850 CLS:PRINT "Vous etes dans une salle de bains, il y a une porte a" 
851 PRINT"l'ouest, une a l'est et une au sud." 
860 PRINT:PRINT B$(2):PRINT B$(3):PRINT B$(4):PRINT 
861 PRINT IQ$;:INPUT I 
862 IF INT(I)<>I OR I<2 THEN GOTO 861 
863 ON I-1 GOTO 1100,600,1150:GOTO 861
900 CLS:PRINT "Vous etes dans une salle de projection, il y a une porte" 
901 PRINT"au nord, une au sud et une a l'ouest." 
910 PRINT:PRINT B$(1):PRINT B$(2):PRINT B$(4):PRINT 
911 PRINT IQ$;:INPUT I
912 IF INT(I)<>I OR I<1 THEN GOTO 911
913 ON I GOTO 800,1000,911,700:GOTO 911 
950 CLS:PRINT "Vous etes sur un toit plat, une barriere electrique H.T."
951 PRINT"en fait le tour et des escaliers en descendent au sud." 
960 PRINT:PRINT B$(1):PRINT B$(2):PRINT B$(3):PRINT B$(4):PRINT B$(6):PRINT 
961 PRINT IQ$;:INPUT I
962 IF INT(I)<>I OR I<1 THEN GOTO 961
963 ON I GOTO 964,964,964,964,961,400:GOTO 961
964 IF HT=1 THEN GOTO 966
965 CLS:PRINT "Vous vous electrocutez.":GOTO 417 
966 PRINT:PRINT"Il y a des pointes sur le mur qui entoure la maison." 
967 PRINT:PRINT" 1 Vous sautez du toit en prenant de nombreux risques."
968 PRINT B$(6):PRINT 
969 PRINT IQ$;:INPUT I
970 IF I=6 THEN GOTO 400 
971 IF I<>1 THEN GOTO 969 
972 IF Z=10 THEN GOTO 975 
973 CLS:PRINT "Vous tombez sur les pointes qui entourent la maison."
974 GOTO 417
975 CLS:PRINT "Vous avez eu de la chance, votre saut a ete assez important" 
976 PRINT"pour franchir les pointes. Malheureusement, vous vous etes casse la" 
977 PRINT"jambe en tombant mal." 
978 PRINT"Enfin, vous vous en etes sorti et c'est le principal."
979 PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT TAB(30)"BRAVO !"
980 END 
1000 CLS:PRINT "Vous etes dans un auditorium, il y a une porte au nord,"
1001 PRINT"une au sud et une a l'ouest." 
1010 PRINT:PRINT B$(1):PRINT B$(2):PRINT B$(4):PRINT 
1011 PRINT IQ$;:INPUT I 
1012 IF INT(I)<>I OR I<1 THEN GOTO 1011
1013 ON I GOTO 900,700,1011,550:GOTO 1011
1050 CLS:PRINT "Vous etes dans un atelier. Il y a une porte au sud."
1060 PRINT:PRINT B$(2):PRINT 
1061 PRINT IQ$;:INPUT I 
1062 IF I=2 THEN GOTO 450 ELSE GOTO 1061 
1100 CLS:PRINT "Vous etes sur un escalier, il y a une porte en haut au nord"
1101 PRINT"et 2 portes en bas : au sud et a l'ouest."
1110 PRINT:PRINT B$(1):PRINT B$(2):PRINT B$(4):PRINT
1111 PRINT IQ$;:INPUT I
1112 IF INT(I)<>I OR I<1 THEN GOTO 1111
1113 ON I GOTO 850,500,1111,750:GOTO 1111
1150 CLS:PRINT "Vous etes dans une chambre ou il y a une porte a l'est." 
1152 PRINT"Il y a aussi une armoire a l'ouest." 
1153 IF A0=0 THEN GOTO 1159
1154 PRINT"L'armoire est ouverte."
1155 PRINT:PRINT" 1 Vous regardez dans l'armoire"
1156 GOTO 1160
1159 PRINT:PRINT" 1 Vous essayez d'ouvrir l'armoire"
1160 PRINT B$(3):PRINT
1161 PRINT IQ$;:INPUT I
1162 IF I=3 THEN GOTO 850
1163 IF I<>1 THEN GOTO 1161
1165 IF A0=1 THEN GOTO 1320
1166 PRINT:PRINT"Impossible de l'ouvrir."
1167 IF CO=0 AND CP=0 THEN GOTO 1161
1168 PRINT:IF CO=1 THEN PRINT" 1 Vous essayez d'ouvrir la porte avec votre clef en OR"
1169 IF CP=1 THEN PRINT" 2 Vous essayez d'ouvrir la porte avec votre petite clef"
1170 PRINT B$(3):PRINT
1171 PRINT IQ$;:INPUT I
1172 IF INT(I)<>I OR I<1 THEN GOTO 1171
1173 ON I GOTO 1319,1174,850:GOTO 1171
1174 IF CP=0 THEN GOTO 1171
1175 CLS:PRINT "Impossible de l'ouvrir, la clef ne convient pas."
1176 FOR I=1 TO TEMPO*2:NEXT I:GOTO 1150
1200 CLS:PRINT "Vous etes dans une chambre. Il y a une porte a l'ouest."
1201 PRINT"Il y a aussi un telephone sur une table."
1210 PRINT:PRINT B$(4):PRINT" 5 Vous essayez d'appeler police-secours.":PRINT
1211 PRINT IQ$;:INPUT I
1212 IF I=4 THEN GOTO 350
1213 IF I<>5 THEN GOTO 1211
1214 PRINT:PRINT"En decrochant le telephone, vous n'entendez aucune tonalite."
1215 PRINT"En regardant sous la table, vous voyez que les fils sont arraches."
1216 FOR I=1 TO TEMPO*3:NEXT I:GOTO 1200
1220 CLS:PRINT "Vous etes dans une chambre, il y a une porte a l'ouest."
1221 PRINT"Il y a aussi une commode avec 6 tiroirs."
1225 PRINT:PRINT B$(4):PRINT" 5 Vous cherchez dans les tiroirs":PRINT
1226 PRINT IQ$;:INPUT I
1227 IF I=4 THEN GOTO 350
1228 IF I<>5 THEN GOTO 1226
1229 IF LA=0 THEN GOTO 1231
1230 PRINT:PRINT A$:GOTO 1226
1231 PRINT:PRINT"En ouvrant le tiroir en bas a droite, vous trouvez une lampe "
1232 PRINT"de poche.":PRINT:PRINT"Vous la prenez(1) ou pas(2) ?"
1233 PRINT:PRINT IQ$;:INPUT I
1234 IF I=1 THEN GOTO 1238
1235 IF I<>2 THEN GOTO 1233
1236 PRINT:PRINT A$
1237 FOR I=1 TO TEMPO*2:NEXT I:GOTO 1220
1238 PRINT:PRINT A$:LA=1:GOTO 1237
1240 CLS:PRINT "Vous etes dans une chambre, il y a une porte a l'est."
1250 PRINT:PRINT B$(3):PRINT B$(7):PRINT
1251 PRINT IQ$;:INPUT I
1252 IF I=3 THEN GOTO 350
1253 IF I<>7 THEN GOTO 1251
1254 FOR I=1 TO TEMPO*10:NEXT I:GOTO 1251
1260 CLS:PRINT "Vous etes dans une salle de bains, il y a une porte a l'est."
1270 PRINT:PRINT B$(3):PRINT B$(7):PRINT
1271 PRINT IQ$;:INPUT I
1272 IF I=3 THEN GOTO 350
1273 IF I<>7 THEN GOTO 1271
1274 FOR I=1 TO TEMPO*8:NEXT I:GOTO 1271
1280 CLS:PRINT "Vous etes devant les WC, vous pouvez soit entrer vous"
1281 PRINT"soulager(1) ou rester dans le couloir(0)."
1285 PRINT:PRINT IQ$;:INPUT I
1286 IF I=0 THEN GOTO 350
1287 IF I<>1 THEN GOTO 1285
1288 CLS:PRINT "En entrant dans les WC, vous pouvez lire ce message sur la"
1289 PRINT"porte : IL FAUT BEAUCOUP D'AMPOULES POUR ECLAIRER NEW-YORK,"
1290 PRINT" MAIS UNE LAMPE DE POCHE PERMET DE SORTIR DE CETTE MAISON."
1291 FOR I=1 TO TEMPO*10:NEXT I
1292 CLS:PRINT "Vous retournez dans le couloir apres vous etre soulage."
1293 FOR I=1 TO TEMPO*2:NEXT I:GOTO 350
1300 CLS:PRINT "Vous etes dans une salle-a-manger, i1 y a une porte a"
1301 PRINT"l'ouest et 2 au sud : une a l'est et une a l'ouest."
1310 PRINT:PRINT B$(4):PRINT B$(15):PRINT B$(18):PRINT
1311 PRINT IQ$;:INPUT I
1312 IF INT(I)<>I OR I<4 THEN GOTO 1311
1313 ON I-3 GOTO 800:IF I<15 THEN GOTO 1311
1314 ON I-14 GOTO 550,1311,1311,300:GOTO 1311
1319 IF CO=0 THEN GOTO 1171:A0=1
1320 CLS:PRINT "Derriere le faux fond de l'armoire se trouve une grotte"
1321 PRINT"sombre. Des bruits etranges d'animaux sauvages vous font tressaillir."
1322 PRINT"Mais,le jour vois apparait deja la-bas, tout au fond de la grotte."
1328 PRINT:PRINT" 1 Vous avancez":PRINT" 2 Vous retournez dans la chambre."
1329 IF LA=1 AND LAA=0 THEN PRINT" 3 Vous allumez la lampe de poche"
1330 PRINT:PRINT IQ$;:INPUT I
1331 IF INT(I)<>I OR I<1 THEN GOTO 1330
1332 ON I GOTO 1333,1150,1350:GOTO 1330
1333 IF LAA=1 THEN GOTO 1335
1334 CLS:PRINT "Vous tombez dans un trou.":GOTO 417
1335 CLS:PRINT "Vous voyez apparaitre un trou devant vous que vous contournez."
1336 FOR I=1 TO TEMPO*3:NEXT I
1337 PRINT:PRINT"Vous continuez ensuite d'avancer. Les rats vous font encore"
1338 PRINT"quelques frayeurs."
1339 FOR I=1 TO TEMPO*2:NEXT I
1340 PRINT:PRINT"Mais,finalement, le jour se rapproche et vous etes bientot libre"
1341 FOR I=1 TO TEMPO*2:NEXT I
1342 PRINT:PRINT"Ca y est,vous vous en etes tout de meme sorti."
1343 PRINT:PRINT:PRINT:PRINT:PRINT TAB(20);"TRIPLES BRAVOS !!!!!!!!!!!!!"
1344 END
1350 IF LA=0 THEN GOTO 1330
1351 PRINT:PRINT A$
1352 FOR I=1 TO TEMPO*2:NEXT I:LAA=1:GOTO 1320